home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol065 / bye78.asm < prev    next >
Assembly Source File  |  1984-04-29  |  71KB  |  2,979 lines
  1. ;    TITLE    'BYE V7.8 AS OF 02/20/82'
  2. ;    PAGE    44
  3. ;
  4. ;        BYE V7.8 (revised 02/20/82)
  5. ;    REMOTE CONSOLE PROGRAM FOR CP/M AND MODEM
  6. ;
  7. ;This program allows modem callers to use your CP/M system
  8. ;just as if they were seated at the system console.  Special
  9. ;assembly-time options allow limiting the caller's access by
  10. ;password and/or access to only a message-service program.
  11. ;
  12. ;Based on an original program written by Dave Jaffe, January 1979
  13. ;Rewritten for PMMI modem by Ward Christensen, February 1979.
  14. ;This program now supports DC Hayes, PMMI, and external modems.
  15. ;The UARTS supported are the Intel 8251 and the Western Digital 8250.
  16. ;Be sure to set the equates for the modem you are using. 
  17. ;
  18. ;*************************************************************************
  19. ;DANGER: Pay close attention to the polarity of the jump instructions    *
  20. ;after any in from a uart when running under 8250/8251's,  I have tried  *
  21. ;to fix them for the most common logical setup, but your system may      *
  22. ;differ.                                 *
  23. ;*************************************************************************
  24. ;
  25. ;Thanks to Bill Precht for the "label + offset" idea allowing
  26. ;this program to relocate itself without using DDT to initially
  27. ;set it up.
  28. ;
  29. ;Modifications/fixes: (in reverse order to minimize reading time)
  30. ;
  31. ;02/03/82 Fixed the buggy conditional jumps in/after RINGWT.
  32. ;      Now there is conditional assembly depending on if you are
  33. ;      a WD8250/IN8251 or a "standard" system.
  34. ;      Fixed a few bugs in conditional assembly.
  35. ;      Improved LF code.
  36. ;                          -- Paul S Traina
  37. ;
  38. ;01/20/82 Add equates and routines for HEATH or IMS systems and any
  39. ;      other systems using External modems and the WD8250 UART.
  40. ;      Included assembly option for compatability with RBBS,
  41. ;      MINICBBS, and OXGATE implimentations. by Thom Quick
  42. ;
  43. ;01/09/82 Added WRTLOC flag for use with an RBBS program that sets
  44. ;      this flag during disk writes; avoids files out of synch
  45. ;      problem if caller hangs up during writes. Added MINICK
  46. ;      routines which do the same with MINICBBS. Added patch
  47. ;      to allow bye to run below the CCP with programs such as
  48. ;      TYPESQ. Separated Superb conditional assembly into Externl
  49. ;      and LOSER, this separates external modem operation from a
  50. ;      losing feature of a particular BIOS. (P. L. Kelley)
  51. ;        
  52. ;12/03/81 Implemented OxGate protocol,  fixed some bugs in conditional
  53. ;        equates.  Variables for UCLSW and NULLS moved up so that
  54. ;        programs can poke them too.    (Paul Traina)
  55. ;
  56. ;12/02/81 Make variables for MAXDRV, MAXUSR, and TOVALUE that
  57. ;         can be found via the warm boot BIOS vector at zero,
  58. ;      so that these values can be changed while BYE is
  59. ;      running to accomodate privileged users, either through
  60. ;      action of the BYE-run .COM file or some other password
  61. ;      program run later. Move MCBOOT and the USRLOG vector
  62. ;      to just after the START vector, for easier access
  63. ;      if desired.
  64. ;
  65. ;11/04/81 Print out BYE version number in PRNLOG, to allow
  66. ;      program to be identified easily when running. Call
  67. ;      USRCHK in all cases to print out version number on
  68. ;      local ctrl-C, then ask to resume BYE instead of
  69. ;      warm boot. Convert many msgs to upper/lower case.
  70. ;                    By Steve Bogolub
  71. ;
  72. ;10/24/81 Modified NOPASS so that COM files that look for
  73. ;      a second file on the command line (such as HELP18)
  74. ;      will find a 20H at FCB+1 for default purposes.  Also
  75. ;      added RUNCOM at the end of NOPASS and changed the
  76. ;      jumps to the TPA (100h) to a CALL so that a COM file
  77. ;      will return to BYE where a clean jump to warm boot
  78. ;      can be done instead of going off to never-never land.
  79. ;                    R. L. Plouffe
  80. ;
  81. ;10/11/81 Print password on local console with DUAL$IO. Allow
  82. ;      return from PRNLOG with USRLOG. Make <CR><LF> instead
  83. ;      of <LF><CR> in USRLOG reports. Print out BYE version
  84. ;      number for easy identification. Position PRNLOG after
  85. ;      cold boot routine, and change cold boot routine to
  86. ;      jump to MBOOT, thereby defining path to PRNLOG for
  87. ;      all BYE programs and allowing one trivial program
  88. ;      that can be run to get the BYE log. Make counters
  89. ;      16 bits for greater range. By Steve Bogolub
  90. ;
  91. ;10/01/81 Added CALL CHECK to MSTAT routine to eliminate
  92. ;      possibility of system crash when carrier lost while
  93. ;      performing repeated console status checks without
  94. ;      any console output.  This problem occurs during the
  95. ;      password input of USERPW.ASM, and potentially any other
  96. ;      program that does repeated direct console input, such
  97. ;      as MBASIC, etc.  
  98. ;      By Ron Fowler and Dave Hardy
  99. ;
  100. ;05/14/81 Added CCS disk support (to turn off disks when idle)
  101. ;      Added support for Godbout SS1 Real time clock.
  102. ;      Added Phone to Lister, Punch & Reader patch. (AAJ)
  103. ;
  104. ;03/20/81 Fixed MOUTPUT so parity bit is stripped before outputting
  105. ;      character to modem.  Corrected 3/18/81 null fix.  Added
  106. ;      additional description to heading of this file.  (KBP)
  107. ;
  108. ;03/18/81 Add first-ring debounce routine, change PMMI HANGUP
  109. ;      to do break for faster disconnect, fix error in P3TODTR
  110. ;      equate for PMMI, added end-of-program error message to
  111. ;      mark ending address (see note at label DEST). By KBP.
  112. ;      Fix bug that prevented nulls at end of line if DUAL$IO
  113. ;      was true.  By Hank Szyszka.
  114. ;
  115. ;02/23/81 Conditional assembly added for Intertec SuperBrain
  116. ;      with Racal-Vadic 3451 modem. Corrected lack of RET in
  117. ;      CONIN. In MOUTPUT, replaced CZ CHECK with JNZ SILENT,
  118. ;      CALL CHECK; this eliminates chance of looping in MOUTPUT
  119. ;      if modem doesn't empty USART after carrier lost.
  120. ;      Also had to write a routine to patch BIOS so that after
  121. ;      the warm boot disk read this program repatches the BIOS.
  122. ;      Apparently the SuperBrain warm boot overwrites a portion
  123. ;      of the BIOS. By P.L. Kelley
  124. ;
  125. ;02/17/81 Added check for extraneous control characters in
  126. ;      hardcopy log.  (Formfeed seems to be a common "hit").
  127. ;      Changed local startup test to directly test for carrier
  128. ;      instead of calling CARCK, to avoid 15 second delay.
  129. ;      <BRR>
  130. ;
  131. ;02/15/81 Removed dependance on DC Hayes hardware timer so that
  132. ;         DCHAYES conditional assembly is compatible with both
  133. ;         old-style 80-103A and new-style MM100 boards.
  134. ;         Rearranged patch list to "most recent first" order.
  135. ;      Added message for invalid-drive test.
  136. ;         Added ANI 7Fh to upper case conversion test so that
  137. ;         it's not fooled by bit 7 being set.
  138. ;         Added WELUSR equate for user # containing WELCOME file.
  139. ;         Removed PTRPORT equate and changed hardcopy logic to
  140. ;         work through the BIOS printer driver. <BRR>
  141. ;
  142. ;01/22/81 Changed carrier detect routine for DC Hayes to wait for
  143. ;      15 seconds after loss of carrier to return. <DAVID KOZINN>
  144. ;
  145. ;01/17/81 Changed timing loops to use DC Hayes hardware timer
  146. ;      if present.   <DAVID KOZINN>
  147. ;
  148. ;01/16/81 Added equates and code for the DC Hayes 
  149. ;      Micromodem 100.  <DAVID KOZINN>
  150. ;
  151. ;09/23/80 Fixed bugs that prevented "bye /a" and "bye /c" from
  152. ;      working properly.  Also repaired several errors in
  153. ;      conditional assembly nesting.  By Ron Fowler
  154. ;
  155. ;09/20/80 Modified status checking during ring-wait routine to
  156. ;      use cp/m BDOS call, as suggested by Keith Petersen.
  157. ;      This should make the program more portable.  Also
  158. ;      added Bruce Ratoff's update to DCHBYE program (5.5),
  159. ;      that allows the use of bye from non-zero user areas.
  160. ;      By Ron Fowler
  161. ;
  162. ;09/19/80 Modified COM file load routine to prevent BDOS
  163. ;      overwrite if the COM file won't fit in the TPA
  164. ;      By Ron Fowler
  165. ;
  166. ;09/19/80 Added new '/' option C, which has the same affect as
  167. ;      /A, except that /C loads the com file after answering
  168. ;      the phone, while /A boots CP/M.  By Ron Fowler
  169. ;
  170. ;09/19/80 Added conditional assembly to give the operator a
  171. ;      'twit' logout key. Added conditionals for 'message
  172. ;      from operator' and 'system down in 5 minutes' keys.
  173. ;      Added front-panel selection of hard-copy log, remote
  174. ;      'black-out', and password option.  Also, if cpm/2 is
  175. ;      used, a message is printed when an unsupported user
  176. ;      area is entered.  By Ron Fowler and Dave Hardy
  177. ;
  178. ;09/19/80 Modified to prevent re-load of the com file when
  179. ;      a voice call comes in.  Reset the DMA address back
  180. ;      to 80h after the com file is loaded.  By Ron Fowler
  181. ;
  182. ;09/16/80 Added conditional assembly to allow automatic
  183. ;      loading of a com file instead of cp/m boot. Also
  184. ;      added decimal usrlog counters as conditional
  185. ;      assembly.  By Ron Fowler
  186. ;
  187. ;09/15/80 Added conditional assembly for automatic timed
  188. ;      log-out, drive and user number masking, lower
  189. ;      case query at login, and cp/m 2.x.  Thanks to
  190. ;      Bruce Ratoff for the routines (lifted from his
  191. ;      'DCHBYE54.ASM') used to implement these functions
  192. ;      NOTE: in order to implement the timed log-out, it
  193. ;      was necessary to do timing in software loops.
  194. ;      Therefore, a new equate, FASTCLK, has been added
  195. ;      to allow for 4mhz clock speeds. Also added Bruce
  196. ;      Ratoff's overrun/framing error checking when read-
  197. ;      ing the modem port.  By Ron Fowler
  198. ;
  199. ;07/16/80 Added "/R" command option to allow USRLOG
  200. ;      counters to be reset upon entry.  By Dave Hardy
  201. ;
  202. ;07/11/80 Added conditional assembly for password and
  203. ;      user log routines, and routines to print USRLOG
  204. ;      information on console after program exit.
  205. ;      By Dave Hardy
  206. ;
  207. ;07/10/80 Added code to allow auto-answer after first
  208. ;      or second ring for more reliable auto-answer
  209. ;      when using "ringback" option.  By Dave Hardy
  210. ;
  211. ;06/29/80 Added USRLOG routines to keep track of number
  212. ;      of callers, and display on front panel
  213. ;      of IMSAI (i.e. output number to port FFH).
  214. ;      By Dave Hardy
  215. ;
  216. ;06/11/80 Added routines to allow conditional assembly for
  217. ;      Morrow's Discus 2D board (all Rev's) with memory
  218. ;      mapped I/O.  Added 710 Baud rate selection option
  219. ;      at sign-on.  By Dave Hardy and Bruce Levison.
  220. ;
  221. ;01/24/80 Added routines to preserve registers when calling
  222. ;      the user's CBIOS.  Added conditional assembly for
  223. ;      callback feature.  Increased stack space to 60.
  224. ;      By Keith Petersen.
  225. ;
  226. ;09/24/79 Added routines to allow automatic multiple baud
  227. ;      rate selection, exit to CP/M from local console,
  228. ;      echo nr. of nulls selected. By Keith Petersen,
  229. ;      with thanks to Bob Mathias for suggestions.
  230. ;
  231. ;05/06/79 Added routine to allow "callback" operation so modem
  232. ;      does not answer normal voice calls.  By Robbin Hough
  233. ;      and Keith Petersen, W8SDZ.
  234. ;
  235. ;------------------------------------------------
  236. ;
  237. ;This program runs up in high RAM.  It gets there
  238. ;by being moved there when 'BYE' is typed.
  239. ;
  240. ;The program in high RAM does the following:
  241. ;
  242. ;    1.    Hangs up the phone
  243. ;    2.    Awaits ring detect, allows exit
  244. ;        to CP/M if local KBD types CTL-C
  245. ;    3.    Outputs carrier (see callback routines)
  246. ;    4.    Awaits incoming carrier going to step 1
  247. ;        if none found in 15 seconds
  248. ;    5.    Asks number of nulls (0-9)
  249. ;    6.    Types the file "WELCOME" from
  250. ;        disk, allowing CTL-C to skip it
  251. ;    7.    Asks for a password, allowing
  252. ;        5 tries to get it right.
  253. ;    8.    When password entered, if used,
  254. ;        drops into CP/M.
  255. ;    9.    Caller can leave by hanging up,
  256. ;        (any time carrier is lost, it
  257. ;        waits 15 seconds, then goes
  258. ;        back to step 1), or the caller
  259. ;        may type the program name (BYE)
  260. ;
  261. ;------------------------------------------------
  262. ;
  263. ;System equates
  264. ;
  265. FALSE    EQU    0
  266. TRUE    EQU    NOT FALSE
  267. ;
  268. CR    EQU    0DH
  269. LF    EQU    0AH
  270. MINUTES    EQU    20*60    ;CONSTANT FOR 1 MIN TIME DELAY
  271. ;
  272. ;Change the following equate to an area in your
  273. ;high memory where this program may patch itself in.
  274. ;Approximate memory requirements: 2k bytes or more,
  275. ;depending upon the options selected.  A marker has
  276. ;been placed at the end to deliberately print an error
  277. ;message during assembly in order to determine the actual
  278. ;ending address of the program.  The error message will
  279. ;not affect the assembly.  Make sure you have memory
  280. ;available up to the address shown.
  281. ;
  282. DEST0    EQU    0F900H    ;RUNNING LOCATION OF CODE
  283. ;
  284. ;Change the following to specify either DCHAYES, PMMI or systems
  285. ;with EXTERNAL  modems. Be sure to change either TPORT for PMMI or
  286. ;DATA for DCHAYES if they are not at the standard locations.
  287. ;
  288. DCHAYES    EQU    TRUE     ;TRUE FOR DC HAYES MODEM
  289. PMMI    EQU    FALSE     ;TRUE FOR PMMI MODEM
  290. IN8251    EQU    FALSE    ;TRUE FOR EXTERNAL AND INTEL 8251
  291. WD8250  EQU    FALSE    ;TRUE FOR EXTERNAL AND WESTERN DIGITAL 8250 
  292. ;
  293. ;Change the following if you have a DC Hayes modem that is
  294. ;not based at 80H. All other port equates are based on this.
  295. ;
  296.     IF    DCHAYES
  297. DATA    EQU    80H    ;DC HAYES DATA PORT
  298.     ENDIF        ;DCHAYES
  299. ;
  300. ;Change the following if you have a PMMI modem that is not
  301. ;based at 0C0H.  All other port equates are based on this.
  302. ;
  303.     IF    PMMI
  304. TPORT    EQU    0C0H    ;UART CONTROL/STATUS PORT
  305.     ENDIF
  306. ;
  307.     IF    WD8250 
  308. BASE$PORT  EQU  20H
  309.     ENDIF
  310. ;
  311. ;You will likely also want to change the password,
  312. ;located below at label 'PASSWD', and the messages
  313. ;printed at label 'WELCOME' and just above label
  314. ;'HANGUP'. The names of the welcome and com files
  315. ;are at lables 'WELFIN' and 'COMFCB' respectively. 
  316. ;
  317. ;****************************************************
  318. ;*        Option configuration section        *
  319. ;****************************************************
  320. ;
  321. ;-----------------General Options------------------
  322. ;
  323. OXGATE    EQU    TRUE     ;WANT TO RUN AN OXGATE NODE?
  324. PRINTER EQU    TRUE     ;WANT TO RETAIN LIST DEVICE?
  325. DUAL$IO EQU    TRUE     ;WANT CONSOLE & MODEM?
  326. CALLBAK EQU    FALSE    ;WANT CALLBACK FEATURE?
  327. PWRQD    EQU    FALSE     ;WANT TO USE PASSWORD?
  328. BOOTMSG    EQU    FALSE    ;TRUE IF BOOT MESSAGE
  329. FKEYS    EQU    TRUE    ;WANT SPECIAL FUNCTION KEYS
  330. USRLOG    EQU    FALSE    ;WANT TO COUNT NUMBER OF USERS?
  331. HARDLOG EQU    TRUE     ;WANT TO ECHO REMOTE KBD TO PRINTER?
  332. TIMEOUT EQU    TRUE    ;WANT AUTO LOG-OFF FOR SLEEPY CALLERS?
  333. TOVALUE EQU    5    ;MINUTES TO AUTO LOGOFF
  334. COMFILE EQU    TRUE    ;WANT TO AUTOBOOT A COM FILE?
  335. DECIMAL EQU    TRUE    ;WANT DECIMAL VALUES FOR LOGS?
  336. TRAPLC    EQU    FALSE    ;WANT TO TRAP LOWER CASE?
  337. ALLDEV    EQU    FALSE    ;RETAIN PUNCH, READER, LISTER
  338. MINICK    EQU    FALSE    ;TRUE IF MINICBBS
  339. RBBSCK    EQU    FALSE    ;TRUE IF RBBS SETS/RESETS FLAG AT 'WRTLOC'
  340. IOBYTE    EQU    0003    ;LOCATION OF INTEL IOBYTE
  341. IOVAL    EQU    0    ;INITIAL VALUE TO STORE IN IOBYTE
  342. ; 
  343. ;----------System and hardware dependent options--------------
  344. ;
  345. ZCPRT    EQU    TRUE     ;TRUE IF RUNNING NewZCPR (IN SECURE MODE)
  346. WHEEL    EQU    0FFFFH    ;LOCATION OF NZCPR'S WHEEL FLAG
  347. BYELOW    EQU    FALSE    ;TRUE IF BYE BELOW CCP
  348. LOSER    EQU    FALSE    ;TRUE IF WARM BOOT OVERWRITE PART OF THE BIOS
  349. NORING    EQU    FALSE    ;UART RING INDICATOR NOT AVAILABLE
  350. CPM2    EQU    TRUE    ;USING CP/M 2.X?
  351. MAXUSR    EQU    15    ;SET TO 0 FOR CP/M 1.4
  352. WELUSR    EQU    14    ;USER # OF WELCOME FILE, CPM2 TRUE
  353. COMUSR    EQU     14    ;USER # OF COM FILE, CPM2 TRUE
  354. FASTCLK    EQU     TRUE    ;SET TRUE FOR 4MHZ CLOCK
  355. MAXDRV    EQU    3    ;HIGHEST DRIVE SUPPORTED
  356. IMSAI    EQU    FALSE    ;ADDS VARIOUS OPTIONS W/SENSE SW'S
  357. TWITKEY EQU    'N'-40H ;KEYCODE TO LOG-OUT A CREEP
  358. MSGKEY    EQU    'Q'-40H ;KEYCODE TO PRINT 'MESG FROM OPER:'
  359. SYSDKEY EQU    'O'-40H ;KEYCODE TO PRINT SYS DOWN MSG
  360. SENSE    EQU    0FFH    ;SENSE SWITCH PORT NUMBER IMSAI TRUE
  361. BLKOUT    EQU    FALSE    ;SWITCH TO TURN OFF REMOTE SEND IMSAI TRUE
  362. SELPASS EQU    FALSE     ;SWITCH TO REQUIRE A PASSWORD IMSAI TRUE
  363. CCSDISK    EQU    FALSE     ;SET TRUE IF CCS DISK CONTROLLER   
  364. RTC    EQU    FALSE     ;SET TRUE IF GODBOUT SS1 BOARD
  365. ;
  366.     IF CCSDISK
  367. ;
  368. DISKON    EQU    071H    ;MOTORS ON, SELECT DISK A
  369. DISK    EQU    34H    ;DISK CONTROL PORT
  370. DISKOFF    EQU    051H    ;MOTORS OFF, SELECT DISK A;
  371.     ENDIF        ;CCSDISK
  372. ;
  373. ;Assignment of front-panel options to switches:
  374. ;
  375. LOGSW    EQU    01H    ;TURN ON FOR HARDCOPY
  376. PWDSW    EQU    02H    ;TURN ON FOR 'PASSWORD' MODE
  377. BLACKSW EQU    04H    ;TURN ON TO BLACK OUT REMOTE END
  378. ENABLF    EQU    08H    ;TURN ON TO ENABLE SPL FUNC KEYS
  379. ;
  380.     IF BYELOW
  381. DEST    EQU    DEST0+3    ;KEEP ON TARGET
  382. ;
  383. ;****WARNING *** WMLOC AND OLDBD ARE SYSTEM DEPENDENT****
  384. ;WMLOC can be found in the BIOS by tracing through the
  385. ;warm boot routine with DDT until you find:
  386. ;    LXI    H,OLDBD
  387. ;    SHLD    0006
  388. ;WMLOC is the address containing the LSB of OLDBD
  389. ;
  390. WMLOC    EQU    0E04DH
  391. OLDBD    EQU    0D006H
  392. ;
  393.     ENDIF        ;BYELOW 
  394. ;
  395.     IF    NOT BYELOW
  396. DEST    EQU    DEST0
  397.     ENDIF        ;NOT BYELOW
  398. ;
  399. ;There are some cases where warm boot overwrites the
  400. ;initial bios jump table. This problem was solved for
  401. ;the Superbrain 3.0 bios by finding a warmboot call
  402. ;to high in the bios. This call is then patched by
  403. ;BYE.  The form of the call is:
  404. ;    WBCALL  CALL    WMSTRT
  405. ;
  406.     IF    LOSER
  407. ;
  408. WBCALL    EQU    0DE48H    ;CHECK THIS IN YOUR BIOS     
  409. ;
  410. ;The following location is called
  411. ;
  412. WMSTRT    EQU    0EE48H    ;CHECK THIS IN YOUR BIOS
  413. ;
  414.     ENDIF        ;LOSER
  415. ;            
  416. ;****************************************************
  417. ;*     End of option configuration section        *
  418. ;****************************************************
  419. ;
  420. ;All modem I/O and control are here
  421. ;
  422. ;
  423. ;************ D.C. Hayes modem I/O area ************
  424. ;
  425.     IF    DCHAYES
  426. ;
  427. ;Port equates
  428. ;
  429. DPORT    EQU    DATA    ;DATA PORT
  430. STATUS    EQU    DATA+1
  431. RPORT    EQU    STATUS    ;MODEM STATUS PORT
  432. CR1    EQU    DATA+1
  433. CR2    EQU    DATA+2
  434. CR3    EQU    DATA+3
  435. ;
  436. ;Bit functions
  437. ;
  438. ;    Status register
  439. ;
  440. RRF    EQU    1    ;RECEIVE REGISTER FULL
  441. TRE    EQU    2    ;TRANSMITTER HOLDING REGISTER EMPTY
  442. PE    EQU    4    ;PARITY ERROR
  443. FE    EQU    8    ;FRAMING ERROR
  444. OE    EQU    10H    ;OVERRUN ERROR
  445. TMR    EQU    20H    ;TIMER STATUS (MM100 ONLY)
  446. CD    EQU    40H    ;CARRIER PRESENT
  447. RI    EQU    80H    ;NOT RING INDICATOR (LOW TRUE)
  448. P2RDET    EQU    RI    ;SAME AS ABOVE
  449. ;
  450. ;    Control register 1 (CR1)
  451. ;
  452. EPE    EQU    1    ;EVEN PARITY ENABLE
  453. LS1    EQU    2    ;WORD LENGTH SELECT BIT 1
  454. LS2    EQU    4    ;WORD LENGTH SELECT BIT 2
  455. SBS    EQU    8    ;STOP BITS
  456. PI    EQU    10H    ;PARITY INHIBIT
  457. TMIE    EQU    20H    ;TIMER INTERRUPTS ENABLE (MM100 ONLY)
  458. ;
  459. ;    Control register 2 (CR2)
  460. ;
  461. BRS    EQU    1    ;BAUD RATE CONTROL
  462. TXE    EQU    2    ;TRANSMIT CARRIER ENABLE
  463. MS    EQU    4    ;MODE (0=ANSWER 1=ORIGINATE)
  464. BRK    EQU    8    ;SEND BREAK
  465. ST    EQU    10H    ;SELF TEST
  466. TIE    EQU    20H    ;TRANSMITTER INTERRUPT ENABLE
  467. RIE    EQU    40H    ;RECEIVER INTERRUPT ENABLE (MM100 ONLY)
  468. OH    EQU    80H    ;OFF-HOOK
  469. ;
  470.     ENDIF        ;DCHAYES
  471. ;
  472. ;
  473. ;************ PMMI modem I/O area ************
  474. ;
  475.     IF    PMMI
  476. ;
  477. ;PMMI modem port equates (TPORT previously done)
  478. ;
  479. DPORT    EQU    TPORT+1 ;DATA PORT
  480. RPORT    EQU    TPORT+2 ;RATE GEN/MODEM STATUS
  481. CPORT    EQU    TPORT+3 ;MODEM CONTROL
  482. ;
  483. ;Switch hook and modem commands, output to TPORT (port 0)
  484. ;
  485. P0BYE    EQU    0    ;ON HOOK, OR DIALING BREAK
  486. P0ORIG    EQU    1    ;OFF HOOK, ORIG.
  487. P0ANSW    EQU    2    ;ANSWER PHONE
  488. P08BIT    EQU    0CH    ;8 DATA BITS
  489. P0NOPY    EQU    10H    ;NO PARITY
  490. P0EPS    EQU    20H    ;EVEN PARITY SELECT
  491. P0TSB    EQU    40H    ;2 STOP BITS
  492. P0EI    EQU    80H    ;ENABLE INTERRUPTS
  493. P0NORM    EQU    P08BIT+P0NOPY        ;NORMAL 8 BITS, NO PARITY
  494. P0110    EQU    P08BIT+P0NOPY+P0TSB ;SAME W/2 STOP BITS
  495. ;
  496. ;Modem status, input on RPORT (port 3)
  497. ;
  498. P2DTD    EQU    1    ;DIAL TONE DETECT
  499. P2RDET    EQU    2    ;RING DETECT
  500. P2CTS    EQU    4    ;CTS (CARRIER DETECT)
  501. P2RXBRK EQU    8    ;RECEIVE BREAK
  502. P2CONN    EQU    10H    ;CONNECTED? (0=YES, 1=MODEM CHIP HUNG UP)
  503. P2TMPUL EQU    80H    ;TIMER PULSES (40% UP CYCLE)
  504. ;
  505. ;Timer rate selection
  506. ;
  507. TRATE    EQU    250    ;VALUE FOR .1 SEC
  508. ;
  509. ;PMMI modem status masks
  510. ;
  511. P0TBMT    EQU    1    ;XMIT BUFF EMPTY
  512. P0DAV    EQU    2    ;DATA AVAILABLE
  513. P0TEOC    EQU    4    ;TEST END OF CHAR
  514. P0RPE    EQU    8    ;REC'D PARITY ERR
  515. P0ORUN    EQU    10H    ;OVERRUN
  516. P0FERR    EQU    20H    ;FRAMING ERROR
  517. ;
  518. ;Baud rate divisors
  519. ;
  520. B110    EQU    142    ;110 BAUD
  521. B300    EQU    52    ;300 BAUD
  522. B450    EQU    35    ;450 BAUD
  523. B600    EQU    26    ;600 BAUD
  524. B710    EQU    22    ;710 BAUD
  525. ;
  526.     ENDIF        ;PMMI
  527. ;
  528. ;************ EXTERNAL MODEM I/O AREA ************
  529. ;
  530.     IF    IN8251
  531. ;
  532. ;True if uart is Intel 8251 or equivalent
  533. ;
  534. DPORT    EQU    58H    ;DATA PORT
  535. CPORT    EQU    59H    ;CONTROL PORT
  536. SPORT    EQU    CPORT    ;STATUS PORT
  537. BPORT    EQU    60H    ;BAUD RATE PORT
  538. RPORT    EQU    69H    ;RING INDICATOR PORT
  539. ;
  540. ;The following are CPORT commands
  541. ;
  542. RSTINS    EQU    42H    ;RESET USART AND SEND DTR
  543. MODINS1    EQU    4EH    ;8 BITS, NO PARITY, 1 STOP BIT, 16X BAUD RATE
  544. MODINS2    EQU    0CEH    ;8 BITS, NO PARITY, 2 STOP BITS, 16X BAUD RATE
  545. ONINS    EQU    17H    ;RESET ERROR FLAGS, SEND DTR, ENABLE RECEIVE
  546.             ;AND TRANSMIT
  547. OFFINS    EQU    10H    ;DROP DTR, DISABLE RECEIVE AND TRANSMIT
  548. ;
  549. ;The following are SPORT status masks
  550. ;
  551. TRNRDY    EQU    01H    ;TRANSMITER EMPTY
  552. RCVRDY    EQU    02H    ;DATA AVAILABLE
  553. PERR    EQU    08H    ;PARITY ERROR
  554. ORERR    EQU    10H    ;OVERRUN ERROR
  555. FRERR    EQU    20H    ;FRAMING ERROR
  556. TOERR    EQU    ORERR + FRERR    ;OVERRUN PLUS FRAMING ERROR
  557. DSR    EQU    80H    ;DATA SET READY
  558. ;
  559. ;The following are baud rates for BPORT. The upper 4 bits are
  560. ;for the modem port while the lower four are for the auxiliary
  561. ;port.
  562. ;
  563. BD110    EQU    27H    ;110 BAUD
  564. BD300    EQU    57H    ;300 BAUD
  565. BD1200    EQU    77H    ;1200 BAUD
  566. ;
  567. ;Ring indicator port mask
  568. ;
  569. RI    EQU    40H    ;NOT RING INDICATOR (LOW TRUE)
  570. P2RDET    EQU    RI
  571. ;
  572.     ENDIF        ;IN8251
  573. ;
  574. ;****************WD8250  I/O AREAS*************************
  575. ;True if usar is Western Digital 8250 or equivilent.
  576. ;
  577.     IF    WD8250
  578. ; 
  579. DPORT    EQU    BASE$PORT    ;DATA PORT
  580. LPORT    EQU    BASE$PORT+3    ;LINE CONTROL
  581. CPORT    EQU    BASE$PORT+4    ;MODEM CONTROL
  582. SPORT    EQU    BASE$PORT+5    ;LINE STATUS PORT
  583. MSPORT    EQU    BASE$PORT+6    ;MODEM STATUS PORT
  584. RPORT    EQU    BASE$PORT+6    ;RING INDICATOR PORT
  585. ;
  586. *****************LINE STATUS MASKS************************
  587. ;
  588. P0TBMT    EQU    20H    ;XMIT BUFFER EMPTY
  589. P0DAV    EQU    01H    ;DATA AVAILABLE
  590. P0RPE    EQU    04H    ;PARITY ERROR
  591. P0ORUN    EQU    02H    ;OVERRUN ERROR
  592. P0FERR    EQU    08H    ;FRAMING ERROR
  593. P0BRK    EQU    10H    ;BREAK DETECT
  594. ;
  595. ;****************MODEM STATUS MASKS***********************
  596. ;
  597. P2DSR    EQU    20H    ;DATA SET READY
  598. P2CTS    EQU    080H    ;CARRIER DETECT
  599. P2RDET    EQU    040H    ;RING DETECT
  600. ;
  601. ;******************BAUD RATE DIVISORS*********************
  602. ;
  603. BR300LS    EQU    000H    ;300 BAUD
  604. BR300MS    EQU    001H    
  605. BR450LS    EQU    0ABH    ;450 BAUD
  606. BR450MS    EQU    000H    
  607. BR600LS    EQU    080H    ;600 BAUD
  608. BR600MS    EQU    000H    
  609. BR120LS    EQU    040H    ;1200 BAUD
  610. BR120MS    EQU    000H
  611. ;
  612. ;*******************MODEM CONTROL****************************
  613. ;
  614. MCDTR    EQU    01H    ;
  615. MCRTS    EQU    02H
  616. MCOUT1    EQU    04H
  617. MCOUT2    EQU    08H
  618. ;
  619. ;*********************LINE CONTROL****************************
  620. ;
  621. LCWLS0    EQU    01H
  622. LCWLS1    EQU    02H
  623. LCSTB    EQU    04H
  624. LCPEN    EQU    08H
  625. LCPES    EQU    10H
  626. LCSPS    EQU    20H
  627. LCBRK    EQU    40H
  628. LCDLAB    EQU    80H
  629.     ENDIF        ;WD8250
  630. ;
  631. ;---------------------------------------------------------
  632. ;
  633.     ORG    100H
  634. ;
  635.     IF     BYELOW    
  636. ;This code allow running below ccp and using programs such as
  637. ;Mbasic or Typesq ect....
  638. ;
  639.     LXI    H,OLDBD    ;OLD LOCATION STORED IN 6 AND 7 FOR
  640.             ;JUMP FROM BDOS CALL
  641.     SHLD    DEST-2    ;STORE IT JUST ABOVE BYE
  642.     LXI    H,DEST-3 ;POINT TO THREE BYTE ABOVE 
  643.              ;NORMAL BYE
  644.     MVI    M,0C3H    ;PUT A JUMP THERE
  645.     SHLD    0006H    ;STORE DEST-3 FOR BDOS JUMP
  646.     SHLD    WMLOC    ;STORE DEST-3 IN YOUR BIOS
  647. ;
  648.     ENDIF        ;BYELOW
  649. ;
  650. ;Move modem interface program up to high RAM and jump to it
  651. ;
  652. MOVEUP    LXI    B,PEND-START+1        ;NUMBER OF BYTES TO MOVE
  653.     LXI    H,DEST+PEND-START+1 ;END OF MOVED CODE
  654.     LXI    D,SOURCE+PEND-START ;END OF SOURCE CODE
  655. ;
  656. MVLP    LDAX    D    ;GET BYTE
  657.     DCX    H    ;BUMP POINTERS
  658.     MOV    M,A    ;NEW HOME
  659.     DCX    D
  660.     DCX    B    ;BUMP BYTE COUNT
  661.     MOV    A,B    ;CHECK IF ZERO
  662.     ORA    C
  663.     JNZ    MVLP    ;IF NOT, DO SOME MORE
  664. ;
  665.     PUSH    H    ;SAVE FOR LATER JUMP
  666.     MVI    A,0C3H    ;CLEAR ANY TRAPS SO SYSOP..
  667.     STA    0    ;CAN USER "BYE /A"
  668.     XRA    A    ;NEXT WARMBOOT TO USR0/DRV A
  669.     STA    4
  670.     MVI    C,14    ;MAKE DRIVE A DEFAULT
  671.     MOV    E,A    ;LOG-IN DRIVE CP/M FUNCTION
  672.            CALL    BDOS                                     
  673. ;
  674.     IF    CPM2    ;SET USER 0
  675.     MVI    C,32    ;GET/SET USR CP/M FUNCTION
  676.     MVI    E,WELUSR
  677.     CALL    BDOS
  678.     ENDIF        ;CPM2
  679. ;
  680.     RET        ;TO ADRS PUSHED ABOVE
  681. ;
  682. ;
  683. SOURCE    EQU    $    ;BOUNDARY MEMORY MARKER
  684. ;
  685. OFFSET    EQU    DEST-SOURCE ;RELOC AMOUNT
  686. ;
  687. ;-----------------------------------------------;
  688. ;    The following code gets moved        ;
  689. ;    to high RAM located at "DEST",        ;
  690. ;        where it is executed.        ;
  691. ;-----------------------------------------------;
  692. ;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  693. ;XX   C A U T I O N :  If modifying anything    XX
  694. ;XX    in this program from here on:        XX
  695. ;XX    A-L-L  labels must be of the form:    XX
  696. ;XX    LABEL    EQU    $+OFFSET        XX
  697. ;XX    in order that the relocation to high      XX
  698. ;XX    RAM work successfully.  Forgetting to    XX
  699. ;XX    specify '$+OFFSET' will cause the pro-    XX
  700. ;XX    gram to JMP into whatever is currently    XX
  701. ;XX    in low memory, with unpredictable    XX
  702. ;XX    results.  Be careful....        XX
  703. ;XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
  704. ;
  705. START    EQU    $+OFFSET
  706.     JMP    START0    ;HOP OVER FIXED VECTORS
  707. ;
  708. ;Cold boot vector ends up here. Our cold boot routine
  709. ;consists of a jump to the warm boot routine. We are
  710. ;defined to consist of only this jump, with a jump
  711. ;to PRNLOG immediately after this jump, and other
  712. ;modifiable variables after that. By doing this,
  713. ;a trivial program can be written that calculates
  714. ;where PRNLOG is thru the warm boot vector at 0001H,
  715. ;then calls PRNLOG, allowing remote users to get the
  716. ;BYE log printed. Such a program, easily entered
  717. ;with DDT, is as follows:
  718. ;
  719. ;    LHLD    0001H    ;PT TO COLD BOOT VECTOR + 3
  720. ;    DCX    H    ;PT TO VECTOR HIGH BYTE
  721. ;    MOV    D,M    ;GET THAT IN D
  722. ;    DCX    H    ;PT TO VECTOR LOW BYTE
  723. ;    MOV    E,M    ;GET THAT IN E
  724. ;    LXI    H,3    ;CALC PRNLOG ADDRESS
  725. ;    DAD    D    ; BY ADDING TO COLD BOOT ADDRESS
  726. ;    PCHL        ;GO PRINT LOG INFO, THEN
  727. ;            ; RETURN TO CCP
  728. ;
  729. ;A similar calculation can be used to determine
  730. ;the locations of the MXUSR, MXDRV, and TOVAL
  731. ;variables to change them on the fly for special
  732. ;users. Since this will often be done by a
  733. ;BASIC signon program, the following sequence
  734. ;of code is recommended:
  735. ;
  736. ;  10 A=PEEK(2)*256+PEEK(1)-2 'Pt to cold boot address
  737. ;  20 A=PEEK(A+1)*256+PEEK(A)+6 'Get address of MXUSR
  738. ;  30 POKE A,8  'Set MXUSR to 8, allows 0-8
  739. ;  40 POKE A+1,4 'Set MXDRV to 4, allows A-D
  740. ;  50 POKE A+2,5 'Set TOVAL to 5, allows 5 min of inactivity
  741. ;
  742. ;The values POKE'ed will be reset to the assembly
  743. ;values of MAXUSR, MAXDRV and TOVALUE respectively
  744. ;the next time BYE answers the phone.
  745. ;
  746. ;The following will test whether bye is active and then set
  747. ;the flag at WRTLOC.
  748. ;
  749. ;  10 A=PEEK(2)*256+PEEK(1)-2
  750. ;  20 A=PEEK(A+1)*256+PEEK(A)+9 'Get Address of WRTLOC
  751. ;  30 IF CHR$(PEEK(A+1))+SHR$(PEEK(A+2))+CHR$(PEEK(A+3))<>"BYE" THEN
  752. ;  40 POKE A,&HFF 'SET FLAG FOR WRITE IN PROGRESS
  753. ;
  754. ;The routine on line 30 should be used in RBBS so that when RBBS is 
  755. ;running locally nothing will be poked into the bios.
  756. ;   
  757. MCBOOT    EQU    $+OFFSET
  758.     JMP    MBOOT    ;OFF TO WARM BOOT
  759.     JMP    PRNLOG    ;GO PRINT OUT ITEMS OF INTEREST
  760. ;
  761. ;Variables follow in a predefined order that can
  762. ;be manipulated by a passworded or other program
  763. ;to give special users different capabilities.
  764. ;
  765. MXUSR    EQU    $+OFFSET
  766.     DB    MAXUSR    ;RUNTIME MAX USER # (UNUSED
  767.             ; UNDER CP/M 1.4)
  768. ;
  769. MXDRV    EQU    $+OFFSET
  770.     DB    MAXDRV    ;RUNTIME # DRIVES ACCESSABLE
  771. ;
  772. TOVAL    EQU    $+OFFSET
  773.     DB    TOVALUE    ;RUNTIME # INACTIVE MINUTES
  774.             ; BEFORE AUTO LOGOFF
  775. NULLS    EQU    $+OFFSET
  776.     DB    5    ;INITIAL NUMBER OF NULLS
  777. ;
  778. ULCSW    EQU    $+OFFSET
  779.     DB    0    ;UPPER CASE ONLY SWITCH
  780. ;
  781. LFEEDS    EQU    $+OFFSET
  782.     DB    0    ;LINE FEED SWITCH
  783. ;    
  784. WRTLOC    EQU    $+OFFSET
  785.     DB    0    ;LOCATION OF FLAG FOR RBBS TO 
  786.             ;SET WHILE DOING DISK WRITES
  787.  
  788. ;Program version number message.
  789. ;
  790. VMSG    EQU    $+OFFSET
  791.     DB    'BYE version 7.8 as of 02/20/82',CR,LF,'$'
  792. ;
  793. ;----------------------------------------------
  794. ;This is the official start of the BYE program.
  795. ;----------------------------------------------
  796. ;
  797. ;If carrier lost, hang up, await ring.
  798. ;Otherwise, say goodbye, and hang up
  799. ;
  800. START0    EQU    $+OFFSET
  801. ;
  802.     XRA    A    ;GET 0
  803.     STA    LOSTFLG ;SHOW NO CARR. LOST
  804. ;
  805.     IF    MINICK
  806. ;
  807. ;Set MINICK to true if you use MINICBBS and want to take
  808. ;advantage of its feature which can prevent the modem
  809. ;from hanging up if the caller should happen to discon-
  810. ;nect during a file update. MINICBBS sets the high-order 
  811. ;bit of IOBYTE to (address 0003) to indicate a file update
  812. ;is in progress.
  813. ;
  814.     MVI    A,IOVAL
  815.     STA    IOBYTE
  816. ;
  817.     ENDIF        ;MINICK
  818. ;
  819. ;Don't allow a remote user to do 'BYE /A'
  820. ;
  821.     IF    DCHAYES
  822.     IN    STATUS
  823.     ANI    CD    ;CHECK CARRIER DETECT
  824.     JNZ    GOODBY    ;SAY GOODBYE IF REMOTE
  825.     ENDIF        ;DCHAYES
  826. ;
  827.     IF    PMMI
  828.     IN    RPORT    ;AS ABOVE, FOR PMMI MODEM
  829.     ANI    P2CTS    ;CD DEDUCED FROM CTS
  830.     JZ    GOODBY
  831.     ENDIF        ;PMMI
  832. ;
  833.     IF    IN8251
  834.     IN    SPORT
  835.     ANI    DSR    ;CHECK CARRIER DETECT
  836.     JNZ    GOODBY    ;GOODBYE IF REMOTE
  837.     ENDIF        ;IN8251
  838. ;
  839.     IF    WD8250 
  840.     IN    MSPORT
  841.     ANI    P2CTS
  842.     JNZ    GOODBY
  843.     ENDIF        ;WD8250
  844. ;
  845. ;Identify version of program
  846. ;
  847.     MVI    C,PRINTF
  848.     LXI    D,VMSG
  849.     CALL    BDOS
  850. ;
  851. ;Check for /A option on command - request to
  852. ;go immediately into answer mode
  853.     LXI    H,FCB+1 ;TO OPTION
  854.     MOV    A,M
  855.     CPI    '/'    ;OPTION?
  856.     JNZ    HANGUP
  857. ;Got an option - validate it
  858.     INX    H    ;TO OPTION BYTE
  859.     MOV    A,M    ;GET IT
  860.     STA    OPTION    ;MIGHT NEED LATER
  861.     CPI    'A'    ;ANSWER?
  862.     JZ    ANSWER
  863. ;
  864.     IF    COMFILE
  865.     CPI    'C'
  866.     JZ    ANSWER
  867.     ENDIF        ;COMFILE
  868. ;
  869.     IF    USRLOG    ;CHECK FOR RESET OF COUNTERS
  870.     CPI    'R'
  871.     CZ    RESET
  872.     ENDIF        ;USRLOG
  873. ;
  874.     JMP    HANGUP    ;WE KNOW IT'S LOCAL, SO SKIP CALL TO CARCK
  875. ;
  876. ;No option, or invalid one
  877. ;
  878. NOSLASH EQU    $+OFFSET
  879.     CALL    CARCK    ;SIGNED OFF W/THIS PROG?
  880.     JC    HANGUP    ;NOBODY THERE
  881. ;
  882. GOODBY    EQU    $+OFFSET
  883.     CALL    ILPRT    ;PRINT THIS MSG:
  884.     DB    CR,LF,'Good-bye, call again...'
  885.     IF     RTC
  886.     DB    CR,LF,CR,LF,'Off at ',0
  887.     CALL    TIME
  888.     CALL    ILPRT
  889.     ENDIF        ;RTC
  890. ;
  891.     DB    CR,LF,CR,LF,0
  892.     CALL    UNPATCH ;UNDO BIOS PATCHES
  893. ;
  894. ;Nobody there, or we are done, so hang up
  895. ;
  896. HANGUP    EQU    $+OFFSET
  897.     LXI    SP,STACK ;SET UP LOCAL STACK
  898.     XRA    A     ;FORCE NEXT WARMBOOT TO USER 0
  899.     STA    4     ;AND DRIVE A
  900. ;
  901.     IF CCSDISK
  902. ;
  903.     CALL DSKOFF    ;SHUT DOWN THE DRIVES
  904. ;
  905.     ENDIF    ;CCSDISK
  906. ;
  907.     MVI    C,14     ;MAKE DRIVE A DEFAULT
  908.     MOV    E,A
  909.     CALL    BDOS
  910.     MVI    A,' '     ;DON'T ALLOW OPTIONS..
  911.     STA    OPTION     ;..AFTER 1 "BYE / <ANYTHING>"
  912. ;
  913.     IF    CPM2 AND COMFILE
  914.     MVI    C,32     ;GET/SET USER CODE
  915.     MVI    E,COMUSR ;LOCATION OF OUR COMFILE
  916.     CALL    BDOS
  917.     ENDIF         ;CPM2 AND COMFILE
  918. ;
  919.     IF    COMFILE
  920.     CALL    LODCOM    ;LOAD THE COM FILE
  921.     ENDIF        ;COMFILE
  922. ;
  923. ;
  924. HANGUP2 EQU    $+OFFSET
  925. ;
  926. ;Clear DTR causing phone to hang up
  927. ;
  928.     IF    DCHAYES
  929.     XRA    A    ;GET A ZERO
  930.     OUT    CR2    ;WRITE TO CR2, CAUSING HANGUP
  931.     ENDIF        ;DCHAYES
  932. ;
  933.     IF    PMMI
  934.     XRA    A    ;GET DISCONNECT VALUE
  935.     OUT    TPORT    ;RESET ORIG/ANSW
  936.     OUT    CPORT    ;TURN OFF DTR, DO BREAK
  937.     ENDIF        ;PMMI
  938. ;
  939.     IF    IN8251
  940.     MVI    A,OFFINS    ;CLEAR DTR
  941.     OUT    CPORT    ;CAUSING HANGUP
  942.     PUSH    B    ;PRESERVE IN CASE WE NEED IT
  943.     MVI    B,150    ;15 SECOND DELAY
  944. ;
  945. OFFTI    EQU    $+OFFSET
  946.     CALL    DELAY    ;0.1 SECOND DELAY
  947.     DCR    B
  948.     JNZ    OFFTI    ;KEEP LOOPING UNTIL FINISHED
  949.     POP    B    ;RESTORE B
  950.     MVI    A,ONINS    ;TURN DTR ON ALLOWING MODEM TO ANSWER PHONE
  951.     OUT    CPORT
  952.     ENDIF        ;IN8251
  953. ;
  954.     IF    WD8250 
  955.     XRA    A    ;SHUT OFF DTR & RTS
  956.     OUT    CPORT    ;SHUT OFF MODEM
  957.     ENDIF        ;WD8250
  958. ;
  959.     IF    WD8250 AND NORING
  960. ;
  961.     PUSH    B    ;PRESERVE IT IF WE NEED IT
  962.     MVI    B,150    ;15 SEC DELAY
  963.  
  964. OFFTI    EQU    $+OFFSET
  965.     CALL    DELAY    ;0.1 SEC DELAY
  966.     DCR    B    
  967.     JNZ    OFFTI    ;KEEP LOOPING UNTIL DONE
  968.     POP    B    ;RESTORE B
  969.     MVI    A,MCDTR+MCRTS    ;TURN ON DTR/RTS 
  970.     OUT    CPORT
  971.     ENDIF        ;WD8250 
  972. ;
  973.     MVI    A,0C3H    ;CLEAR ANY TRAPS..
  974.     STA    0    ;..LEFT FROM COM FILE
  975. ;
  976. ;Await ringing
  977. ;
  978. RINGWT    EQU    $+OFFSET
  979. ;
  980. ;Check local keyboard for CTL-C exit request.
  981. ;NOTE: Must do input via BDOS because CBIOS patches
  982. ;are not done until call comes in.
  983. ;
  984.     CALL    UCSTS
  985.     ANI    7FH    ;STRIP PARITY BIT
  986.     CPI    'C'-40H ;CONTROL C?
  987.     CZ    USRCHK    ;Check for exit if so
  988. ;
  989.     IF    NORING
  990.     IN    MSPORT
  991.     ANI    P2CTS    ;GOT CARRIER
  992.     JNZ    ANSWER
  993.     JMP    RINGWT    ;KEEP CHECKING
  994.     ENDIF        ;NORING
  995. ;
  996. RINGW2    EQU    $+OFFSET
  997.     IN    RPORT    ;GET THE STATUS
  998.     ANI    P2RDET    ;RINGING?
  999. ;
  1000.     IF    WD8250 OR IN8251
  1001.     JZ    RINGWT    ;NO, WAIT
  1002.     ENDIF    ;WD8250 OR IN8251
  1003. ;
  1004.     IF    NOT (WD8250 OR IN8251)
  1005.     JNZ    RINGWT    ;NO, WAIT
  1006.     ENDIF    ;NOT (WD8250 OR IN8251)
  1007. ;
  1008. ;The phone may be ringing.  Wait .1 sec and look
  1009. ;again to make sure it isn't just relay bounce
  1010.     CALL    DELAY    ;.1 SEC DELAY FOR DEBOUNCE
  1011.     IN    RPORT    ;GET STATUS
  1012.     ANI    P2RDET    ;STILL RINGING?
  1013. ;
  1014.     IF    WD8250 OR IN8251
  1015.     JZ    RINGWT    ;NO, IT WAS RELAY BOUNCE
  1016.     ENDIF    ;WD8250 OR IN8251
  1017. ;
  1018.     IF    NOT (WD8250 OR IN8251)
  1019.     JNZ    RINGWT    ;NO, IT WAS A RELAY BOUNCE
  1020.     ENDIF    ;NOT (WD8250 OR IN8251)
  1021. ;
  1022. ;The phone is definitely ringing, now wait until ring is finished
  1023. ;
  1024. ENDRING EQU    $+OFFSET
  1025.     CALL    DELAY    ;.1 SEC DELAY FOR DEBOUNCE
  1026.     IN    RPORT    ;GET STATUS
  1027.     ANI    P2RDET    ;STILL RINGING?
  1028. ;
  1029.     IF    WD8250 OR IN8251
  1030.     JNZ    ENDRING ;WAIT UNTIL RING FINISHED
  1031.     ENDIF    ;WD8250 OR IN8251
  1032. ;
  1033.     IF    NOT (WD8250 OR IN8251)
  1034.     JZ    ENDRING    ;WAIT UNTIL RING FINISHED
  1035.     ENDIF    ;NOT (WD8250 OR IN8251)
  1036. ;
  1037.     IF    CALLBAK ;NEXT ROUTINES IMPLEMENT CALLBAK
  1038. ;
  1039. ;This routine minimizes the computer's interference
  1040. ;with normal household phone use by having computer
  1041. ;folk dial, let the phone ring once, hang up and 
  1042. ;then dial again.  When the phone rings only once it
  1043. ;alerts the computer which then waits for and answers
  1044. ;any ring which occurs within the next 40 seconds.
  1045. ;
  1046.     MVI    L,45    ;DELAY 4.5 SECONDS FOR NEXT RING
  1047. ;
  1048. WAITNX    EQU    $+OFFSET
  1049.     CALL    DELAY    ;WAIT .1 SECONDS
  1050.     DCR    L    ;MORE TO GO?
  1051.     JNZ    WAITNX    ;YES, LOOP
  1052.     IN    RPORT    ;GET THE STATUS
  1053.     ANI    P2RDET    ;RINGING AGAIN?
  1054.     ENDIF    ;CALLBAK
  1055. ;
  1056.     IF    CALLBAK AND (WD8250 OR IN8251)
  1057.     JZ    EXPECT    ;NO?...ITS FOR ME!
  1058.     ENDIF
  1059. ;
  1060.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1061.     JNZ    EXPECT    ;NO?...ITS FOR ME!
  1062.     ENDIF
  1063. ;
  1064.     IF    CALLBAK
  1065. ;
  1066. ;If second ring, then check for third ring, in case
  1067. ;caller's phone exchange not synch'ed with computer's
  1068. ;
  1069. ENDRNG2 EQU    $+OFFSET
  1070.     IN    RPORT    ;GET THE STATUS
  1071.     ANI    P2RDET    ;STILL RINGING?
  1072.     ENDIF    ;CALLBAK
  1073. ;
  1074.     IF    CALLBAK AND (WD8250 OR IN8251)
  1075.     JZ    ENDRNG2 ;WAIT UNTIL RING FINISHED
  1076.     ENDIF
  1077. ;
  1078.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1079.     JNZ    ENDRNG2    ;WAIT UNTIL RING FINISHED
  1080.     ENDIF
  1081. ;
  1082.     IF    CALLBAK
  1083.     MVI    L,45    ;DELAY 4.5 SECONDS FOR NEXT RING
  1084. ;
  1085. WAITNX2 EQU    $+OFFSET
  1086.     CALL    DELAY    ;WAIT .1 SECONDS
  1087.     DCR    L    ;MOE TO GO?
  1088.     JNZ    WAITNX2    ;YES, LOOP
  1089.     IN    RPORT    ;GET THE STATUS
  1090.     ANI    P2RDET    ;RINGING AGAIN?
  1091.     ENDIF    ;CALLBAK
  1092. ;
  1093.     IF    CALLBAK AND (WD8250 OR IN8251)
  1094.     JZ    EXPECT    ;NO?...ITS FOR ME!
  1095.     ENDIF
  1096. ;
  1097.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1098.     JNZ    EXPECT    ;NO?...ITS FOR ME!
  1099.     ENDIF
  1100. ;
  1101.     IF    CALLBAK
  1102. ;
  1103. ;Call not for computer - wait until ringing done, then reset
  1104. ;
  1105. WAITNR    EQU    $+OFFSET
  1106.     MVI    L,100    ;WAIT FOR 10 SECS NO RINGING
  1107. ;
  1108. WAITNRL EQU    $+OFFSET
  1109.     CALL    DELAY    ;DELAY .1 SECONDS
  1110.     IN    RPORT    ;GET THE STATUS
  1111.     ANI    P2RDET    ;STILL RINGING?
  1112.     ENDIF    ;CALLBAK
  1113. ;
  1114.     IF    CALLBAK AND (WD8250 OR IN8251)
  1115.     JNZ    WAITNR    ;YES, WAIT 10 MORE SECONDS
  1116.     ENDIF
  1117. ;
  1118.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1119.     JZ    WAITNR    ;YES, WAIT 10 MORE SECONDS
  1120.     ENDIF
  1121. ;
  1122.     IF    CALLBAK
  1123.     DCR    L    ;NO RING, MAYBE WE'RE DONE
  1124.     JNZ    WAITNRL ;NO, LOOP SOME MORE
  1125.     ENDIF
  1126. ;
  1127.     IF    CALLBAK AND USRLOG
  1128.     LXI    H,NONUSR ;RECORD AS VOICE CALL
  1129.     CALL    BOPLOG    ;CALL ROUTINE TO ADD ONE
  1130.     ENDIF        ;CALLBAK AND USRLOG
  1131. ;
  1132.     IF    CALLBAK ;CONTINUE WITH CALLBAK ROUTINES
  1133.     JMP    HANGUP2    ;GO WAIT FOR NEXT CALL
  1134. ;
  1135. EXPECT    EQU    $+OFFSET
  1136.     LXI    H,400    ;40 SECONDS TO WAIT FOR SECOND CALL
  1137. ;
  1138. RELOOK    EQU    $+OFFSET
  1139.     IN    RPORT    ;GET THE STATUS
  1140.     ANI    P2RDET    ;RINGING AGAIN?
  1141.     ENDIF    ;CALLBAK
  1142. ;
  1143.     IF    CALLBAK AND (WD8250 OR IN8251)
  1144.     JNZ    ANSWER    ;YES, GO ANSWER IT
  1145.     ENDIF
  1146. ;
  1147.     IF    CALLBAK AND NOT (WD8250 OR IN8251)
  1148.     JZ    ANSWER    ;YES, GO ANSWER IT
  1149.     ENDIF
  1150. ;
  1151.     IF    CALLBAK
  1152.     CALL    DELAY    ;WAIT .1 SECOND
  1153.     DCX    H    ;ONE LESS COUNT
  1154.     MOV    A,H
  1155.     ORA    L    ;IS COUNT ZERO?
  1156.     JNZ    RELOOK    ;NO, LOOK SOME MORE
  1157.     JMP    HANGUP2    ;COUNT DONE, WAIT FOR NEW CALL
  1158. ;
  1159.     ENDIF        ;END OF CALLBAK ROUTINES
  1160. ;
  1161. ;Setup modem
  1162. ;
  1163. ANSWER    EQU    $+OFFSET
  1164. ;
  1165.     IF    ZCPRT        ;RESET WHEEL STATUS
  1166.     XRA    A        ;WHEN RUNNING ZCPR-T## FOR YOUR CCP.
  1167.     STA    WHEEL
  1168.     ENDIF    ;ZCPRT
  1169. ;
  1170.     IF    USRLOG AND PWRQD ;COUNT # OF LOGON ATTEMPTS
  1171.     LXI    H,OLDUSR    ;GET # OF ATTEMPTS
  1172.     CALL    BOPLOG        CALL ROUTINE TO ADD ONE
  1173.     ENDIF    ;USRLOG AND PWRQD
  1174. ;
  1175.     IF    DCHAYES
  1176.     MVI    A,LS1+LS2+PI+SBS ;8 DATA BITS, NO PARITY, 2 STOP BITS
  1177.     OUT    CR1
  1178.     MVI    A,TXE+OH ;TURN ON CARRIER AND ANSWER PHONE
  1179.     OUT    CR2
  1180.     IN    DATA    ;CLEAR DATA INPUT PORT
  1181.     IN    DATA    ;MAKE SURE IT'S CLEAR
  1182.     CALL    CARCK    ;LOOK FOR CARRIER
  1183.     JC    HANGUP2    ;AWAIT ANOTHER CALLER
  1184. ;
  1185. ;Now test input for baud rate
  1186.     CALL    PATCH    ;PATCH JUMP TABLE
  1187.     CALL    TSTBAUD    ;SEE IF BAUD = 110
  1188.     JZ    WELCOME    ;YES, EXIT
  1189. ;
  1190.     MVI    A,LS1+LS2+PI    ;SET FOR 1 STOP BIT, 8 DATA, NO PARITY
  1191.     OUT    CR1
  1192.     MVI    A,TXE+OH+BRS    ;SET FOR 300 BAUD
  1193.     OUT    CR2
  1194.     CALL    TSTBAUD        ;SEE IF BAUD = 300
  1195.     JZ    WELCOME        ;YES,EXIT
  1196.     ENDIF            ;DCHAYES
  1197. ;
  1198.     IF    PMMI
  1199.     MVI    A,7FH    ;TURN ON DTR
  1200.     OUT    CPORT    ;.. AND SET FILTER VALUE FOR 300 BAUD
  1201.     CALL    DELAY    ;GIVE TIME TO TURN ON
  1202.     MVI    A,P0110+P0ANSW
  1203.     OUT    TPORT    ;ANSWER PHONE
  1204.     CALL    DELAY    ;GIVE TIME FOR ANSWER
  1205.     CALL    UCSTS
  1206.     IN    DPORT    ;CLEAR MODEM PORT
  1207.     IN    DPORT    ;MAKE SURE ITS CLEAR
  1208.     MVI    A,B110    ;SET DIVISOR
  1209.     OUT    RPORT    ;.. TO 110 BAUD RATE
  1210. ;Output value allowing modem to hang up on loss of carrier
  1211.     MVI    A,P0110 ;NORMAL MODE FOR 110 BAUD
  1212.     OUT    TPORT
  1213.     CALL    CARCK    ;LOOK FOR CARRIER
  1214.     JC    HANGUP2 ;AWAIT ANOTHER CALLER
  1215. ;Now test input for baud rate
  1216.     CALL    PATCH     ;PATCH JMP TABLE
  1217.     CALL    TSTBAUD  ;SEE IF BAUD = 110
  1218.     JZ    WELCOME  ;YES, EXIT
  1219. ;
  1220.     MVI    A,P0NORM ;SET FOR 1 STOP BIT, ETC.
  1221.     OUT    TPORT
  1222.     MVI    A,B300     ;SET DIVISOR
  1223.     OUT    RPORT     ;.. TO 300 RATE
  1224.     CALL    TSTBAUD  ;SEE IF BAUD = 300
  1225.     JZ    WELCOME  ;YES, EXIT
  1226. ;
  1227.     MVI    A,B450     ;SET DIVISOR
  1228.     OUT    RPORT     ;.. TO 450 RATE
  1229.     MVI    A,5FH     ;SET FILTER VALUE
  1230.     OUT    CPORT     ;.. FOR > 300
  1231.     CALL    TSTBAUD  ;SEE IF BAUD = 450
  1232.     JZ    WELCOME  ;YES, EXIT
  1233. ;
  1234.     MVI    A,B600     ;SET DIVISOR
  1235.     OUT    RPORT     ;.. TO 600 RATE
  1236.     CALL    TSTBAUD  ;SEE IF BAUD = 600
  1237.     JZ    WELCOME  ;YES, EXIT
  1238. ;
  1239.     MVI    A,B710     ;SET DIVISOR
  1240.     OUT    RPORT     ;.. TO 710 RATE
  1241.     CALL    TSTBAUD  ;SEE IF BAUD = 710
  1242.     JZ    WELCOME  ;YES, EXIT
  1243.     ENDIF         ;PMMI
  1244. ;
  1245.     IF    IN8251
  1246.     MVI    A,BD300     ;LOAD 300 BAUD
  1247.     OUT    BPORT
  1248.     IN    DPORT     ;CLEAR
  1249.     IN    DPORT     ;DATA PORT
  1250.     MVI    A,RSTINS ;RESET USART
  1251.     OUT    CPORT
  1252.     CALL    UDELAY     ;USART DELAY
  1253.     MVI    A,MODINS1 ;1 STOP BIT, ETC.
  1254.     OUT    CPORT
  1255.     CALL    UDELAY     ;USART DELAY
  1256.     MVI    A,ONINS     ;DSR, ETC.
  1257.     OUT    CPORT
  1258.     CALL    CARCK     ;SEE IF CARRIER IS PRESENT
  1259.     JC    HANGUP2
  1260. ;Test input for baud rate
  1261.     CALL    PATCH     ;PATCH JUMP TABLE
  1262.     CALL    TSTBAUD     ;SEE IF 300 BAUD
  1263.     JZ    WELCOME     ;YES, EXIT
  1264. ;
  1265.     MVI    A,BD1200 ;LOAD 1200 BAUD
  1266.     OUT    BPORT
  1267.     CALL    TSTBAUD     ;SEE IF 1200 BAUD
  1268.     JZ    WELCOME     ;YES,EXIT
  1269. ;
  1270.     MVI    A,RSTINS ;RESET USART
  1271.     OUT    CPORT
  1272.     CALL    UDELAY     ;DELAY FOR USART
  1273.     MVI    A,MODINS2 ;2 STOP BITS, ETC.
  1274.     OUT    CPORT
  1275.     CALL    UDELAY     ;DELAY FOR USART
  1276.     MVI    A,ONINS     ;DTR, ETC.
  1277.     OUT    CPORT
  1278.     MVI    A,BD110     ;LOAD 110 BAUD
  1279.     OUT    BPORT
  1280.     CALL    TSTBAUD     ;TEST FOR 110 BAUD
  1281.     JZ    WELCOME
  1282.     ENDIF         ;IN8251
  1283. ;
  1284.     IF    WD8250 AND NOT NORING
  1285. ;
  1286.     MVI    A,MCDTR+MCRTS    ;TURN ON DATA SET, ANSWER PHONE; 
  1287.     OUT    CPORT
  1288.     ENDIF          ;WD8250 AND NOT NORING
  1289. ;
  1290.     IF    WD8250 
  1291.     MVI    A,(LCWLS0+LCWLS1) AND 0FFH ;8 BIT DATA 1 STOP BIT NO PAR
  1292.     OUT    LPORT
  1293.     CALL    PATCH    ;PATCH DRIVERS
  1294. ;
  1295. ;    BAUD RATE SELECTOR
  1296. ;
  1297. TST300:    EQU    $+OFFSET
  1298.     PUSH    D    ;SAVE D/E
  1299.     MVI    D,BR300MS
  1300.     MVI    E,BR300LS
  1301.     CALL    SETBAUD
  1302.     POP    D
  1303.     CALL    TSTBAUD
  1304.     JNZ    TST450
  1305.     CALL    TSTBAUD
  1306.     JZ    WELCOME
  1307. TST450:    EQU    $+OFFSET
  1308.     PUSH    D
  1309.     MVI    D,BR450MS
  1310.     MVI    E,BR450LS
  1311.     CALL    SETBAUD
  1312.     POP    D
  1313.     CALL    TSTBAUD
  1314.     JNZ    TST600
  1315.     CALL    TSTBAUD
  1316.     JZ    WELCOME
  1317. TST600:    EQU    $+OFFSET
  1318.     PUSH    D
  1319.     MVI    D,BR600MS
  1320.     MVI    E,BR600LS
  1321.     CALL    SETBAUD
  1322.     POP    D
  1323.     CALL    TSTBAUD
  1324.     JNZ    TST120
  1325.     CALL    TSTBAUD
  1326.     JZ    WELCOME
  1327. TST120:    EQU    $+OFFSET
  1328.     PUSH    D
  1329.     MVI    D,BR120MS
  1330.     MVI    E,BR120LS
  1331.     CALL    SETBAUD
  1332.     POP     D
  1333.     CALL    TSTBAUD
  1334.     JNZ    BADDO
  1335.     CALL    TSTBAUD
  1336.     JZ    WELCOME
  1337.     ENDIF        ;WD8250 
  1338. ;
  1339. BADDO    EQU     $+OFFSET
  1340.     CALL    UNPATCH  ;RESTORE ORIG BIOS JMP TBL
  1341.     JMP    ANSWER     ;TEST MORE - INVALID BAUD RATE
  1342. ;
  1343.     IF    IN8251
  1344. UDELAY    EQU    $+OFFSET
  1345.     NOP ! NOP ! NOP !
  1346.     RET
  1347.     ENDIF        ;IN8251
  1348. ;
  1349. ;Get the console status when unpatched
  1350. ;
  1351. UCSTS    EQU    $+OFFSET
  1352. ;
  1353.     IF    CPM2
  1354.     MVI    C,DRECTIO ;DIRECT I/O CALL
  1355.     MVI    E,0FFH      ;ASK FOR INPUT
  1356.     CALL    BDOS      ;A=0 IF NO CHAR WAITING
  1357.     RET
  1358.     ENDIF          ;CPM2
  1359. ;
  1360.     IF    NOT CPM2
  1361.     MVI    C,CSTS      ;IN CPM 1.4, WE HAVE TO GET..
  1362.     CALL    BDOS      ;..THE STATUS FIRST
  1363.     ORA    A
  1364.     RZ
  1365.     MVI    C,CI      ;AND THEN THE CHARACTER
  1366.     CALL    BDOS
  1367.     RET
  1368.     ENDIF          ;NOT CPM2
  1369.  
  1370. ;
  1371. ;Following are the USRLOG routines
  1372. ;
  1373.     IF    USRLOG     ;INCLUDE RESET FUNCTIONS
  1374. RESET    EQU    $+OFFSET ;RESET ALL LOGON COUNTERS
  1375.     LXI    H,0    ;ZEROING 16 BIT COUNTERS
  1376.     ENDIF         ;USRLOG
  1377. ;
  1378.     IF    USRLOG AND PWRQD
  1379.     SHLD    OLDUSR    ;RESET ATTEMPT COUNTER
  1380.     ENDIF        ;USRLOG AND PWRQD
  1381. ;
  1382.     IF    USRLOG
  1383.     SHLD    NEWUSR    ;RESET LOGON COUNTER
  1384.     ENDIF        ;USRLOG
  1385. ;
  1386.     IF    USRLOG AND CALLBAK
  1387.     SHLD    NONUSR    ;RESET VOICE COUNTER
  1388.     ENDIF        ;USRLOG AND CALLBAK
  1389. ;
  1390.     IF    USRLOG AND IMSAI
  1391.     MVI    A,0FFH
  1392.     OUT    SENSE    ;RESET IMSAI PANEL DISPLAY
  1393.     ENDIF        ;USRLOG AND IMSAI
  1394. ;
  1395.     IF    USRLOG
  1396.     RET
  1397.     ENDIF        ;USRLOG
  1398. ;
  1399. ;  PRNLOG is called to print out the BYE version
  1400. ; # and USRLOG info. It can be called from
  1401. ; outside the program, using the vector after
  1402. ; MCBOOT.
  1403. ;
  1404. PRNLOG    EQU    $+OFFSET
  1405. ;
  1406.     MVI    C,PRINTF ;PRINT OUT PROG VERSION #
  1407.     LXI    D,VMSG
  1408.     CALL    BDOS
  1409. ;
  1410.     IF    USRLOG AND PWRQD ;PRINT # OF LOGON ATTEMPTS
  1411.     MVI    C,PRINTF
  1412.     LXI    D,ATMSG
  1413.     CALL    BDOS
  1414.     LXI    H,OLDUSR+1 ;PT TO HIGH BYTE
  1415.     CALL    HXOUT
  1416.     ENDIF        ;USRLOG AND PWRQD
  1417. ;
  1418.     IF    USRLOG    ;PRINT # OF LOGONS
  1419.     MVI    C,PRINTF
  1420.     LXI    D,SUMSG
  1421.     CALL    BDOS
  1422.     LXI    H,NEWUSR+1
  1423.     CALL    HXOUT
  1424.     ENDIF        ;USRLOG
  1425. ;
  1426.     IF    USRLOG AND CALLBAK    ;# OF VOICE CALLS
  1427.     MVI    C,PRINTF
  1428.     LXI    D,VCMSG
  1429.     CALL    BDOS
  1430.     LXI    H,NONUSR+1
  1431.     CALL    HXOUT
  1432.     ENDIF        ;USRLOG AND CALLBAK
  1433. ;
  1434.     RET        ;IF NO LOG, NULL PRNLOG ROUTINE
  1435. ;
  1436. USRCHK    EQU    $+OFFSET
  1437.     CALL    PRNLOG    ;GIVE INFO
  1438.     MVI    C,PRINTF
  1439.     LXI    D,RS1MSG
  1440.     CALL    BDOS    ;PROMPT FOR RESUME BYE
  1441. ;
  1442. PRNREL    EQU    $+OFFSET
  1443.     CALL    UCSTS    ;GET REPLY
  1444.     ORA    A
  1445.     JZ    PRNREL    ;WAIT UNTIL ANSWERED
  1446.     CPI    'R'    ;IS ANSWER "R", FOR RESUME?
  1447.     JZ    PRNRES    ;GO DO IT IF SO
  1448.     CPI    'R'+20H    ;TAKE LOWER CASE ALSO
  1449.     JNZ    EXCPM    ;IF NOT "R", WARM BOOT CP/M
  1450. ;
  1451. PRNRES    EQU    $+OFFSET
  1452.     MVI    C,PRINTF
  1453.     LXI    D,RS2MSG
  1454.     JMP    BDOS    ;RESUME VIA BDOS AFTER MSG
  1455. ;
  1456. RS1MSG    EQU    $+OFFSET
  1457.     DB    CR,LF,CR,LF,'Type "R" to resume,'
  1458.     DB    ' anything else to warm boot: $'
  1459. RS2MSG    EQU    $+OFFSET
  1460.     DB    'Resuming...',CR,LF,'$'
  1461. ;
  1462. ;  Here to exit to CP/M
  1463. ;
  1464. EXCPM    EQU    $+OFFSET
  1465. ;
  1466.     IF CCSDISK
  1467. ;
  1468.     CALL    DSKON    ;TURN ON THE DRIVES
  1469. ;
  1470.     ENDIF    ;CCSDISK
  1471. ;
  1472.     IF BYELOW
  1473. ;
  1474.     LXI    H,OLDBD    ;RESET THE OLD BDOS JUMP IN
  1475.     SHLD    WMLOC    ;THE BIOS WARM BOOT ROUTINE
  1476. ;
  1477.     ENDIF        ;BYELOW
  1478. ;    
  1479.     JMP    0000H    ;Warm boot CP/M
  1480. ;
  1481.     IF    USRLOG
  1482. ;
  1483. ;  BOPLOG INCREMENTS THE 16 BIT COUNTER PT'ED AT BY
  1484. ; HL. IF DECIMAL SWITCH IN USE, NUMBER IS KEPT AS
  1485. ; 4 BCD DIGITS.
  1486. ;
  1487. BOPLOG    EQU    $+OFFSET
  1488.     MOV    A,M    ;GET LOW BYTE
  1489.     INR    A    ;INCREMENT
  1490.     ENDIF        ;USRLOG
  1491. ;
  1492.     IF    USRLOG AND DECIMAL
  1493.     DAA        ;DECIMAL ADJUST
  1494.     ENDIF        ;USRLOG AND DECIMAL
  1495. ;
  1496.     IF    USRLOG
  1497.     MOV    M,A    ;REPLACE LOW ORDER
  1498.     RNC        ;IF NO CARRY, BOP DONE
  1499.     INX    H    ; ELSE CARRY TO HIGH ORDER
  1500.     MOV    A,M    ;GET HIGH ORDER
  1501.     INR    A    ; AND BOP IT
  1502.     ENDIF
  1503. ;
  1504.     IF    USRLOG AND DECIMAL
  1505.     DAA        ;DECIMAL ADJUST
  1506.     ENDIF        ;USRLOG AND DECIMAL
  1507. ;
  1508.     IF    USRLOG
  1509.     MOV    M,A    ;REPLACE HIGH ORDER
  1510.     RET        ;CARRY OUT OF HIGH DROPPED
  1511.     ENDIF        ;USRLOG
  1512. ;
  1513.     IF    USRLOG AND PWRQD
  1514. ATMSG    EQU    $+OFFSET
  1515.     DB    CR,LF,'Number of logon attempts: $'
  1516.     ENDIF        ;USRLOG AND PWRQD
  1517. ;
  1518.     IF    USRLOG
  1519. SUMSG    EQU    $+OFFSET
  1520.     DB    CR,LF,'Number of logons: $'
  1521.     ENDIF        ;USRLOG
  1522. ;
  1523.     IF    USRLOG AND CALLBAK
  1524. VCMSG    EQU    $+OFFSET
  1525.     DB    CR,LF,'Number of voice calls: $'
  1526.     ENDIF        ;USRLOG AND CALLBAK
  1527. ;
  1528.     IF    USRLOG
  1529. HXOUT    EQU    $+OFFSET
  1530.     PUSH    H    ;SAVE PTR
  1531.     CALL    HXHAF    ;DO HIGH ORDER HALF OF #
  1532.     POP    H    ;RESTORE PTR
  1533.     DCX    H    ;PT TO LOW, THEN DROP
  1534.             ; IN TO DO LOW HALF
  1535. ;
  1536. HXHAF    EQU    $+OFFSET
  1537.     MOV    A,M    ;GET HALF # IN ACC
  1538.     MOV    B,A    ;SAVE NUMBER
  1539.     RAR        ;ROTATE RIGHT 4 BITS
  1540.     RAR        ;TO MAKE AN ASCII DIGIT
  1541.     RAR
  1542.     RAR
  1543.     CALL    ONEOUT    ;OUTPUT MSH TO CONSOLE
  1544.     MOV    A,B    ;GET NUMBER BACK
  1545. ;
  1546. ONEOUT    EQU    $+OFFSET
  1547.     ANI    0FH    ;GET LSH FOR OUTPUT
  1548.     ADI    90H    ;CVT TO DECIMAL ASCII
  1549.     DAA
  1550.     ACI    40H
  1551.     DAA
  1552.     PUSH    B
  1553.     MVI    C,02H
  1554.     MOV    E,A    ;OUTPUT THE NUMBER
  1555.     CALL    BDOS
  1556.     POP    B
  1557.     RET
  1558.     ENDIF        ;USRLOG
  1559. ;
  1560. ;Welcome to the system
  1561. ;
  1562. WELCOME EQU    $+OFFSET
  1563. ;
  1564.     IF CCSDISK
  1565. ;
  1566.     CALL DSKON    ;TURN ON THE DRIVES
  1567. ;
  1568.     ENDIF    ;CCSDISK
  1569. ;
  1570.     IF    CPM2
  1571.     MVI    A,MAXUSR    ;RESET MAX USER #
  1572.     STA    MXUSR
  1573.     ENDIF    ;CPM2
  1574. ;
  1575.     MVI    A,MAXDRV    ;RESET MAX DRIVE #
  1576.     STA    MXDRV
  1577. ;
  1578.     IF    TIMEOUT
  1579.     MVI    A,TOVALUE    ;RESET TIMEOUT COUNT
  1580.     STA    TOVAL
  1581.     ENDIF    ;TIMEOUT
  1582. ;
  1583.     MVI    A,5    ;Assume this many nulls
  1584.     STA    NULLS    ; in case error
  1585. ;
  1586.     IF     NOT OXGATE
  1587. ;
  1588. GETNULL EQU    $+OFFSET
  1589. ;
  1590.     CALL    ILPRT    ;PRINT THIS MSG:
  1591.     DB    CR,LF
  1592.     DB    'HOW MANY NULLS (0-9) DO YOU NEED? ',0
  1593.     CALL    MINPUT    ;GET VALUE
  1594.     MOV    C,A    ;TO C FOR MOUTPUT
  1595.     CALL    MOUTPUT ;ECHO CHAR
  1596.     MOV    A,C    ;RESTORE VALUE
  1597.     CPI    '0'
  1598.     JC    GETNULL ;BAD, RETRY
  1599.     CPI    '9'+1
  1600.     JNC    GETNULL ;BAD
  1601.     SUI    '0'    ;MAKE BINARY
  1602.     STA    NULLS    ;SAVE COUNT
  1603. ;
  1604.     ENDIF        ;NOT OXGATE
  1605. ;
  1606.     IF    TRAPLC AND (NOT OXGATE)
  1607. GETULC    EQU    $+OFFSET
  1608.     CALL    ILPRT    ;PRINT THIS MSG:
  1609.     DB    CR,LF
  1610.     DB    'CAN YOUR TERMINAL DISPLAY LOWER CASE? ',0
  1611.     MVI    A,20H    ;FORCE CASE CONVERSION FOR NOW
  1612.     STA    ULCSW
  1613.     CALL    MINPUT    ;GET Y OR NO
  1614.     MOV    C,A
  1615.     CALL    MOUTPUT ;ECHO
  1616.     MOV    A,C
  1617.     CPI    'N'
  1618.     JZ    DONEOPT ;WE'RE ALREADY SET UP FOR NO LWR CASE
  1619.     CPI    'Y'
  1620.     JNZ    GETULC    ;WASN'T Y OR N...GO ASK AGAIN
  1621.     XRA    A
  1622.     STA    ULCSW    ;SET FLAG FOR NO CONVERSION
  1623. ;
  1624. DONEOPT EQU    $+OFFSET
  1625.     ENDIF        ;TRAPLC AND (NOT OXGATE)
  1626. ;
  1627.     CALL    ILPRT
  1628.     DB    CR,LF,0
  1629. ;Print the welcome file
  1630.     LXI    H,WELFILN ;SOURCE
  1631.     LXI    D,FCB    ;DESTINATION
  1632.     MVI    B,13    ;LENGTH
  1633.     CALL    MOVE    ;MOVE THE NAME
  1634. ;Set DMA address to 80h
  1635.     LXI    D,80H
  1636.     MVI    C,STDMA
  1637.     CALL    BDOS
  1638. ;
  1639.     IF    CPM2
  1640. ;Set user number for welcome file
  1641.     MVI    C,32
  1642.     MVI    E,WELUSR
  1643.     CALL    BDOS
  1644.     ENDIF        ;CPM2
  1645. ;
  1646. ;Open the welcome file
  1647.     LXI    D,FCB
  1648.     MVI    C,OPEN
  1649.     CALL    BDOS
  1650. ;Did it exist?
  1651.     INR    A    ;A=> 0 MEANS "NO"
  1652.     JZ    PASSINT ;NO WELCOME FILE
  1653. ;Got a file, type it
  1654.     XRA    A    ;GET 0
  1655.     STA    FCBRNO    ;ZERO RECORD #
  1656.     LXI    H,100H    ;GET INITIAL BUFF POINTER
  1657. ;
  1658. ;Type the welcome file
  1659. WELTYLP EQU    $+OFFSET
  1660.     CALL    RDBYTE    ;GET A BYTE
  1661.     CPI    1AH    ;EOF?
  1662.     JZ    PASSINT ;YES, DONE
  1663.     MOV    C,A    ;SETUP FOR TYPE
  1664.     CALL    MOUTPUT ;TYPE THE CHAR
  1665.     CALL    MSTAT    ;CHECK FOR..
  1666.     ORA    A    ;CHAR TYPED?
  1667.     JZ    WELTYLP ;..NO, LOOP
  1668.     CALL    MINPUT    ;..YES, GET CHAR
  1669.     CPI    'C'-40H ;CTL-C?
  1670.     JNZ    WELTYLP ;..NO, LOOP UNTIL EOF
  1671. ;
  1672. ;Get the password
  1673. ;
  1674. PASSINT EQU    $+OFFSET
  1675. ;
  1676.     IF    PWRQD AND IMSAI AND SELPASS 
  1677.     IN    SENSE    ;TURN THE SWITCH UP..
  1678.     ANI    PWDSW    ;..TO REQUIRE THE PASSWORD
  1679.     JZ    NOPASS
  1680.     ENDIF        ;PWRQD AND IMSAI AND SELPASS
  1681. ;
  1682.     IF    PWRQD
  1683.     MVI    D,5    ;5 TRIES AT PASSWORD
  1684. ;
  1685. PASSINP EQU    $+OFFSET
  1686.     CALL    ILPRT
  1687.     DB    CR,LF,'Enter password: ',0
  1688.     LXI    H,PASSWD ;POINT TO PASSWORD
  1689.     MVI    E,0    ;NO MISSED LETTERS
  1690.     IN    DPORT    ;CLEAR OUT GARBAGE
  1691. ;
  1692. PWMLP    EQU    $+OFFSET
  1693.     CALL    MINPUT    ;GET A CHAR
  1694.     CPI    60H    ;LOWER CASE?
  1695.     JC    NOTLC    ;NO,
  1696.     ANI    5FH    ;MAKE UPPER CASE ALPHA
  1697. ;
  1698. NOTLC    EQU    $+OFFSET
  1699.     ENDIF        ;PWRQD
  1700.  
  1701.     IF    DUAL$IO AND PWRQD
  1702.     PUSH    PSW    ;SAVE CHAR INPUT
  1703.     CPI    20H    ;IS CHAR CONTROL?
  1704.     JNC    PWDIS    ;PASS IF DISPLAYABLE
  1705.     MVI    C,'^'    ;IF CONTROL,
  1706.     CALL    CONOUT    ; MAP TO UP-ARROW,
  1707.     POP    PSW    ; THEN DISPLAYABLE
  1708.     PUSH    PSW
  1709.     ADI    40H
  1710. PWDIS    EQU    $+OFFSET
  1711.     MOV    C,A
  1712.     CALL    CONOUT    ;OUTPUT CHAR LOCALLY
  1713.     POP    PSW    ;RESTORE TO ACC
  1714.     ENDIF        ;DUAL$IO AND PWRQD
  1715.  
  1716.     IF    PWRQD
  1717.     CPI    'U'-40H ;CTL-U?
  1718.     JZ    PASSINP ;YES, RE-GET IT
  1719.     CMP    M    ;MATCH PASSWORD?
  1720.     JZ    PWMAT    ;..YES
  1721.     MVI    E,1    ;..NO, SHOW MISS
  1722.     CPI    CR    ;C/R?
  1723.     JNZ    PWMLP    ;..NO, WAIT FOR C/R
  1724. ;
  1725. ;Password didn't match
  1726. ;
  1727. PWNMAT    EQU    $+OFFSET
  1728.     CALL    ILPRT
  1729.     DB    'Incorrect',CR,LF,0
  1730.     DCR    D    ;MORE TRIES?
  1731.     JNZ    PASSINP ;YES
  1732.     JMP    BADPASS ;NO, GO HANG UP
  1733. ;
  1734. ;Character matched in password
  1735. ;
  1736. PWMAT    EQU    $+OFFSET
  1737.     INX    H    ;TO NEXT CHAR
  1738.     CPI    CR    ;END?
  1739.     JNZ    PWMLP    ;..NO, LOOP
  1740. ;End of password.  Any missed chars?
  1741.     MOV    A,E    ;GET FLAG
  1742.     ORA    A
  1743.     JNZ    PWNMAT    ;NOT RIGHT
  1744. ;Password correct
  1745.     ENDIF        ;PWRQD
  1746. ;
  1747. NOPASS    EQU    $+OFFSET
  1748. ;
  1749.     IF     RTC
  1750.     CALL    ILPRT
  1751.     DB    CR,LF,CR,LF,'On at ',0
  1752.     CALL    TIME
  1753.     CALL    ILPRT
  1754.     DB    CR,LF,0
  1755.     ENDIF        ;RTC
  1756. ;
  1757. ;
  1758.     IF    USRLOG    ;COUNT # OF SUCCESSFUL LOGONS
  1759.     LXI    H,NEWUSR ;GET LAST VALUE
  1760.     CALL    BOPLOG    ;CALL ROUTINE TO ADD ONE
  1761.     ENDIF        ;USRLOG
  1762. ;
  1763.     IF    IMSAI AND USRLOG
  1764.     LDA    NEWUSR    ;RE-GET LOW ORDER VALUE
  1765.     CMA        ;INVERT FOR LIGHTS
  1766.     OUT    SENSE    ;DISPLAY ON IMSAI FRONT PANEL
  1767.     ENDIF        ;IMSAI AND USRLOG
  1768. ;
  1769.     IF    BOOTMSG
  1770. ;
  1771.     CALL    ILPRT
  1772.     DB    CR,LF
  1773.     DB    'Please Wait... ' ;BOOT MSG HERE
  1774.     DB    0
  1775.     ENDIF        ;BOOTMSG
  1776. ;
  1777.     IF    COMFILE AND CPM2
  1778.     MVI    C,32
  1779.     MVI    E,COMUSR    ;SWITCH TO COM FILE USER #
  1780.     CALL    BDOS
  1781.     ENDIF        ;COMFILE AND CPM2
  1782. ;
  1783. ;
  1784.     IF    COMFILE
  1785.     MVI    A,20H    ;FOOL THE SYSTEM
  1786.     STA    FCB+1    ;SO THAT COM FILE WILL SEE
  1787.             ;20H AT FCB+1 FOR DEFAULT PURPOSES.
  1788.     LDA    OPTION
  1789.     CPI    'A'    ;SYSOP CAN BYPASS COM FILE BY..
  1790.     JZ    0    ;..TYPING "BYE /A"
  1791.     CPI    'C'    ;OPER CAN ALSO GO TO COM..
  1792.     JNZ    RUNCOM    ;..FILE LOAD WITH "BYE /C"
  1793.     CALL    ILPRT    ;PRINT THIS MESSAGE:'
  1794.     DB    'Loading system...',CR,LF,0
  1795.     CALL    LODCOM
  1796. RUNCOM    EQU    $+OFFSET ;EVERYONE ELSE GETS COM FILE
  1797.     CALL    100H
  1798.     ENDIF        ;COMFILE
  1799. ;
  1800.     JMP    0    ;WARM BOOT NOW FOR "NORMAL" CP/M USE
  1801. ;
  1802. ;TSTBAUD attempts to read a LF or CR, returns with
  1803. ;zero flag if the character read is one of these two.
  1804. ;
  1805. TSTBAUD EQU    $+OFFSET
  1806.     CALL    MINPUT    ;GET CHARACTER FROM MODEM
  1807.     CPI    CR    ;IF A CARRIAGE RETURN...
  1808.     RZ        ;.. RETURN
  1809.     CPI    LF    ;IF A LINEFEED...
  1810.     RZ
  1811.     CPI    'C'-40H    ;IF A CONTROL C
  1812.     RET        ;RET ZERO FLAG, ELSE NOT ZERO
  1813. ;
  1814. ;**************SET WD8250  BAUD RATE************************
  1815. ;
  1816.     IF    WD8250
  1817. ;
  1818. SETBAUD: EQU    $+OFFSET
  1819.     MVI    A,83H    ;SET DLAB
  1820.     OUT    LPORT
  1821.     MOV    A,E    ;GET LSB
  1822.     OUT    DPORT
  1823.     MOV    A,D    ;GET MSB
  1824.     OUT    DPORT+1
  1825.     CPI    04H    ;110?
  1826.     JNZ    ONESTOP    
  1827.     MVI    A,LCWLS0+LCWLS1+LCSTB    ;8 DATA 2 STOP BITS
  1828.     OUT     LPORT
  1829.     JMP    DLOOP
  1830. ONESTOP: EQU    $+OFFSET
  1831.     MVI    A,LCWLS0+LCWLS1
  1832.     OUT     LPORT
  1833. DLOOP:    EQU    $+OFFSET
  1834.     XCHG        ;PUT DIVISOR IN HL
  1835.     DAD H!DAD H!DAD H!DAD H    ;MULTIPLY BY 16
  1836.                 ;SO WE DELAY APPROX 2 CHARS TIMES
  1837. DLOOP1:    EQU    $+OFFSET
  1838.     DCX    H
  1839.     MOV    A,L
  1840.     ORA    H
  1841.     JNZ    DLOOP1
  1842.     XCHG
  1843.     IN    DPORT
  1844.     IN    DPORT
  1845.     RET
  1846. ;
  1847.     ENDIF        ;WD8250
  1848. ;
  1849. ;Loss of connection test
  1850. ;
  1851. CARCK    EQU    $+OFFSET
  1852. ;
  1853.     IF    DCHAYES
  1854. ;
  1855. ;The DC Hayes has a hardware hangup feature, but we won't use it.
  1856. ;Instead, if we detect that there is no carrier upon entry to
  1857. ;this routine, we'll keep checking for 15 seconds to see if the
  1858. ;carrier returns. If so, we'll just continue on. If not, we'll
  1859. ;signal this by setting the carry flag.
  1860. ;
  1861.     IN    STATUS    ;GET MODEM STATUS
  1862.     ANI    CD    ;GOT A CARRIER?
  1863.     JNZ    CARCK2    ;YES, GO ON WITH TESTS
  1864.     PUSH    B    ;PRESERVE SO WE CAN USE IT
  1865.     MVI    B,150    ;SET FOR 15 SECONDS
  1866. ;
  1867. CARLP    EQU    $+OFFSET
  1868.     CALL    DELAY    ;WAIT .1 SECONDS
  1869.     IN    STATUS    ;GET MODEM STATUS
  1870.     ANI    CD    ;HAS CARRIER RETURNED?
  1871.     MOV    A,B    ;PRESERVE COUNTDOWN VALUE
  1872.     POP    B    ;FIX STACK IN CASE ALL IS OK
  1873.     JNZ    CARCK2    ;GOT CARRIER, CONTINUE ON
  1874.     DCR    A    ;COUNT TIME DOWN
  1875.     STC        ;IN CASE THIS IS THE END OF TIME
  1876.     RZ        ;RETURN IF TIMED OUT
  1877.     PUSH    B    ;PRESERVE B
  1878.     MOV    B,A    ;GET COUNTER VALUE IN B
  1879.     JMP    CARLP    ;KEEP CHECKING
  1880.     ENDIF        ;DCHAYES
  1881. ;
  1882.     IF    PMMI
  1883. ;
  1884. ;The PMMI modem automatically hangs up the phone after
  1885. ;15 seconds of loss of carrier, providing you output to
  1886. ;port 0 to allow it (which this program does).
  1887. ;
  1888. ;..so, this routine first checks if the modem has hung up,
  1889. ;and if so, returns with carry set.  If not, it checks for
  1890. ;carrier and returns if carrier is on; otherwise waits for
  1891. ;carrier while still testing for disconnect.
  1892. ;
  1893. ;It tests the PMMI "CTS" (clear to send) bit
  1894. ;which is 0 when there is carrier
  1895. ;
  1896.     IN    RPORT    ;GET STATUS
  1897.     ANI    P2CONN    ;CONNECTED?
  1898.     STC        ;(IN CASE NOT)
  1899.     RNZ        ;HUNG UP.
  1900. ;Still connected, check for carrier
  1901.     IN    RPORT    ;LOOK AT STATUS
  1902.     ANI    P2CTS    ;GET CARRIER DETECT BIT
  1903.     JZ    CARCK2    ;CONTINUE W/TESTS
  1904. ;Loop until either connection lost, or carrier returns
  1905.     JMP    CARCK
  1906.     ENDIF        ;PMMI
  1907. ;
  1908.     IF    IN8251
  1909. ;
  1910. ;Racal-Vadic modem automatically hangs up phone 1 second
  1911. ;after carrier loss.
  1912. ;
  1913.     IN    SPORT    ;GET STATUS
  1914.     ANI    DSR    ;CHECK IF CARRIER ON
  1915.     JNZ    CARCK2    ;YES, CONTINUE ON
  1916.     STC        ;SET CARRY BIT FOR NO CARRIER
  1917.     RET
  1918.     ENDIF        ;IN8251
  1919. ;
  1920.     IF     WD8250
  1921. ;THE WD8250 HAS HARDWARE HANGUP. BUT WE WILL USE CARRIER DETECT
  1922. ;ROUTINE TO DETERMINE CARRIER LOSS AFTER 15 SECONDS.......
  1923. ; 
  1924.     IN    MSPORT    ;GET MODEM STATUS
  1925.     ANI    P2CTS    ;GOT A CARRIER
  1926.     JNZ    CARCK2    ;YES, GO ON WITH TESTS
  1927.     PUSH    B    ;PRESERVE SO WE CAN USE IT
  1928.     MVI    B,150    ;SET FOR 15 SECONDS
  1929. ;
  1930. CARLP    EQU    $+OFFSET
  1931. ;
  1932.     CALL    DELAY    ;WAIT .1 SECOND
  1933.     IN    MSPORT    ;GET MODEM STATUS
  1934.     ANI    P2CTS    ;HAS CARRIER RETURNED ?
  1935.     MOV    A,B    ;PRESERVE COUNT DOWN VALUE
  1936.     POP    B    ;FIX STACK IF ALL IS OK
  1937.     JNZ    CARCK2    ;HAVE CARRIER - CONTINUE
  1938.     DCR    A    ;COUNT DOWN TIME
  1939.     STC        ;IN CASE THIS IS THE END OF TIME
  1940.     RZ        ;RETURN IF TIMED OUT
  1941.     PUSH    B    ;PRESERVE B
  1942.     MOV    B,A    ;GET COUNTER VALUE IN B
  1943.     JMP    CARLP    ;CONTINUE - KEEP CHECKING
  1944.     ENDIF        ;WD8250
  1945.  
  1946. ;Now test drive #'s and (if CP/M 2.x) user #'s to
  1947. ;insure that maximums are not exceeded.
  1948. ;
  1949. CARCK2    EQU    $+OFFSET
  1950.     LDA    4    ;CHECK DISK/USER #
  1951.     ANI    0FH    ;ISOLATE DRIVE
  1952.     PUSH    H    ;SAVE HL
  1953.     LXI    H,MXDRV    ;PT TO ALLOWED # DRIVES
  1954.     CMP    M    ;VALID DRIVE?
  1955.     JC    CARCK3    ;YES, SKIP THIS JUNK
  1956.     LDA    4    ;GET WHOLE LOGIN BYTE
  1957.     ANI    0F0H    ;RETAIN USER # & FORCE DRIVE TO A
  1958.     STA    4    ;UPDATE LOGIN BYTE
  1959.     CALL    ILPRT    ;TELL USER WHAT HE DID
  1960.     DB    'A>',0
  1961.     JMP    0    ;WARM BOOT
  1962. ;
  1963. CARCK3    EQU    $+OFFSET
  1964. ;
  1965.     IF    CPM2
  1966.     LDA    4    ;GET LOGIN BYTE
  1967.     ANI    0F0H    ;ISOLATE USER #
  1968.     RRC        ;MOVE TO LOW BITS
  1969.     RRC
  1970.     RRC
  1971.     RRC
  1972.     LXI    H,MXUSR    ;PT TO MAX USER #
  1973.     CMP    M    ;VALID USER #?
  1974.     JC    CARCK4    ;YES, DON'T CHANGE
  1975.     JZ    CARCK4
  1976.     LDA    4    ;GET LOGIN BYTE AGAIN
  1977.     ANI    0FH    ;KEEP DRIVE, ZERO USER
  1978.     STA    4    ;UPDATE LOGIN BYTE
  1979.     CALL    ILPRT    ;TELL HIM WHAT HAPPENED
  1980.     DB    '> [Invalid user number, returning to 0]',0
  1981.     JMP    0    ;WARM BOOT
  1982.     ENDIF        ;CPM2
  1983. ;
  1984. CARCK4    EQU    $+OFFSET
  1985.     POP    H    ;RESTORE HL
  1986.     ORA    A
  1987.     RET
  1988. ;
  1989. ;.1 sec delay routine
  1990. ;
  1991. DELAY    EQU    $+OFFSET
  1992.     PUSH    B
  1993. ;
  1994.     IF    FASTCLK
  1995.     LXI    B,16667 ;4 MHZ TIMING CONSTANT
  1996.     ENDIF
  1997. ;
  1998.     IF    NOT FASTCLK
  1999.     LXI    B,8334    ;2 MHZ TIMING CONSTANT
  2000.     ENDIF
  2001. ;
  2002. DELAY1    EQU    $+OFFSET
  2003.     DCX    B
  2004.     MOV    A,B
  2005.     ORA    C
  2006.     JNZ    DELAY1
  2007.     POP    B
  2008.     RET
  2009. ;
  2010. ;50 ms delay routine
  2011. ;
  2012. KDELAY    EQU    $+OFFSET
  2013.     PUSH    B
  2014. ;
  2015.     IF    FASTCLK
  2016.     LXI    B,8334
  2017.     ENDIF
  2018. ;
  2019.     IF    NOT FASTCLK
  2020.     LXI    B,4167
  2021.     ENDIF
  2022. ;
  2023.     JMP    DELAY1
  2024. ;
  2025. ;Patch in the new JMP table (saving the old)
  2026. ;
  2027. PATCH    EQU    $+OFFSET
  2028.     CALL    TBLADDR        ;CALC HL= CP/M JMP TABLE
  2029.     LXI    D,VCOLDBT    ;POINT TO SAVE LOCATION
  2030.     MVI    B,24        ;SAVE ALL VECTORS
  2031.     CALL    MOVE        ;MOVE IT
  2032. ;Now move new JMP table to CP/M
  2033.     CALL    TBLADDR        ;CALC HL=CP/M'S JMP TABLE
  2034.     XCHG            ;MOVE TO DE
  2035.     LXI    H,NEWJTBL    ;POINT TO NEW
  2036.     CALL    MOVE        ;MOVE IT
  2037. ;
  2038.     IF    IN8251
  2039.     LXI    H,NWBCALL    ;POINT TO NEW CALL
  2040.     SHLD    WBCALL+1    ;MODIFY CALL IN BIOS
  2041.     ENDIF            ;IN8251
  2042. ;
  2043.     RET
  2044. ;
  2045. UNPATCH EQU    $+OFFSET
  2046.     CALL    TBLADDR        ;HL=CP/M'S JMP TABLE
  2047.     XCHG            ;MOVE TO DE
  2048.     LXI    H,VCOLDBT    ;GET SAVED TABLE
  2049.     CALL    MOVE        ;MOVE ORIG BACK
  2050. ;
  2051.     IF    LOSER
  2052.     LXI    H,WMSTRT    ;LOAD OLD CALL LOCATION
  2053.     SHLD    WBCALL+1    ;RESTORE OLD CALL
  2054.     ENDIF            ;LOSER
  2055. ;
  2056.     RET            
  2057. ;
  2058. ;Calculate HL=CP/M's jump table, B=length
  2059. ;
  2060. TBLADDR EQU    $+OFFSET
  2061.     LHLD    1    ;GET BIOS POINTER
  2062.     DCX    H    ;..SKIP
  2063.     DCX    H    ;..TO
  2064.     DCX    H    ;..COLD BOOT
  2065. ;
  2066.     IF    (NOT PRINTER) and (NOT ALLDEV)
  2067.     MVI    B,18    ;BYTES TO MOVE
  2068.     ENDIF        ;NOT PRINTER AND NOT ALLDEV
  2069. ;
  2070.     IF    PRINTER ;RETAIN LIST DEVICE?
  2071.     MVI    B,15    ;DON'T MOVE LISTER JUMP
  2072.     ENDIF        ;PRINTER
  2073. ;
  2074.     IF    ALLDEV    ;THIS PATCHES ALL DEVICES TO PHONE
  2075.     MVI    B,24    ;MOVE ALL JUMPS
  2076.     ENDIF        ;ALLDEV
  2077.  
  2078.     RET
  2079. ;
  2080. ;Move (HL) to (DE), length in (B)
  2081. ;
  2082. MOVE    EQU    $+OFFSET
  2083.     MOV    A,M    ;GET A BYTE
  2084.     STAX    D    ;PUT AT NEW HOME
  2085.     INX    D    ;BUMP POINTERS
  2086.     INX    H
  2087.     DCR    B    ;DEC BYTE COUNT
  2088.     JNZ    MOVE    ;IF MORE, DO IT
  2089.     RET        ;IF NOT,RETURN
  2090. ;
  2091.     IF    LOSER
  2092. NWBCALL    EQU    $+OFFSET
  2093.     CALL    WMSTRT    ;WARM BOOT DISK READ
  2094.     CALL    PATCH    ;FIX BIOS AGAIN AFTER WMSTRT
  2095.     RET
  2096.     ENDIF        ;LOSER
  2097. ;
  2098. ;Common routine to check for carrier lost, called from console out
  2099. ;
  2100. CHECK    EQU    $+OFFSET
  2101. ;
  2102.     IF    MINICK
  2103. ;
  2104.     LDA    IOBYTE    ;GET IOBYTE
  2105.     ANI    80H    ;TEST FOR DISK UPDATE
  2106.     RTN        ;BUSY WAIT UNTIL DONE
  2107. ;
  2108.     ENDIF        ;MINICK
  2109. ;
  2110.     IF    RBBSCK
  2111. ;
  2112.     LDA    WRTLOC    ;GET WRITE IN PROGRESS FLAG
  2113.     ORA    A
  2114.     RNZ        ;BUSY WAIT UNTIL DONE
  2115. ;
  2116.     ENDIF        ;RBBSCK
  2117. ;
  2118.     CALL    CARCK    ;SEE IF CARRIER STILL ON
  2119.     RNC        ;ALL OK
  2120. ;
  2121. ;Carrier is lost.  Type message so local console shows the reason
  2122. ;
  2123. BADPASS EQU    $+OFFSET ;COME HERE ON BAD PASSWORD
  2124.     MVI    A,1    ;SHOW CARRIER LOST SO
  2125.     STA    LOSTFLG ;..WE WON'T CK AGAIN
  2126.     LXI    SP,STACK ;ENSURE VALID STACK
  2127.     CALL    ILPRT
  2128.     DB    CR,LF
  2129.     DB    '[Carrier Lost]'
  2130.     DB    CR,LF,'   ',0
  2131.     CALL    UNPATCH ;RESTORE ORIG BIOS JMP TBL
  2132.     XRA    A    ;CLEAR OUT CARRIER..
  2133.     STA    LOSTFLG ;..LOST FLAG
  2134.     JMP    HANGUP
  2135. ;
  2136. ;Readbyte routine - used to read the welcome file
  2137. ;
  2138. RDBYTE    EQU    $+OFFSET
  2139.     MOV    A,H    ;TIME TO READ?
  2140.     ORA    A    ;..IF AT 100H
  2141.     JZ    NORD    ;NO READ REQ'D
  2142. ;Have to read a sector
  2143.     LXI    D,FCB
  2144.     MVI    C,READ
  2145.     CALL    BDOS
  2146.     ORA    A    ;OK?
  2147.     MVI    A,1AH    ;FAKE UP EOF
  2148.     RNZ        ;RET EOF IF BAD
  2149.     LXI    H,80H
  2150. ;
  2151. NORD    EQU    $+OFFSET
  2152.     MOV    A,M    ;GET CHAR
  2153.     INX    H    ;TO NEXT
  2154.     RET
  2155. ;
  2156. ;Keyboard/modem status test routine
  2157. ;
  2158. MSTAT    EQU    $+OFFSET
  2159. ;
  2160.     CALL    CHECK    ;CHECK FOR CARRIER LOST
  2161. ;
  2162.     IF    DUAL$IO ;WANT LOCAL CONSOLE?
  2163.     CALL    CONSTAT ;GET LOCAL STATUS
  2164.     ORA    A
  2165.     RNZ        ;RET IF LOCAL CHAR
  2166.     ENDIF        ;DUAL$IO
  2167. ;
  2168.     IF    DCHAYES
  2169.     IN    STATUS    ;GET MODEM STATUS
  2170.     ANI    RRF    ;GOT A CHARACTER?
  2171.     RZ        ;RETURN IF NOT
  2172.     IN    STATUS    ;GET MODEM STATUS
  2173.     ANI    FE+OE    ;CHECK FOR FRAMING AND OVERRUN ERROR
  2174.     JZ    MSTAT1    ;NO ERROR, CHARACTER IS VALID
  2175.     IN    DATA    ;SWALLOW CHARACTER (ALSO CLEAR OE & FE)
  2176.     XRA    A    ;RETURN FALSE
  2177.     RET
  2178.     ENDIF        ;DCHAYES
  2179. ;
  2180.     IF    PMMI
  2181.     IN    TPORT    ;GET STATUS
  2182.     ANI    P0DAV    ;DATA AVAILABLE?
  2183.     RZ        ;RETURN IF NOT READY
  2184.     IN    TPORT    ;GET STATUS
  2185.     ANI    30H    ;CHECK FRAMING AND OVERRUN BITS
  2186.     JZ    MSTAT1    ;NO ERRORS...LEGIT CHARACTER
  2187.     IN    DPORT    ;SWALLOW CHARACTER (CLEARS PODAV)
  2188.     XRA    A    ;RETURN FALSE
  2189.     RET
  2190.     ENDIF        ;PMMI
  2191. ;
  2192.     IF    IN8251
  2193.     IN    SPORT    ;GET STATUS
  2194.     ANI    RCVRDY    ;GOT A CHARACTER
  2195.     RZ        ;RETURN IF NOT
  2196.     IN    SPORT    ;GET STATUS
  2197.     ANI    TOERR    ;CHECK FOR PARITY, FRAMING AND OVERRUN ERRORS
  2198.     JZ    MSTAT1    ;NO ERRORS
  2199.     MVI    A,ONINS    ;RESET ERROR FLAGS
  2200.     OUT    CPORT
  2201.     XRA    A    ;RETURN    FALSE
  2202.     RET
  2203.     ENDIF        ;IN8251
  2204. ;
  2205.     IF    WD8250 
  2206.     IN    SPORT    ;GET STATUS
  2207.     ANI    P0DAV    ;DATA AVAILABLE
  2208.     RZ        ;RTN IF NOT RDY
  2209.     IN    SPORT    ;GET STATUS
  2210.     ANI    0EH    ;CHECK PAR, FRAM ERR AND OVRN BITS
  2211.     JZ    MSTAT1
  2212.     IN    DPORT
  2213.     XRA    A    ;RTN FALSE
  2214.     RET
  2215.     ENDIF        ;WD8250 
  2216. MSTAT1    EQU    $+OFFSET
  2217.     MVI    A,0FFH    ;SHOW READY
  2218.     ORA    A
  2219.     RET
  2220. ;
  2221. ;Modem input function, checks local console first
  2222. ;
  2223. MINPUT    EQU    $+OFFSET
  2224. ;
  2225.     IF    TIMEOUT
  2226.     LDA    TOVAL    ;GET # MINUTES BEFORE TIMEOUT
  2227. ;
  2228. MINPUT0    EQU    $+OFFSET
  2229.     STA    TOCNTM    ;SET MINUTES COUNTER
  2230.     PUSH    H
  2231.     LXI    H,MINUTES ;INIT ONE MINUTE TIMEOUT COUNTER
  2232.     SHLD    TOCNT
  2233.     POP    H
  2234.     ENDIF        ;TIMEOUT
  2235. ;
  2236. MINPUT1 EQU    $+OFFSET
  2237.     LDA    LOSTFLG ;KNOWN LOSS..
  2238.     ORA    A    ;..OF CARRIER?
  2239.     CZ    CHECK    ;CARRIER STILL ON?
  2240.     CALL    MSTAT    ;ANYTHING?
  2241.     ORA    A
  2242. ;
  2243.     IF    NOT TIMEOUT
  2244.     JZ    MINPUT    ;LOOP TILL CHAR RCD
  2245.     ENDIF        ;NOT TIMEOUT
  2246. ;
  2247.     IF    TIMEOUT
  2248.     JNZ    MINPUT2
  2249.     CALL    KDELAY    ;KILL 50 MS
  2250.     PUSH    H
  2251.     LHLD    TOCNT    ;KNOCK DOWN TIMEOUT COUNTER
  2252.     DCX    H
  2253.     SHLD    TOCNT
  2254.     MOV    A,H
  2255.     ORA    L
  2256.     POP    H
  2257.     JNZ    MINPUT1 ;STILL TIME LEFT..KEEP TRYING
  2258.     LDA    TOCNTM    ;COUNT OFF LAST MINUTE
  2259.     DCR    A
  2260.     JNZ    MINPUT0    ;GO BACK IF TIME LEFT
  2261.     CALL    ILPRT
  2262.     DB    '[Input timed out]',7,7,0
  2263.     JMP    NOSLASH
  2264.     ENDIF        ;TIMEOUT
  2265. ;
  2266. MINPUT2 EQU    $+OFFSET
  2267. ;
  2268.     IF    DUAL$IO ;BOTH LOCAL AND REMOTE
  2269.     CALL    CONSTAT ;CHECK LOCAL CONSOLE
  2270.     ORA    A    ;CHAR?
  2271.     JNZ    CONIN    ;..YES, READ IT, RET.
  2272.     ENDIF
  2273. ;
  2274. ;Local console wasn't ready, so read modem
  2275. ;
  2276.     IN    DPORT    ;GET DATA BYTE
  2277.     ANI    7FH    ;DELETE PARITY
  2278.     JZ    MINPUT    ;IGNORE NULLS
  2279. ;
  2280.     IF    IMSAI AND HARDLOG
  2281.     PUSH    B
  2282.     MOV    B,A
  2283.     IN    SENSE
  2284.     ANI    LOGSW
  2285.     MOV    A,B
  2286.     POP    B
  2287.     JZ    NOLOG
  2288.     ENDIF        ;IMSAI AND HARDLOG
  2289. ;
  2290.     IF    HARDLOG
  2291.     CPI    20H
  2292.     JNC    MINPUT3
  2293.     CPI    CR
  2294.     JNZ    NOLOG
  2295. ;
  2296. MINPUT3    EQU    $+OFFSET
  2297.     CALL    LISTOUT ;ECHO ON PRINTER
  2298.     CPI    CR
  2299.     JNZ    NOLOG    ;CR NEEDS LINEFEED
  2300.     MVI    A,LF
  2301.     CALL    LISTOUT ;SO SEND IT
  2302.     MVI    A,CR    ;GET BACK CR
  2303.     ENDIF        ;END OF HARDLOG
  2304. ;
  2305. NOLOG    EQU    $+OFFSET
  2306. ;
  2307.     CPI    3    ;IS IT CONTROL-C?
  2308.     RNZ        ;NO, PASS IT THRU
  2309.     LDA    0    ;SEE IF WARM BOOT DISABLED
  2310.     CPI    0C3H    ;JMP MEANS WARM BOOT OK
  2311.     MVI    A,3    ;SO RETURN CONTROL-C
  2312.     RZ
  2313.     XRA    A    ;ELSE CONVERT TO NULL
  2314.     RET
  2315. ;
  2316. ;Modem output function
  2317. ;
  2318. MOUTPUT EQU    $+OFFSET
  2319. ;
  2320. ;If we already know carrier is lost, don't check
  2321. ;for it again or loop trying to output.
  2322. ;
  2323.     LDA    LOSTFLG ;KNOWN LOSS OF CARRIER?
  2324.     ORA    A
  2325.     JNZ    SILENT    ;AVOID LOOP IN CASE CARRIER LOST
  2326.     CALL    CHECK    ;CARRIER STILL ON?
  2327. ;
  2328.     IF    DCHAYES
  2329.     IN    STATUS    ;GET MODEM STATUS
  2330.     ANI    TRE    ;TRANSMIT BUFFER EMPTY?
  2331.     ENDIF        ;DCHAYES
  2332. ;
  2333.     IF    PMMI
  2334.     IN    TPORT    ;GET MODEM STATUS
  2335.     ANI    P0TBMT    ;TRANSMIT BUFFER EMPTY?
  2336.     ENDIF        ;PMMI
  2337. ;
  2338.     IF    IN8251
  2339.     IN    SPORT    ;GET MODEM STATUS
  2340.     ANI    TRNRDY    ;TRANSMIT BUFFER EMPTY?
  2341.     ENDIF        ;IN8251
  2342. ;
  2343.     IF    WD8250 
  2344.     IN    SPORT
  2345.     ANI    P0TBMT
  2346.     ENDIF        ;WD8250 
  2347. ;
  2348.     JZ    MOUTPUT ;LOOP IF NOT READY
  2349. ;
  2350.     IF    IMSAI AND BLKOUT AND DUAL$IO
  2351.     IN    SENSE    ;FLIP SWITCH UP...
  2352.     ANI    BLACKSW ;..TO BLIND REMOTE USER
  2353.     JNZ    SILENT
  2354.     ENDIF        ;IMSAI AND BLKOUT AND DUAL$IO
  2355. ;
  2356.     MOV    A,C    ;GET CHAR
  2357.     ANI    7FH    ;STRIP PARITY BIT
  2358. ;
  2359.     IF    TRAPLC
  2360.     CPI    60H    ;CHECK FOR LOWER CASE
  2361.     JC    MOUTP2    ;SKIP IF NOT LC
  2362.     CPI    7FH    ;CHECK FOR RUBOUT
  2363.     JZ    MOUTP2
  2364.     PUSH    H
  2365.     LXI    H,ULCSW ;SUBTRACT EITHER 20H OR 0
  2366.     SUB    M
  2367.     POP    H
  2368.     MOV    C,A    ;FORCE ON LOCAL AS WELL AS REMOTE
  2369. ;
  2370. MOUTP2    EQU    $+OFFSET
  2371.     ENDIF        ;TRAPLC
  2372. ;
  2373.     OUT    DPORT    ;OUTPUT TO MODEM
  2374. ;
  2375. SILENT    EQU    $+OFFSET
  2376. ;
  2377.     IF    DUAL$IO ;TO LOCAL ALSO?
  2378.     PUSH    PSW    ;SAVE CHAR
  2379.     CALL    CONOUT    ;SEND TO REGULAR BIOS
  2380.     POP    PSW    ;GET CHAR AGAIN
  2381.     ENDIF        ;DUAL$IO
  2382. ;
  2383. ;Check for nulls
  2384.     CPI    LF    ;TIME FOR NULLS?
  2385.     RNZ        ;NO, RETURN
  2386. ;Send nulls if required
  2387.     LDA    NULLS    ;GET COUNT
  2388.     ORA    A    ;ANY?
  2389.     RZ        ;..NO
  2390.     PUSH    B
  2391.     MOV    B,A    ;SAVE COUNT
  2392.     MVI    C,0    ;0 IS A NULL
  2393. ;
  2394. NULLP    EQU    $+OFFSET
  2395.     CALL    MOUTPUT ;TYPE A NULL
  2396.     DCR    B    ;MORE?
  2397.     JNZ    NULLP    ;..YES, LOOP
  2398.     POP    B
  2399.     MVI    C,LF    ;RESTORE LF
  2400.     RET
  2401. ;
  2402. ;Boot trap - becomes disconnect if JMP at 0 has been altered
  2403. ;
  2404. MBOOT    EQU    $+OFFSET
  2405.     LDA    0    ;LOOK AT OPCODE
  2406.     CPI    0C3H    ;IS IT STILL JMP?
  2407.     JZ    VWARMBT ;YES, ALLOW IT
  2408.     JMP    NOSLASH ;NO, DISCONNECT
  2409. ;
  2410. ;Inline print routine
  2411. ;
  2412. ILPRT    EQU    $+OFFSET
  2413.     XTHL        ;SAVE HL, GET MSG
  2414.     PUSH    B    ;SAVE BC REGS
  2415. ;
  2416. ILPLP    EQU    $+OFFSET
  2417.     MOV    C,M    ;GET CHAR
  2418.     CALL    MOUTPUT ;OUTPUT IT
  2419.     INX    H    ;POINT TO NEXT
  2420.     MOV    A,M    ;TEST
  2421.     ORA    A    ;..FOR END
  2422.     JNZ    ILPLP
  2423.     POP    B    ;RESTORE BC REGS
  2424.     XTHL        ;RESTORE HL, RET ADDR
  2425.     RET        ;RET PAST MSG
  2426. ;
  2427.     IF    PWRQD    ;KEEP PASSWORD HERE
  2428. ;Access password (ends in carriage return)
  2429. ;
  2430. PASSWD    EQU    $+OFFSET
  2431.     DB    'TWIT'    ;THE PASSWORD ITSELF
  2432.     DB    CR    ;END OF PASSWORD
  2433. ;Allow room for bigger password to be patched in
  2434.     DB    0,0,0,0,0,0,0,0,0,0,0,0,0
  2435.     ENDIF        ;PWRQD
  2436. ;
  2437. ;Routine to load the COM file
  2438. ;
  2439.     IF    COMFILE
  2440. LODCOM    EQU    $+OFFSET
  2441.     XRA    A    ;INITIALIZE FCB
  2442.     STA    COMFCB
  2443.     LXI    H,COMFCB+12
  2444.     MVI    B,21
  2445. ;
  2446. ZLOOP    EQU    $+OFFSET
  2447.     MVI    M,0
  2448.     INX    H
  2449.     DCR    B
  2450.     JNZ    ZLOOP
  2451. ;
  2452.     MVI    C,OPEN    ;NOW OPEN THE FILE
  2453.     LXI    D,COMFCB
  2454.     CALL    BDOS
  2455.     INR    A    ;SHOULD BE NON-ZERO
  2456.     JZ    ABORT    ;NO FILE, ABORT
  2457. ;
  2458. ;Now load the file
  2459.     LHLD    6    ;GET TOP OF MEMORY
  2460.     LXI    D,-80H    ;RECORD LOADS CAN'T START..
  2461.     DAD    D    ;..ABOVE (BDOS) - 80H
  2462.     PUSH    H    ;SAVE ON STACK
  2463. ;
  2464.     LXI    D,80H    ;TPA-80H
  2465.     LXI    B,0    ;KEEP A RECORD COUNTER
  2466.     PUSH    B    ;SAVE COUNTER
  2467.     PUSH    D    ;AND LOAD ADDRESS
  2468. ;
  2469. GLOOP    EQU    $+OFFSET
  2470.     POP    D    ;GET TPA ADRS
  2471.     LXI    H,80H    ;POINT TO NXT ADRS TO READ TO
  2472.     DAD    D    ;HL HAS THE ADDRESS
  2473.     POP    B    ;INCREMENT THE COUNTER
  2474. ;Check for load past top-of-memory
  2475.     POP    D    ;GET (TOP-OF-MEMORY)
  2476.     PUSH    D    ;RE-SAVE FOR NEXT TIME
  2477.     MOV    A,E    ;SUBTRACT: (TOP) - (ADRS)
  2478.     SUB    L
  2479.     MOV    A,D    ;ONLY THE CARRY NEEDED
  2480.     SBB    H
  2481.     JNC    SIZEOK    ;CY= BETTER MOVCPM
  2482.     CALL    ERRXIT    ;SO TELL THE STORY
  2483.     DB    '[Program area too small]','$'
  2484. ;
  2485. SIZEOK    EQU    $+OFFSET
  2486.     INX    B
  2487.     PUSH    B
  2488.     PUSH    H    ;SAVE TPA ADRS
  2489.     XCHG        ;ALIGN REGISTERS
  2490.     MVI    C,STDMA ;TELL BDOS WHERE TO PUT RECORD
  2491.     CALL    BDOS
  2492.     LXI    D,COMFCB ;NOW READ THE RECORD
  2493.     MVI    C,READ
  2494.     CALL    BDOS
  2495.     ORA    A
  2496.     JZ    GLOOP    ;A=0 IF MORE TO READ
  2497.     POP    B    ;UNJUNK STACK
  2498.     POP    B    ;THIS IS OUR COUNTER
  2499.     POP    H    ;MORE JUNK ON STACK
  2500.     MOV    A,B    ;CHECK FOR ZERO
  2501.     ORA    C
  2502.     JZ    ABORT    ;WE SHOULD HAVE READ SOMETHING
  2503.     LXI    D,80H    ;WE DID, RESET DMA TO 80H
  2504.     MVI    C,STDMA
  2505.     CALL    BDOS
  2506.     CALL    LOADOK    ;PRINT THIS MSG TO CONSOLE:
  2507.     DB    'COM file loaded',CR,LF,'$'
  2508. ;
  2509. LOADOK    EQU    $+OFFSET
  2510.     POP    D
  2511.     LDA    OPTION    ;SEE IF THIS WAS "BYE /C"
  2512.     CPI    'C'    ;IF IT WAS THEN..
  2513.     RZ        ;..DON'T PRINT MESSAGE
  2514.     MVI    C,PRINTF
  2515.     CALL    BDOS
  2516.     RET
  2517. ;
  2518. ABORT    EQU    $+OFFSET
  2519.     CALL    ERRXIT
  2520.     DB    CR,LF
  2521.     DB    '[Cannot find COM file]','$'
  2522. ;
  2523. ERRXIT    EQU    $+OFFSET
  2524.     POP    D
  2525.     MVI    C,PRINTF
  2526.     CALL    BDOS    ;PRINT THE ABORT MSG
  2527.     JMP    EXCPM    ;WARM BOOT
  2528.     ENDIF        ;COMFILE
  2529. ;
  2530. ;This area is used for vectoring calls to the
  2531. ;user's CBIOS, but saving the registers first
  2532. ;in case they are destroyed.
  2533. ;
  2534. CONSTAT EQU    $+OFFSET
  2535.     PUSH    B
  2536.     PUSH    D
  2537.     PUSH    H
  2538.     CALL    VCONSTAT
  2539.     POP    H
  2540.     POP    D
  2541.     POP    B
  2542.     RET
  2543. ;
  2544. CONIN    EQU    $+OFFSET
  2545.     PUSH    B
  2546.     PUSH    D
  2547.     PUSH    H
  2548.     CALL    VCONIN
  2549. ;
  2550.     IF    FKEYS
  2551.     CALL    CKFUNC
  2552.     ENDIF        ;FKEYS
  2553. ;
  2554.     POP    H
  2555.     POP    D
  2556.     POP    B
  2557.     RET
  2558. ;
  2559. CKFUNC    EQU    $+OFFSET
  2560. ;
  2561.     IF    FKEYS AND IMSAI
  2562.     PUSH    B
  2563.     MOV    B,A    ;SAVE CHAR
  2564.     IN    SENSE    ;READ THE SWITCHES
  2565.     ANI    ENABLF    ;CHECK FKEY ENAB SW
  2566.     MOV    A,B    ;GET CHAR
  2567.     POP    B
  2568.     RZ        ;NO FUNCT IF SW OFF
  2569.     ENDIF        ;FKEYS AND IMSAI
  2570. ;
  2571.     IF    OXGATE
  2572.     CPI    LF    ;WE HAVE A TOGGLE FOR LINE FEEDS
  2573.     JNZ    MOUTP3    ;NOPE, NOT A LF
  2574.     LDA    LFEEDS    ;YES, SEE IF WE CAN SEND IT...
  2575.     ORA    A
  2576.     MVI    A,0
  2577.     RNZ        ;NOPE, DON'T!
  2578.     MVI    A,LF
  2579. MOUTP3    EQU    $+OFFSET
  2580.     ENDIF        ;OXGATE
  2581. ;
  2582.     IF    FKEYS
  2583.     CPI    SYSDKEY
  2584.     JZ    SYSDOWN ;TELL CALLER TO LEAVE
  2585.     CPI    TWITKEY
  2586.     JZ    GOODBY    ;MAKE CALLER LEAVE
  2587.     CPI    MSGKEY
  2588.     RNZ
  2589.     CALL    ILPRT    ;SEND CALLER A MESSAGE
  2590.     DB    'Message from Sysop:',0
  2591.     MVI    A,' '    ;SOMETHING TO RETURN WITH
  2592.     RET
  2593. ;
  2594. SYSDOWN EQU    $+OFFSET
  2595.     CALL    ILPRT
  2596.     DB    'System going down in'
  2597.     DB    ' 5 minutes...',0
  2598.     MVI    A,' '
  2599.     RET
  2600.     ENDIF        ;FKEYS
  2601. ;
  2602. CONOUT    EQU    $+OFFSET
  2603.     PUSH    B
  2604.     PUSH    D
  2605.     PUSH    H
  2606.     CALL    VCONOUT
  2607.     POP    H
  2608.     POP    D
  2609.     POP    B
  2610.     RET
  2611. ;
  2612. LISTOUT    EQU    $+OFFSET
  2613.     PUSH    B
  2614.     PUSH    D
  2615.     PUSH    H
  2616.     PUSH    PSW
  2617.     MOV    C,A
  2618.     CALL    VLISTOUT
  2619.     POP    PSW
  2620.     POP    H
  2621.     POP    D
  2622.     POP    B
  2623.     RET
  2624. ;
  2625. ;This is the JMP table which is copied on top
  2626. ;of the one pointed to by location 1 in CP/M
  2627. ;
  2628. NEWJTBL EQU    $+OFFSET
  2629.     JMP    MCBOOT    ;COLD BOOT
  2630.     JMP    MBOOT    ;WARM BOOT
  2631.     JMP    MSTAT    ;MODEM STATUS TEST
  2632.     JMP    MINPUT    ;MODEM INPUT ROUTINE
  2633.     JMP    MOUTPUT ;MODEM OUTPUT ROUTINE
  2634.     IF    NOT ALLDEV
  2635.     RET        ;DUMMY LIST DEVICE
  2636.     NOP
  2637.     NOP
  2638.     ENDIF        ;NOT ALLDEV
  2639. ;
  2640.     IF    ALLDEV
  2641.     JMP    MOUTPUT    ;MODEM LIST DEVICE
  2642.     JMP    MOUTPUT    ;MODEM PUNCH DEVICE
  2643.     JMP    MINPUT    ;MODEM READER DEVICE
  2644.     ENDIF        ;ALLDEV
  2645. ;
  2646.     IF CCSDISK
  2647. ;
  2648. DSKON    EQU    $+OFFSET
  2649.     PUSH PSW    ;SAVE THE A AND FLAGS
  2650.     MVI A,DISKON    ;VALUE TO TURN ON MOTORS
  2651.     OUT DISK    ;TO THE DISK CONTROLLER
  2652.     PUSH H        ;THIS IS TIMER
  2653.     LXI H,0000H    ;THIS LONG
  2654. DSKLP    EQU    $+OFFSET
  2655.     XTHL
  2656.     XTHL
  2657.     DCX H        ;COUNT LOOP
  2658.     MOV A,H        ;CHECK FOR DONE
  2659.     ORA L
  2660.     JNZ DSKLP
  2661.     POP H        ;RESTORE HL
  2662.     POP PSW        ;AND A & FLAGS
  2663.     RET
  2664. ;
  2665. DSKOFF    EQU    $+OFFSET
  2666.     PUSH PSW    ;SAVE A & FLAG
  2667.     MVI A,DISKOFF    ;VALUE TO TURN MOTORS OFF
  2668.     OUT DISK
  2669.     POP PSW
  2670.     RET
  2671. ;
  2672.     ENDIF        ;CCSDISK
  2673. ;
  2674. IF     RTC
  2675. CLKBASE    EQU    50H    ;BASE OF SYSTEM SUPPORT 1 CARD
  2676. CLKCTL    EQU CLKBASE+10    ;CLOCK CONTROL PORT
  2677. CLKDATA    EQU CLKBASE+11    ;CLOCK DATA PORT
  2678. CREAD    EQU    10H+40H    ;READ COMMAND + HOLD COUNT COMMAND
  2679. ;
  2680. TIME    EQU    $+OFFSET
  2681.     PUSH H
  2682.     PUSH D
  2683.     PUSH B
  2684.     PUSH PSW
  2685.     MVI D,CREAD+5    ;POINT TO 10S OF HOURS
  2686.     MVI B,3        ;3 LOOPS
  2687.     JMP TX        ;START W/ NO SEPARATOR
  2688. ;
  2689. T1    EQU    $+OFFSET
  2690.     MVI C,':'    ;SEPARATOR
  2691.     CALL MOUTPUT    ;TO THE PRINTER
  2692. TX    EQU    $+OFFSET
  2693.     MOV A,D        ;GET THE DIGIT ADDRESS
  2694.     CALL CLOCK    ;GET THE VALUE
  2695.     MOV C,A        ;SAVE IT
  2696.     MVI A,CREAD+5    ;TEST FOR FIRST LOOP
  2697.     CMP D        ;1ST LOOP?
  2698.     MOV A,C        ;RECOVER THE VALUE
  2699.     JNZ T2        ;JUMP IF NOT 1ST LOOP
  2700.     ANI 3        ;DROP PM INDICATOR
  2701. T2    EQU    $+OFFSET
  2702.     ADI '0'        ;ADD ASCII BIAS
  2703.     MOV C,A
  2704.     CALL MOUTPUT    ;AND PRINT IT
  2705.     DCR D        ;POINT TO NEXT DIGIT
  2706.     MOV A,D        ;GET THE DIGIT ADDRESS TO A
  2707.     CALL PCLOCK    ;GET & PRINT ASCII
  2708.     DCR D        ;BUMP DIGIT COUNTER
  2709.     DCR B
  2710.     JNZ T1        ;LOOP TILL ALL PRINTED
  2711. ;
  2712. ;
  2713.     CALL ILPRT    ;PRINT THE TIME ZONE
  2714.     DB ' CST  ',0 ;CENTRAL STANDARD TIME
  2715. ;
  2716. ; WE WILL NOW PRINT THE DAY OF THE WEEK, FOLLOWED
  2717. ; BY THE MONTH, DATE AND YEAR
  2718. ;
  2719. ;
  2720.     MVI A,CREAD+6    ;THIS IS DAY OF WEEK 
  2721.     CALL CLOCK    ;GET THE DAY NUMBER
  2722. ;
  2723. DAYDONE    EQU    $+OFFSET
  2724.     ADD A        ;DOUBLE DAY COUNT
  2725.     LXI H,DAYS    ;POINT TO TABLE
  2726.     MOV E,A        ;ADD OFFSET TO DE
  2727.     MVI D,0
  2728.     DAD D        ;NEW POINTER IN HL
  2729.     MOV A,M        ;GET LO BYTE OF WORD
  2730.     INX H        ;POINT TO HI BYTE
  2731.     MOV H,M        ;TO H
  2732.     MOV L,A        ;PLUS LO BYTE POINTS TO STRING
  2733.     CALL LINOUT    ;PRINT THE DAY
  2734. ;
  2735.     MVI A,CREAD+10    ;10S OF MONTHS
  2736.     CALL CLOCK
  2737.     ORA A        ;WE GOT 10'S OF MONTHS?
  2738.     JZ NOTENS    ;JUMP IF NOT
  2739.     MVI A,10    ;ADD 10S IF WE GOT EM
  2740. NOTENS    EQU    $+OFFSET
  2741.     MOV B,A        ;SAVE 10S IN B
  2742.     MVI A,CREAD+9    ;GET THE ONES
  2743.     CALL CLOCK
  2744.     ADD B        ;ADD TO THE 10S PLACE TO GET MONTH
  2745.     DCR A        ;CORRECT FOR JAN=1
  2746.     ADD A        ;DOUBLE MONTH NUMBER
  2747.     LXI H,MONTHS    ;POINT TO DISPATCH TABLE
  2748.     MOV E,A        ;OFF SET TO DE
  2749.     MVI D,0
  2750.     DAD D        ;POINTER TO STRING AT (HL)
  2751.     MOV A,M        ;GET LO BYTE TO A
  2752.     INX H        ;POINT TO NEXT
  2753.     MOV H,M        ;HI BYTE TO H
  2754.     MOV L,A        ;LO BYTE TO L POINTS TO STRING
  2755.     CALL LINOUT    ;PRINT THE MONTH
  2756. ;
  2757.     MVI A,CREAD+8    ;10S OF DAYS
  2758.     CALL CLOCK
  2759.     ANI 3        ;DROP LEAP YEAR INDICATOR
  2760.     JZ NTENS    ;JUMP IF NO TENS PLACE
  2761.     CALL PASC    ;PRINT IT
  2762. NTENS    EQU    $+OFFSET
  2763.     MVI A,CREAD+7    ;ONES OF DAYS
  2764.     CALL PCLOCK    ;PRINT THEM
  2765.     LXI H,YEAR    ;PLUS YEAR MESSAGE
  2766.     CALL LINOUT    ;TO LISTER
  2767.     MVI A,CREAD+12    ;TENS OF YEAR
  2768.     CALL PCLOCK    ;PRINT THEM
  2769.     MVI A,CREAD+11    ;ONES OF YEAR
  2770.     CALL PCLOCK
  2771.     CALL ILPRT    ;FINISH THE LINE
  2772.     DB CR,LF,CR,LF,0
  2773.     POP PSW
  2774.     POP B
  2775.     POP D
  2776.     POP H
  2777.     RET
  2778. ;
  2779. PCLOCK    EQU    $+OFFSET
  2780.     CALL CLOCK    ;GET THE DIGIT
  2781. PASC    EQU    $+OFFSET
  2782.     ADI '0'        ;ADD ASCII BIAS
  2783.     MOV C,A
  2784.     JMP MOUTPUT    ;AND PRINT
  2785. ;
  2786. CLOCK    EQU    $+OFFSET
  2787.     OUT CLKCTL    ;TELL IT ADDRESS
  2788.     IN CLKDATA    ;GET THE DATA NYBBLE
  2789.     PUSH PSW    ;SAVE THE DATA
  2790.     XRA A        ;GET 0
  2791.     OUT CLKCTL    ;RESET HOLD BIT
  2792.     POP PSW        ;RESTORE DATA
  2793.     RET
  2794. ;
  2795. LINOUT    EQU    $+OFFSET
  2796.     MOV A,M        ;GET THE CHARACTER
  2797.     CPI '$'        ;DONE?
  2798.     RZ        ;RETURN IF DONE
  2799.     MOV C,A        ;ELSE PRINT IT
  2800.     CALL MOUTPUT
  2801.     INX H        ;POINT TO NEXT CHARACTER
  2802.     JMP LINOUT    ;THEN LOOP TILL DONE
  2803. ;
  2804. ;
  2805. SUN    EQU    $+OFFSET
  2806.     DB 'Sunday, $'
  2807. MON    EQU    $+OFFSET
  2808.     DB 'Monday, $'
  2809. TUE    EQU    $+OFFSET
  2810.     DB 'Tuesday, $'
  2811. WED    EQU    $+OFFSET
  2812.     DB 'Wednesday, $'
  2813. THU    EQU    $+OFFSET
  2814.     DB 'Thursday, $'
  2815. FRI    EQU    $+OFFSET
  2816.     DB 'Friday, $'
  2817. SAT    EQU    $+OFFSET
  2818.     DB 'Saturday, $'
  2819. ;
  2820. JAN    EQU    $+OFFSET
  2821.     DB 'January $'
  2822. FEB    EQU    $+OFFSET
  2823.     DB 'February $'
  2824. MAR    EQU    $+OFFSET
  2825.     DB 'March $'
  2826. APR    EQU    $+OFFSET
  2827.     DB 'April $'
  2828. MAY    EQU    $+OFFSET
  2829.     DB 'May $'
  2830. JUN    EQU    $+OFFSET
  2831.     DB 'June $'
  2832. JUL    EQU    $+OFFSET
  2833.     DB 'July $'
  2834. AUG    EQU    $+OFFSET
  2835.     DB 'August $'
  2836. SEP    EQU    $+OFFSET
  2837.     DB 'September $'
  2838. OCT    EQU    $+OFFSET
  2839.     DB 'October $'
  2840. NOV    EQU    $+OFFSET
  2841.     DB 'November $'
  2842. DEC    EQU    $+OFFSET
  2843.     DB 'December $'
  2844. ;
  2845. YEAR    EQU    $+OFFSET
  2846.     DB ', 19$'
  2847. ;
  2848. ;#################################################
  2849. DAYS    EQU    $+OFFSET
  2850.     DW SUN
  2851.     DW MON
  2852.     DW TUE
  2853.     DW WED
  2854.     DW THU
  2855.     DW FRI
  2856.     DW SAT
  2857.     DW SUN
  2858. ;
  2859. MONTHS    EQU    $+OFFSET
  2860.     DW JAN
  2861.     DW FEB
  2862.     DW MAR
  2863.     DW APR
  2864.     DW MAY
  2865.     DW JUN
  2866.     DW JUL
  2867.     DW AUG
  2868.     DW SEP
  2869.     DW OCT
  2870.     DW NOV
  2871.     DW DEC
  2872. ;
  2873. ;
  2874.     ENDIF        ;RTC
  2875. ;
  2876. WELFILN EQU    $+OFFSET
  2877.     DB    0,'WELCOME    ',0
  2878. ;Welcome file name ^^^^^^^^^^^ (must be 11 characters)
  2879. ;
  2880. COMFCB    EQU    $+OFFSET
  2881. ;
  2882.     IF    NOT OXGATE
  2883.     DB    0,'RBBS    COM'
  2884. ;COM file name       ^^^^^^^^^^^ (must be 11 characters)
  2885.     ENDIF        ;NOT OXGATE
  2886. ;
  2887.     IF     OXGATE
  2888.     DB    0,'OXENTR  COM'
  2889. ;COM file name     ^^^^^^^^^^^ (must be 11 characters)
  2890.     ENDIF        ;OXGATE
  2891. ;
  2892. PEND    EQU    $+OFFSET ;END OF RELOCATED CODE
  2893. ;
  2894. ;These areas are not initialized
  2895. ;
  2896.     DS    21    ;REST OF COM FCB
  2897. ;
  2898. OPTION    EQU    $+OFFSET
  2899.     DS    1
  2900. ;
  2901. TOCNTM    EQU    $+OFFSET
  2902.     DS    1
  2903. ;
  2904. TOCNT    EQU    $+OFFSET
  2905.     DS    2
  2906. ;
  2907. ;Byte to keep track of lost carrier when
  2908. ;typing "[Carrier Lost]" so we don't loop
  2909. ;
  2910. LOSTFLG EQU    $+OFFSET
  2911.     DS    1
  2912. ;
  2913. ;Save the CP/M jump table here
  2914. ;
  2915. VCOLDBT EQU    $+OFFSET
  2916.     DS    3
  2917. ;
  2918. VWARMBT EQU    $+OFFSET
  2919.     DS    3
  2920. ;
  2921. VCONSTAT EQU    $+OFFSET
  2922.      DS    3
  2923. ;
  2924. VCONIN     EQU    $+OFFSET
  2925.      DS    3
  2926. ;
  2927. VCONOUT  EQU    $+OFFSET
  2928.      DS    3
  2929. ;
  2930. VLISTOUT EQU    $+OFFSET
  2931.      DS    3
  2932. ;
  2933. VPUNCH    EQU    $+OFFSET
  2934.     DS    3
  2935. ;
  2936. VREADER    EQU    $+OFFSET
  2937.     DS    3
  2938. ;
  2939. ;
  2940. ;
  2941. ;Since these areas are not initialized,
  2942. ;the following counters will not be changed
  2943. ;by subsequent loads of this program
  2944. ;
  2945.     IF    USRLOG
  2946. OLDUSR    EQU    $+OFFSET
  2947.     DS    2
  2948. ;
  2949. NEWUSR    EQU    $+OFFSET
  2950.     DS    2
  2951. ;
  2952. NONUSR    EQU    $+OFFSET
  2953.     DS    2
  2954.     ENDIF        ;USRLOG
  2955. ;
  2956. ;
  2957.     DS    60
  2958. STACK    EQU    $+OFFSET ;LOCAL STACK
  2959. ;
  2960. ENDMARK    EQU    $+OFFSET ;! IGNORE ERROR. THIS MARKS END OF PGM
  2961. ;
  2962. ;BDOS equates
  2963. ;
  2964. CI    EQU    1
  2965. WRCON    EQU    2
  2966. DRECTIO EQU    6
  2967. PRINTF    EQU    9
  2968. CSTS    EQU    11
  2969. OPEN    EQU    15
  2970. READ    EQU    20
  2971. STDMA    EQU    26
  2972. BDOS    EQU    5
  2973. FCB    EQU    5CH 
  2974. FCBRNO    EQU    FCB+32
  2975. ;
  2976.     END
  2977.  
  2978.  
  2979.