home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol066 / apmodm22.asm < prev    next >
Assembly Source File  |  1984-04-29  |  40KB  |  1,766 lines
  1. ;
  2. ;    APMODEM.ASM V2.0
  3. ;    WARD CHRISTENSEN'S CP/M
  4. ;    MODEM FILE TRANSFER PROGRAM
  5. ;    Modified for the Apple ][
  6. ;    BY GORDON BANKS
  7. ;    2/17/81
  8. ;
  9. ;CP/M - CP/M FILE TRANSFER PROGRAM, AND
  10. ;TERMINAL PROGRAM.
  11. ;
  12. ;  ORIGINALLY WRITTEN AND CONCEIVED BY WARD
  13. ;CHRISTENSEN IN 1977, THIS PROGRAM HAS BECOME
  14. ;THE STANDARD PROTOCOL FOR CP/M TRANSFER.
  15. ;SEVERAL OTHERS HAVE CONTRIBUTED SIGNIFICANT
  16. ;ENHANCEMENTS INCLUDING:
  17. ;    KEITH PETERSEN
  18. ;    JIM BELL
  19. ;    BOB MATHIAS
  20. ;
  21. ;NOTE: THIS FILE WILL ASSEMBLE, WITHOUT NEED FOR
  22. ;EDITING, TO WORK WITH A D.C. HAYES MICROMODEM II.  
  23. ;IF YOU HAVE ANOTHER MODEM, YOU MUST CHANGE THE  
  24. ;EQUATES TO FALSE FOR MMII AND TRUE FOR YOUR MODEM.
  25. ;
  26. * * * * * * * * * * * * * * * * * * * * * * * * *
  27. *                        *
  28. *    THIS PROGRAM DOCUMENTED IN "APMODEM.DOC"    *
  29. *                        *
  30. * * * * * * * * * * * * * * * * * * * * * * * * *
  31. ;
  32. ;PLEASE PASS ON MODS, BUGS, ETC, SO YOUR
  33. ;FIXES OR ENHANCEMENTS MAY BE SHARED BY ALL,
  34. ;         TO:
  35. ;    Gordon Banks
  36. ;    5715 S. Drexel #209
  37. ;    Chicago, IL 60637
  38. ;    (312) 324-6194
  39. ;
  40. ;    ----------
  41. ;
  42. ;    12/18/80
  43. ;ADAPTED FOR THE APPLE ][ COMPUTER RUNNING CP/M WITH
  44. ;THE Z-80 SOFTCARD BY CHANGING THE EQUATES FOR THE 
  45. ;VARIOUS APPLE MODEM CONFIGURATIONS AND CHANGING THE
  46. ;IN AND OUT STATEMENTS TO LDA AND STA. (GORDON BANKS)
  47. ;IT SUPPORTS THE FOLLOWING APPLE MODEM CONFIGURATIONS:
  48. ;    1)DC HAYS MICROMODEM II
  49. ;    2)EXTERNAL MODEM THROUGH ONE OF THE FOLLOWING:
  50. ;        a) CCS 7710 SERIAL INTERFACE
  51. ;        b) SSM SERIAL INTERFACE
  52. ;        c) APPLE COMMUNICATIONS INTERFACE
  53. ;        d) APPLE SERIAL INTERFACE
  54. ;
  55. ;DEFINE FALSE AND TRUE
  56. ;
  57. FALSE    EQU    0
  58. TRUE    EQU    NOT FALSE
  59. ;
  60. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  61. ;
  62. BASE    EQU    0    ;CP/M BASE ADDRESS
  63. ;
  64. ;NOTE: IF DC HAYES THEN BAUD RATE DEFAULTS TO
  65. ;300 - 1 STOP BIT.  DO NOT CHANGE NEXT EQUATES
  66. ;
  67. ORIGMOD EQU    8EH    ;OFF HOOK, 110 BAUD, CAR. ON, ORIG.
  68. ANSWMOD    EQU    8AH    ;OFF HOOK, 110 BAUD, CAR. ON, ANSW.
  69. HANGUP    EQU    0    ;ON HOOK
  70. OFHKFLG    EQU    8DH    ;OFF HOOK BYTE
  71. ;
  72. ;IF YOU ARE USING AN EXTERNAL MODEM 
  73. ;CHANGE THESE EQUATES FOR YOUR MODEM PORT REQUIREMENTS
  74. ;
  75. INITREQ    EQU    FALSE     ;TRUE, IF MODEM PORT INIT. REQ'D
  76. ;
  77. ;APPLE MODEM TYPES EQUATES
  78. MMII    EQU    TRUE    ;TRUE, IF USING D.C. HAYES MICROMODEM ][
  79. CCS    EQU    FALSE    ;TRUE, USING CCS 7710 SERIAL INTERFACE
  80. COMCARD    EQU    FALSE    ;TRUE, USING APPLE COMMUNICATIONS CARD
  81. SSM    EQU    FALSE    ;TRUE, USING SSM SERIAL INTERFACE
  82. ;
  83. ;the Apple serial card apparently has the same protocol for DATA 
  84. ;and STATUS as the communication card.
  85. ;N.B.-->I have not tested this program for the SSM or
  86. ;Apple serial interface, but according to documentation I have
  87. ;been able to obtain, they should work using these equates.
  88. ;
  89. INITC1    EQU    03    ;1ST INIT CHAR TO CTL PORT
  90. INITC2    EQU    17     ;2ND INIT CHAR TO CTL PORT
  91. ;
  92.     IF    CCS    ;CCS CARD
  93. MODCTLP    EQU    0E0A0H    ;STATUS PORT OF CCS ACIA         
  94. MODDATP    EQU    0E0A1H    ;DATA PORT OF CCS ACIA (MOT 6850)
  95.      ENDIF        ;CCS
  96. ;
  97.     IF    COMCARD    ;APPLE COMMUNCATIONS CARD
  98. MODCTLP    EQU    0E0AEH    ;STATUS
  99. MODDATP    EQU    0E0AFH    ;DATA
  100.     ENDIF        ;COMCARD
  101. ;
  102.     IF    MMII    ;DC HAYES MICROMODEM ][
  103. MODCTLP    EQU    0E0A6H    ;STATUS PORT
  104. MODCTL2    EQU    0E0A5H    ;2ND STATUS PORT
  105. MODDATP    EQU    0E0A7H    ;DATA PORT
  106.     ENDIF        ;MMII
  107. ;
  108.     IF    SSM    ;SSM INTERFACE
  109. MODCTLP    EQU    0E0A4H    ;STATUS
  110. MODDATP    EQU    0E0A5H    ;DATA
  111.     ENDIF        ;SSM
  112. ;
  113. MODSNDB    EQU    2    ;BIT TO TEST FOR SEND
  114. MODSNDR    EQU    2    ;VALUE WHEN READY
  115. MODRCVB    EQU    1    ;BIT TO TEST FOR RECEIVE
  116. MODRCVR    EQU    1    ;VALUE WHEN READY
  117. ;
  118. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS
  119. EXITCHR    EQU    'E'-40H ;CTL-E EXIT FROM T OR C
  120. DISCCHR    EQU    'D'-40H    ;CTL-D DISCONNECTS MODEM T/E
  121. ;
  122. FASTCLK    EQU    FALSE    ;TRUE FOR 4 MHZ CLOCK
  123. ;
  124. ;SOME TIME-SHARE COMPUTERS REQUIRE TERMINALS TO
  125. ;HAVE BIT 7 HIGH (MARKING), SO IN THE TERMINAL
  126. ;MODE WE FORCE IT TO HIGH IF THE FOLLOWING OPTION
  127. ;IS SELECTED:
  128. ;
  129. TIMESHR    EQU    FALSE    ;TRUE TO MAKE BIT 7 HIGH
  130. ; 
  131. ;DEFINE ASCII CHARACTERS USED
  132. ;
  133. SOH    EQU    1    ;START OF HEADER
  134. EOT    EQU    4    ;END OF TRANSMISSION
  135. ACK    EQU    6    ;ACKNOWLEDGE
  136. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  137. CAN    EQU    18H    ;CANCEL
  138. LF    EQU    10    ;LINEFEED
  139. CR    EQU    13    ;CARRIAGE RETURN
  140. ; 
  141.     ORG    BASE+100H
  142. ;
  143. ;INIT PRIVATE STACK
  144.     LXI    H,0    ;HL=0
  145.     DAD    SP    ;HL=STACK FROM CP/M
  146.     SHLD    STACK    ;..SAVE IT
  147.     LXI    SP,STACK ;SP=MY STACK
  148.     CALL    START    ;GO PRINT ID
  149.     DB    'APPLE ][ MODEM V2.0 as of '
  150.     DB    '2/17/81',CR,LF,'$'
  151. ; 
  152. START    POP    D    ;GET ID MESSAGE
  153.     MVI    C,PRINT
  154.     CALL    BDOS    ;PRINT ID MESSAGE
  155. ;
  156. ;INITIALIZE THE JMPS TO CP/M BIOS
  157. ;
  158.     CALL    INITADR
  159. ;
  160.     LDA    FCB+1    ;GET PRIMARY OPTION
  161.     CPI    'H'    ;MODEM H(ELP)?
  162.     JZ    HELP    ;..YES, GIVE HELP
  163.     CPI    'X'    ;MODEM X(AMPLES)?
  164.     JZ    EXAM    ;GIVE EXAMPLES
  165.     CPI    'C'    ;AUTO DIAL OPTION
  166.     JZ    CONNCT    ;DIAL 
  167. ;
  168. ;SAVE PRIMARY OPTION, VALIDATE SECONDARY OPT.
  169. ;
  170. RTNC    CALL    PROCOPT
  171. ;
  172. ;INIT THE MODEM OR SERIAL PORT
  173. ;
  174.     CALL    INITMOD
  175. ;
  176. ;MOVE THE FILENAME FROM FCB 2 TO FCB 1
  177. ;
  178.     CALL    MOVEFCB
  179. ;
  180. ;GOBBLE UP GARBAGE CHARS FROM THE LINE
  181. ;PRIOR TO RECEIVE OR SEND
  182. ;
  183.     LDA    MODDATP
  184.     LDA    MODDATP
  185. ;
  186. ;JMP TO APPROPRIATE FUNCTION
  187. ;
  188.     LDA    OPTION    ;GET PRIMARY OPTION
  189. ;
  190.     CPI    'C'    ;AUTO DIAL
  191.     JZ    TERM    ;DROP INTO TERMINAL MODE
  192. ;
  193.     CPI    'E'    ;TERMINAL IN ECHO
  194.     JZ    TRMECHO    ;..MODE?
  195. ;
  196.     CPI    'T'    ;TERMINAL..
  197.     JZ    TERM    ;..MODE?
  198. ;
  199.     CPI    'D'
  200.     JZ    DISCONN
  201. ;
  202.            CPI    'S'    ;SEND..
  203.     JZ    SENDFIL    ;..A FILE?
  204. ;
  205.     CPI    'R'    ;RECEIVE..
  206.     JZ    RCVFIL    ;..A FILE?
  207. ;
  208. ;INVALID OPTION
  209. ;
  210.     JMP    BADOPT
  211. ;
  212. * * * * * * * * * * * * * * * * * * * * *
  213. *                    *
  214. *    TERM: TERMINAL MODE        *
  215. *                    *
  216. * * * * * * * * * * * * * * * * * * * * *
  217. ;
  218. ;THIS PROGRAM SIMPLY SENDS KEYED CHARACTERS
  219. ;DOWN THE LINE, AND DISPLAYS CHARACTERS
  220. ;RECEIVED FROM THE LINE.  THIS MAKES IT
  221. ;SUITABLE FOR COMMUNICATION WITH TIME SHARING
  222. ;COMPUTERS, CBBS'S, OR ANOTHER PROGRAM
  223. ;RUNING "MODEM E" (ECHO MODE)
  224. ;
  225. ;TYPE THE "EXITCHR" (ORIGINALLY CTL-E) TO EXIT.
  226. ;OR THE "DISCCHR" (ORIGINALLY CTL-D) TO DISCONN.
  227. ;
  228. ;A FUTURE ENHANCEMENT WILL BE TO WRITE THE
  229. ;RECEIVED DATA IN MEMORY, AND ALLOW IT TO
  230. ;BE WRITTEN TO DISK
  231. ;
  232. TERM    CALL    STAT    ;LOCAL CHAR KEYED?
  233.     JZ    TERML    ;..NO, CHECK LINE
  234.     CALL    KEYIN    ;GET CHAR
  235.     CPI    EXITCHR    ;TIME TO END?
  236.     JZ    CKDIS    ;YES, CK DISCONN
  237.     CPI    DISCCHR    ;DISCONNECT REQUEST?
  238.     JZ    DISCONN    ;YES, DO IT
  239.     IF    TIMESHR
  240.     ORI    80H    ;FORCE BIT 7 TO HIGH
  241.     ENDIF        ;TIMESHR
  242.     STA    MODDATP    ;SEND THE CHAR
  243. ;
  244. ;SEE IF CHAR FROM LINE
  245. ;
  246. TERML    LDA    MODCTLP    ;READ STATUS
  247.     ANI    MODRCVB    ;ISOLATE BIT
  248.     CPI    MODRCVR    ;READY?
  249.     JNZ    TERM    ;..NO, LOOP
  250.     LDA    MODDATP    ;READ DATA
  251.     ANI    7FH    ;STRIP PARITY BIT
  252.     CALL    TYPE    ;TYPE IT
  253.     JMP    TERM    ;LOOP
  254. ;
  255. * * * * * * * * * * * * * * * * * * * * *
  256. *                    *
  257. *    TRMECHO: TERMINAL WITH ECHO    *
  258. *                    *
  259. * * * * * * * * * * * * * * * * * * * * *
  260. ;
  261. ;TERMINAL PROGRAM WITH ECHO - SEE NOTES
  262. ;UNDER "TERM" ABOVE
  263. ;
  264. ;C A U T I O N   DON'T RUN WITH BOTH COMPUTERS
  265. ;IN "ECHO" MODE - LINE ERRORS (OR ANY CHAR)
  266. ;WILL BE ECHOED BACK AND FORTH AD INFINITUM.
  267. ;
  268. TRMECHO    LDA    MODCTLP    ;GET STATUS
  269.     ANI    MODRCVB    ;ISOLATE READY BIT
  270.     CPI    MODRCVR    ;ARE WE READY?
  271.     JZ    LINECHR    ;YES, READ THE CHR
  272.     CALL    STAT    ;CHECK LOCAL KB
  273.     JZ    TRMECHO    ;..NO CHAR
  274.     CALL    KEYIN    ;GET LOCAL CHAR
  275.     CPI    EXITCHR    ;END?
  276.     JZ    CKDIS    ;YES, CK DISCONN, EXIT
  277.     CPI    DISCCHR    ;DISCONN?
  278.     JZ    DISCONN    ;..YES, DO IT.
  279.     STA    MODDATP    ;SEND CHAR
  280.     CALL    TYPE    ;ECHO IT LOCALLY
  281.     JMP    TRMECHO    ;..AND LOOP
  282. ;
  283. ;GOT CHAR FROM LINE
  284. ;
  285. LINECHR    LDA    MODDATP    ;GET CHAR
  286.     STA    MODDATP    ;ECHO IT
  287.     ANI    7FH    ;STRIP PARITY BIT
  288.     CALL    TYPE    ;TYPE IT
  289.     JMP    TRMECHO    ;LOOP
  290. ;
  291. * * * * * * * * * * * * * * * * * * * * *
  292. *                    *
  293. *    SENDFIL: SENDS A CP/M FILE    *
  294. *                    *
  295. * * * * * * * * * * * * * * * * * * * * *
  296. ;
  297. ;THE CP/M FILE SPECIFIED IN THE MODEM COMMAND
  298. ;IS TRANSFERRED OVER THE PHONE TO ANOTHER
  299. ;COMPUTER RUNNING MODEM WITH THE "R" (RECEIVE)
  300. ;OPTION.  THE DATA IS SENT ONE SECTOR AT A
  301. ;TIME WITH HEADERS AND CHECKSUMS, AND RE-
  302. ;TRANSMISSION ON ERRORS.  
  303. ;
  304. SENDFIL    CALL    OPENFIL    ;OPEN THE FILE
  305.     MVI    E,80    ;WAIT 80 SEC..
  306.     CALL    WAITNAK    ;..FOR INITIAL NAK
  307. ;
  308. SENDLP    CALL    RDSECT    ;READ A SECTOR
  309.     JC    SENDEOF    ;SEND EOF IF DONE
  310.     CALL    INCRSNO    ;BUMP SECTOR #
  311.     XRA    A    ;ZERO ERROR..
  312.     STA    ERRCT    ;..COUNT
  313. ;
  314. SENDRPT    CALL    SENDHDR    ;SEND A HEADER
  315.     CALL    SENDSEC    ;SEND DATA SECTOR
  316.     CALL    SENDCKS    ;SEND CKSUM
  317.     CALL    GETACK    ;GET THE ACK
  318.     JC    SENDRPT    ;REPEAT IF NO ACK
  319.     JMP    SENDLP    ;LOOP UNTIL EOF
  320. ;
  321. ;FILE SENT, SEND EOT'S
  322. ;
  323. SENDEOF    MVI    A,EOT    ;SEND..
  324.     CALL    SEND    ;..AN EOT
  325.     CALL    GETACK    ;GET THE ACK
  326.     JC    SENDEOF    ;LOOP IF NO ACK
  327.     JMP    DONE    ;ALL DONE
  328. ;
  329. * * * * * * * * * * * * * * * * * * * * *
  330. *                    *
  331. *    RCVFIL: RECEIVE A FILE        *
  332. *                    *
  333. * * * * * * * * * * * * * * * * * * * * *
  334. ;
  335. ;RECEIVES A FILE IN BLOCK FORMAT AS SENT
  336. ;BY ANOTHER PERSON DOING "MODEM S FN.FT".
  337. ;
  338. RCVFIL    CALL    ERASFIL    ;ERASE THE FILE
  339.     CALL    MAKEFIL    ;..THEN MAKE NEW
  340.     CALL    ILPRT    ;PRINT:
  341.     DB    'FILE OPEN, READY TO RECEIVE',CR,LF,0
  342. ;
  343. RCVLP    CALL    RCVSECT    ;GET A SECTOR
  344.     JC    RCVEOT    ;GOT EOT
  345.     CALL    WRSECT    ;WRITE THE SECTOR
  346.     CALL    INCRSNO    ;BUMP SECTOR #
  347.     CALL    SENDACK    ;ACK THE SECTOR
  348.     JMP    RCVLP    ;LOOP UNTIL EOF
  349. ;
  350. ;GOT EOT ON SECTOR - FLUSH BUFFERS, END
  351. ;
  352. RCVEOT    CALL    WRBLOCK    ;WRITE THE LAST BLOCK
  353.     CALL    SENDACK    ;ACK THE SECTOR
  354.     CALL    CLOSFIL    ;CLOSE THE FILE
  355.     JMP    DONE    ;ALL DONE
  356. ;
  357. * * * * * * * * * * * * * * * * * * * * *
  358. *                    *
  359. *        SUBROUTINES        *
  360. *                    *
  361. * * * * * * * * * * * * * * * * * * * * *
  362. ;
  363. ;
  364. ;---->    RCVSECT: RECEIVE A SECTOR
  365. ;
  366. ;RETURNS WITH CARRY SET IF EOT RECEIVED.
  367. ;
  368. RCVSECT    XRA    A    ;GET 0
  369.     STA    ERRCT    ;INIT ERROR COUNT
  370. ;
  371. RCVRPT    LDA    QFLG    ;QUIET?
  372.     ORA    A
  373.     JZ    RCVSQ    ;YES, NO STAT MSG.
  374.     CALL    ILPRT    ;PRINT:
  375.     DB    'AWAITING #',0
  376.     LDA    SECTNO    ;GET SECTOR #
  377.     INR    A    ;(REAL INR LATER)
  378.     CALL    HEXO    ;PRINT IN HEX
  379.     CALL    CRLF    ;..THEN CRLF
  380. ;
  381. RCVSQ    MVI    B,10    ;10 SEC TIMEOUT
  382.     CALL    RECV    ;GET SOH/EOT
  383.     JC    RCVSTOT    ;TIMEOUT
  384.     CPI    SOH    ;GET SOH?
  385.     JZ    RCVSOH    ;..YES
  386. ;
  387. ;EARLIER VERS. OF MODEM PROG SENT SOME NULLS -
  388. ;IGNORE THEM
  389. ;
  390.     ORA    A    ;00 FROM SPEED CHECK?
  391.     JZ    RCVSQ    ;YES, IGNORE IT
  392.     CPI    EOT    ;END OF TRANSFER?
  393.     STC        ;RETURN WITH CARRY..
  394.     RZ        ;..SET IF EOT
  395. ;
  396. ;DIDN'T GET SOH  OR EOT - 
  397. ;
  398.     MOV    B,A    ;SAVE CHAR
  399.     LDA    VSEEFLG    ;VIEWING..
  400.     ORA    A    ;..MODE?
  401.     JZ    RCVSEH    ;YES, PRT.MSG
  402.     LDA    QFLG    ;QUIET..
  403.     ORA    A    ;..MODE?
  404.     JZ    RCVSERR    ;YES, SKIP MSG
  405. RCVSEH    MOV    A,B    ;GET CHAR
  406.     CALL    HEXO    ;SHOW IN HEX
  407.     CALL    ILPRT    ;PRINT:
  408.     DB    'H RCD, NOT SOH',CR,LF,0
  409. ;
  410. ;DIDN'T GET VALID HEADER - PURGE THE LINE,
  411. ;THEN SEND NAK.
  412. ;
  413. RCVSERR    MVI    B,1    ;WAIT FOR 1 SEC..
  414.     CALL    RECV    ;..WITH NO CHARS
  415.     JNC    RCVSERR    ;LOOP UNTIL SENDER DONE
  416.     MVI    A,NAK    ;SEND..
  417.     CALL    SEND    ;..THE NAK
  418.     LDA    ERRCT    ;ABORT IF..
  419.     INR    A    ;..WE HAVE REACHED..
  420.     STA    ERRCT    ;..THE ERROR..
  421.     CPI    ERRLIM    ;..LIMIT?
  422.     JC    RCVRPT    ;..NO, TRY AGAIN
  423. ;
  424. ;10 ERRORS IN A ROW - 
  425. ;
  426.     LDA    VSEEFLG    ;VIEWING..
  427.     ORA    A    ;..FILE?
  428.     JZ    RCVCKQ    ;YES, ASK RETRY/QUIT
  429.     LDA    QFLG    ;QUIET..
  430.     ORA    A    ;..MODE?
  431.     JZ    RCVSABT    ;ABORT
  432. ;
  433. RCVCKQ    CALL    CKQUIT    ;RETRY/QUIT?
  434.     JZ    RCVSECT    ;TRY AGAIN
  435. ;
  436. RCVSABT    CALL    CLOSFIL    ;KEEP WHATEVER WE GOT
  437.     CALL    ERXIT
  438.     DB    '++UNABLE TO RECEIVE BLOCK'
  439.     DB    CR,LF,'++ABORTING++$'
  440. ;
  441. ;TIMEDOUT ON RECEIVE
  442. ;
  443. RCVSTOT    LDA    VSEEFLG    ;VIEWING..
  444.     ORA    A    ;..MODE?
  445.     JZ    RCVSPT    ;YES, PRT MSG
  446.     LDA    QFLG    ;QUIET..
  447.     ORA    A    ;..MODE?
  448.     JZ    RCVSERR    ;YES, NO MSG
  449. ;
  450. RCVSPT    CALL    ILPRT
  451.     DB    '++TIMEOUT++ ',0
  452. ;
  453. RCVPRN    LDA    ERRCT    ;PRINT ERROR..
  454.     CALL    HEXO    ;..COUNT
  455.     CALL    CRLF
  456.     JMP    RCVSERR    ;BUMP ERR CT, ETC.
  457. ;
  458. ;GOT SOH - GET BLOCK #, BLOCK # COMPLEMENTED
  459. ;
  460. RCVSOH    MVI    B,1    ;TIMEOUT = 1 SEC
  461.     CALL    RECV    ;GET SECTOR
  462.     JC    RCVSTOT    ;GOT TIMEOUT
  463.     MOV    D,A    ;D=BLK #
  464.     MVI    B,1    ;TIMEOUT = 1 SEC
  465.     CALL    RECV    ;GET CMA'D SECT #
  466.     JC    RCVSTOT    ;TIMEOUT
  467.     CMA        ;CALC COMPLEMENT
  468.     CMP    D    ;GOOD SECTOR #?
  469.     JZ    RCVDATA    ;YES, GET DATA
  470. ;
  471. ;GOT BAD SECTOR #
  472. ;
  473.     LDA    VSEEFLG    ;VIEWING..
  474.     ORA    A    ;..MODE?
  475.     JZ    RCVBSE    ;..YES, PRT MSG
  476.     LDA    QFLG    ;QUIET..
  477.     ORA    A    ;..MODE?
  478.     JZ    RCVSERR    ;..YES, NO MSG
  479. ;
  480. RCVBSE    CALL    ILPRT    ;PRINT:
  481.     DB    '++BAD SECTOR # IN HDR',CR,LF,0
  482.     JMP    RCVSERR    ;BUMP ERROR CT.
  483. ;
  484. RCVDATA    MOV    A,D    ;GET SECTOR #
  485.     STA    RCVSNO    ;SAVE IT
  486.     MVI    A,1    ;SHOW..
  487.     STA    DATAFLG    ;GETTING DATA
  488.     MVI    C,0    ;INIT CKSUM
  489.     LXI    H,BASE+80H    ;POINT TO BUFFER
  490. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  491.     CALL    RECV    ;GET CHAR
  492.     JC    RCVSTOT    ;TIMEOUT
  493.     MOV    M,A    ;STORE CHAR
  494.     INR    L    ;DONE?
  495.     JNZ    RCVCHR    ;NO, LOOP
  496. ;
  497. ;VERIFY CHECKSUM
  498. ;
  499.     MOV    D,C    ;SAVE CHECKSUM
  500.     XRA    A    ;SHOW..
  501.     STA    DATAFLG    ;..END OF DATA
  502.     MVI    B,1    ;TIMEOUT LEN.
  503.     CALL    RECV    ;GET CHECKSUM
  504.     JC    RCVSTOT    ;TIMEOUT
  505.     CMP    D    ;CHECKSUM OK?
  506.     JNZ    RCVCERR    ;NO, ERROR
  507. ;
  508. ;GOT A SECTOR, IT'S A DUP IF = PREV,
  509. ;    OR OK IF = 1 + PREV SECTOR
  510. ;
  511.     LDA    RCVSNO    ;GET RECEIVED
  512.     MOV    B,A    ;SAVE IT
  513.     LDA    SECTNO    ;GET PREV
  514.     CMP    B    ;PREV REPEATED?
  515.     JZ    RECVACK    ;ACK TO CATCH UP
  516.     INR    A    ;CALC NEXT SECTOR #
  517.     CMP    B    ;MATCH?
  518.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  519.     RET        ;CARRY OFF - NO ERRORS
  520. ;
  521. ;GOT CKSUM
  522. ;
  523. RCVCERR    LDA    VSEEFLG    ;VIEWING..
  524.     ORA    A    ;..MODE?
  525.     JZ    RCVCPR    ;..YES, PRT MSG
  526.     LDA    QFLG    ;QUIET..
  527.     ORA    A    ;..MODE?
  528.     JZ    RCVSERR    ;YES, NO MSG
  529. ;
  530. RCVCPR    CALL    ILPRT
  531.     DB    '++CKSUM++ ',0
  532.     JMP    RCVPRN    ;PRINT ERROR #
  533. ;
  534. ;PREV SECT REPEATED, DUE TO THE LAST ACK
  535. ;BEING GARBAGED.  ACK IT SO SENDER WILL CATCH UP 
  536. ;
  537. RECVACK    CALL    SENDACK    ;SEND THE ACK,
  538.     JMP    RCVSECT    ;GET NEXT BLOCK
  539. ;
  540. ;SEND AN ACK FOR THE SECTOR
  541. ;
  542. SENDACK    MVI    A,ACK    ;GET ACK
  543.     CALL    SEND    ;..AND SEND IT
  544.     RET
  545. ;
  546. ;---->    SENDHDR: SEND THE SECTOR HEADER
  547. ;
  548. ;SEND: (SOH) (BLOCK #) (COMPLEMENTED BLOCK #)
  549. ;
  550. SENDHDR    LDA    QFLG    ;QUIET..
  551.     ORA    A    ;..MODE?
  552.     JZ    SENDHNM    ;YES, SKIP STATUS MSG.
  553.     CALL    ILPRT    ;PRINT:
  554.     DB    'SEND # ',0
  555.     LDA    SECTNO    ;PRINT..
  556.     CALL    HEXO    ;..SECT #
  557.     CALL    CRLF    ;..THEN CR/LF
  558. ;
  559. SENDHNM    MVI    A,SOH    ;SEND..
  560.     CALL    SEND    ;..SOH,
  561.     LDA    SECTNO    ;THEN SEND..
  562.     CALL    SEND    ;..SECTOR #
  563.     LDA    SECTNO    ;THEN SECTOR #
  564.     CMA        ;..COMPLEMENTED..
  565.     CALL    SEND    ;..SECTOR #
  566.     RET        ;FROM SENDHDR
  567. ;
  568. ;---->    SENDSEC: SEND THE DATA SECTOR
  569. ;
  570. ;WHILE SENDING THE SECTOR, THE "DATAFLG" IS SET
  571. ;SUCH THAT IF "V" (VIEW THE FILE) WAS REQUESTED,
  572. ;THE "SHOW" ROUTINE WILL PRINT THE DATA, BUT NOT
  573. ;THE HDR OR CKSUM, OR ANY NON-FATAL MSGS.
  574. ;
  575. SENDSEC    MVI    A,1    ;SHOW NOW AT DATA..
  576.     STA    DATAFLG    ;..FOR VIEW COMMAND
  577.     MVI    C,0    ;INIT CKSUM
  578.     LXI    H,BASE+80H    ;POINT TO BUFFER
  579. SENDC    MOV    A,M    ;GET A CHAR
  580.     CALL    SEND    ;SEND IT
  581.     INR    L    ;POINT TO NEXT CHAR
  582.     JNZ    SENDC    ;LOOP IF <100H
  583.     XRA    A    ;SHOW NOT INTO DATA..
  584.     STA    DATAFLG    ;..FOR VIEW COMMAND
  585.     RET        ;FROM SENDSEC
  586. ;
  587. ;---->    SENDCKS: SEND THE CHECKSUM
  588. ;
  589. SENDCKS    MOV    A,C    ;SEND THE..
  590.     CALL    SEND    ;..CHECKSUM
  591.     RET        ;FROM SENDCKS
  592. ;
  593. ;---->    GETACK: GET THE ACK ON THE SECTOR
  594. ;
  595. ;RETURNS WITH CARRY CLEAR IF ACK RECEIVED.
  596. ;IF AN ACK IS NOT RECEIVED, THE ERROR COUNT
  597. ;IS INCREMENTED, AND IF LESS THAN "ERRLIM",
  598. ;CARRY IS SET AND CONTROL RETURNS.  IF THE
  599. ;ERROR COUNT IS AT "ERRLIM", THE PROGRAM
  600. ;ABORTS IF IN "QUIET" MODE, OR ASKS THE
  601. ;USER FOR QUIT/RETRY IF NOT.
  602. ;
  603. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  604.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  605.     JC    GETATOT    ;TIMED OUT
  606.     CPI    ACK    ;OK? (CARRY OFF IF =)
  607.     RZ        ;YES, RET FROM GETACK
  608.     MOV    B,A    ;SAVE CHAR
  609.     LDA    QFLG    ;QUIET..
  610.     ORA    A    ;..MODE?
  611.     JZ    ACKERR    ;..YES, NO MSG
  612.     MOV    A,B    ;GET CHAR
  613.     CALL    HEXO    ;PRINT IN HEX
  614.     CALL    ILPRT    ;PRINT:
  615.     DB    'H RCD, NOT ACK',CR,LF,0
  616. ;
  617. ;TIMEOUT OR ERROR ON ACK - BUMP ERROR COUNT
  618. ;
  619. ACKERR    LDA    ERRCT    ;GET COUNT
  620.     INR    A    ;BUMP IT
  621.     STA    ERRCT    ;SAVE BACK
  622.     CPI    ERRLIM    ;AT LIMIT?
  623.     RC        ;NOT AT LIMIT
  624. ;
  625. ;REACHED ERROR LIMIT
  626. ;
  627.     LDA    VSEEFLG    ;VIEWING..
  628.     ORA    A    ;..FILE?
  629.     JZ    GACKV    ;YES, ASK QUIT/RETRY
  630.     LDA    QFLG    ;QUIET..
  631.     ORA    A    ;..MODE?
  632.     JZ    CSABORT ;..YES, NO MSG
  633. ;
  634. GACKV    CALL    CKQUIT    ;SEE IF WANT TO QUIT
  635.     STC        ;TO SHOW NO ACK
  636.     RZ        ;KEEP ON TRYIN'
  637. ;
  638. CSABORT    CALL    ERXIT
  639.     DB    'CAN''T SEND SECTOR '
  640.     DB    '- ABORTING',CR,LF,'$'
  641. ;
  642. ;TIMEOUT GETTING ACK
  643. ;
  644. GETATOT    LDA    QFLG    ;QUIET..
  645.     ORA    A    ;..MODE?
  646.     JZ    ACKERR    ;YES, NO MSG
  647.     CALL    ILPRT    ;PRINT:
  648.     DB    'TIMEOUT ON ACK',CR,LF,0
  649.     JMP    ACKERR
  650. ; 
  651. ABORT    LXI    SP,STACK
  652. ;
  653. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  654.     CALL    RECV
  655.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  656.     MVI    A,NAK    ;NEGATIVE ACK
  657.     CALL    SEND    ;TELL SENDING END
  658.     CALL    ILPRT    ;EXIT WITH ABORT MSG
  659.     DB    'MODEM PROGRAM CANCELLED',CR,LF,0
  660.     JMP    CKDIS    ;CHECK FOR DISCONN.
  661. ;
  662. ;---->    INCRSNO: INCREMENT SECTOR #
  663. ;
  664. INCRSNO    LDA    SECTNO    ;INCR..
  665.     INR    A    ;..SECT..
  666.     STA    SECTNO    ;..NUMBER
  667.     RET
  668. ;
  669. ;---->    ERASFIL: ERASE THE INCOMING FILE.
  670. ;
  671. ;IF IT EXISTS, ASK IF IT MAY BE ERASED.
  672. ;
  673. ERASFIL    LXI    D,FCB    ;POINT TO CTL BLOCK
  674.     MVI    C,SRCHF ;SEE IF IT..
  675.     CALL    BDOS    ;..EXISTS
  676.     INR    A    ;FOUND?
  677.     RZ        ;..NO, RETURN
  678.     CALL    ILPRT    ;PRINT:
  679.     DB    '++FILE EXISTS, TYPE Y TO ERASE: ',0
  680.     CALL    KEYIN    ;GET CHAR
  681.     PUSH    PSW
  682.     CALL    TYPE    ;ECHO
  683.     CALL    CRLF    ;BACK TO START OF LINE
  684.     POP    PSW
  685.     ANI    5FH    ;MAKE UPPER CASE
  686.     CPI    'Y'    ;WANT ERASED?
  687.     JNZ    CKDIS    ;QUIT IF NOT ERASE
  688. ;
  689. ;ERASE OLD FILE
  690. ;
  691.     LXI    D,FCB    ;POINT TO FCB
  692.     MVI    C,ERASE    ;GET BDOS FNC
  693.     CALL    BDOS    ;DO THE ERASE
  694.     RET        ;FROM "ERASFIL"
  695. ;
  696. ;---->    MAKEFIL: MAKES THE FILE TO BE RECEIVED
  697. ;
  698. MAKEFIL    LXI    D,FCB    ;POINT TO FCB
  699.     MVI    C,MAKE    ;GET BDOS FNC
  700.     CALL    BDOS    ;TO THE MAKE
  701.     INR    A    ;FF=BAD?
  702.     RNZ        ;OPEN OK
  703. ;DIRECTORY FULL - CAN'T MAKE FILE
  704.     CALL    ERXIT
  705.     DB    '++ERROR - CAN''T MAKE FILE',CR,LF
  706.     DB    '++DIRECTORY MUST BE FULL',CR,LF,'$'
  707. ;
  708. ;---->    OPENFIL: OPENS THE FILE TO BE SENT
  709. ;
  710. OPENFIL    LXI    D,FCB    ;POINT TO FILE
  711.     MVI    C,OPEN    ;GET FUNCTION
  712.     CALL    BDOS    ;OPEN IT
  713.     INR    A    ;OPEN OK?
  714.     JNZ    OPENOK    ;..YES
  715.     CALL    ERXIT    ;..NO, ABORT
  716.     DB    'CAN''T OPEN FILE$'
  717. ;
  718. OPENOK    CALL    ILPRT    ;PRINT:
  719.     DB    'FILE OPEN, EXTENT LENGTH: ',0
  720.     LDA    FCB+15    ;GET # SECTORS
  721.     CALL    HEXO    ;PRINT IN HEX
  722.     CALL    ILPRT    ;PRINT:
  723.     DB    'H',CR,LF,0
  724.     RET
  725. ;
  726. ;---->    CLOSFIL: CLOSES THE RECEIVED FILE
  727. ;
  728. CLOSFIL    LXI    D,FCB    ;POINT TO FILE
  729.     MVI    C,CLOSE    ;GET FUNCTION
  730.     CALL    BDOS    ;CLOSE IT
  731.     INR    A    ;CLOSE OK?
  732.     RNZ        ;..YES, RETURN
  733.     CALL    ERXIT    ;..NO, ABORT
  734.     DB    'CAN''T CLOSE FILE$'
  735. ;
  736. ;---->    RDSECT: READS A SECTOR
  737. ;
  738. ;FOR SPEED, THIS ROUTINE BUFFERS UP 16
  739. ;SECTORS AT A TIME.
  740. ;
  741. RDSECT    LDA    SECINBF    ;GET # SECT IN BUFF.
  742.     DCR    A    ;DECREMENT..
  743.     STA    SECINBF    ;..IT
  744.     JM    RDBLOCK    ;EXHAUSTED?  NEED MORE.
  745.     LHLD    SECPTR    ;GET POINTER
  746.     LXI    D,BASE+80H    ;TO DATA
  747.     CALL    MOVE128    ;MOVE TO BUFFER
  748.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  749.     RET        ;FROM "READSEC"
  750. ;
  751. ;BUFFER IS EMPTY - READ IN ANOTHER BLOCK OF 16
  752. ;
  753. RDBLOCK    LDA    EOFLG    ;GET EOF FLAG
  754.     CPI    1    ;IS IT SET/
  755.     STC        ;TO SHOW EOF
  756.     RZ        ;GOT EOF
  757.     MVI    C,0    ;SECTORS IN BLOCK
  758.     LXI    D,DBUF    ;TO DISK BUFFER
  759. ;
  760. RDSECLP    PUSH    B
  761.     PUSH    D
  762.     MVI    C,STDMA    ;SET DMA..
  763.     CALL    BDOS    ;..ADDR
  764.     LXI    D,FCB
  765.     MVI    C,READ
  766.     CALL    BDOS
  767.     POP    D
  768.     POP    B
  769.     ORA    A    ;READ OK?
  770.     JZ    RDSECOK    ;YES
  771.     DCR    A    ;EOF?
  772.     JZ    REOF    ;GOT EOF
  773. ;
  774. ;READ ERROR
  775. ;
  776.     CALL    ERXIT
  777.     DB    '++FILE READ ERROR$'
  778. ;
  779. RDSECOK    LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  780.     DAD    D    ;...TO NEXT BUFF
  781.     XCHG        ;BUFF TO DE
  782.     INR    C    ;MORE SECTORS?
  783.     MOV    A,C    ;GET COUNT
  784.     CPI    16    ;DONE?
  785.     JZ    RDBFULL    ;..YES, BUFF IS FULL
  786.     JMP    RDSECLP    ;READ MORE
  787. ;
  788. REOF    MVI    A,1
  789.     STA    EOFLG    ;SET EOF FLAG
  790.     MOV    A,C
  791. ;
  792. ;BUFFER IS FULL, OR GOT EOF
  793. ;
  794. RDBFULL    STA    SECINBF    ;STORE SECTOR COUNT
  795.     LXI    H,DBUF    ;INIT BUFFER..
  796.     SHLD    SECPTR    ;..POINTER
  797.     LXI    D,BASE+80H    ;RESET..
  798.     MVI    C,STDMA    ;..DMA..
  799.     CALL    BDOS    ;..ADDR
  800.     JMP    RDSECT    ;PASS SECT TO CALLER
  801. ;
  802. ;---->    WRSECT: WRITE A SECTOR
  803. ;
  804. ;WRITES THE SECTOR INTO A BUFFER.  WHEN 16
  805. ;HAVE BEEN WRITTEN, WRITES THE BLOCK TO DISK.
  806. ;
  807. ;ENTRY POINT "WRBLOCK" FLUSHES THE BUFFER AT EOF.
  808. ;
  809. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  810.     XCHG        ;TO DE FOR MOVE
  811.     LXI    H,BASE+80H    ;FROM HERE
  812.     CALL    MOVE128    ;MOVE TO BUFFER
  813.     XCHG        ;SAVE NEXT..
  814.     SHLD    SECPTR    ;..BLOCK POINTER
  815.     LDA    SECINBF    ;BUMP THE..
  816.     INR    A    ;..SECTOR #..
  817.     STA    SECINBF    ;..IN THE BUFF
  818.     CPI    16    ;HAVE WE 16?
  819.     RNZ        ;NO, RETURN
  820. ;
  821. ;---->    WRBLOCK: WRITES A BLOCK TO DISK
  822. ;
  823. WRBLOCK    LDA    SECINBF    ;# SECT IN BUFFER
  824.     ORA    A    ;0 MEANS END OF FILE
  825.     RZ        ;NONE TO WRITE
  826.     MOV    C,A    ;SAVE COUNT
  827.     LXI    D,DBUF    ;POINT TO DISK BUFF
  828. ;
  829. DKWRLP    PUSH    H
  830.     PUSH    D
  831.     PUSH    B
  832.     MVI    C,STDMA    ;SET DMA
  833.     CALL    BDOS    ;TO BUFFER
  834.     LXI    D,FCB    ;THEN WRITE
  835.     MVI    C,WRITE    ;..THE..
  836.     CALL    BDOS    ;..BLOCK
  837.     POP    B
  838.     POP    D
  839.     POP    H
  840.     ORA    A
  841.     JNZ    WRERR    ;OOPS, ERROR
  842.     LXI    H,80H    ;LENGTH OF 1 SECT
  843.     DAD    D    ;HL= NEXT BUFF
  844.     XCHG        ;TO DE FOR SETDMA
  845.     DCR    C    ;MORE SECTORS?
  846.     JNZ    DKWRLP    ;..YES, LOOP
  847.     XRA    A    ;GET A ZERO
  848.     STA    SECINBF    ;RESET # OF SECTORS
  849.     LXI    H,DBUF    ;RESET BUFFER..
  850.     SHLD    SECPTR    ;..POINTER
  851. ;
  852. RSDMA    LXI    D,BASE+80H ;RESET..
  853.     MVI    C,STDMA    ;..DMA..
  854.     CALL    BDOS    ;..ADDR
  855.     RET
  856. ;
  857. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  858.     CALL    ILPRT    ;PRINT:
  859.     DB    '++ERROR WRITING FILE',CR,LF,0
  860.     JMP    ABORT    ;EXIT
  861. ;
  862. ;---->    RECV: RECEIVE A CHARACTER
  863. ;
  864. ;TIMEOUT TIME IS IN B, IN SECONDS.  ENTRY VIA
  865. ;"RECVDG" DELETES GARBAGE CHARACTERS ON THE
  866. ;LINE.  FOR EXAMPLE, HAVING JUST SENT A SECTOR,
  867. ;CALLING RECVDG WILL DELETE ANY LINE-NOISE-INDUCED
  868. ;CHARACTERS "LONG" BEFORE THE ACK/NAK WOULD
  869. ;BE RECEIVED.
  870. ;
  871. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  872.     LDA    MODDATP    ;GET A CHAR
  873.     LDA    MODDATP    ;..TOTALLY PURGE UART
  874. ;
  875. RECV    PUSH    D    ;SAVE
  876. ;
  877.     IF    FASTCLK    ;4MHZ?
  878.     MOV    A,B    ;GET TIME REQUEST
  879.     ADD    A    ;DOUBLE IT
  880.     MOV    B,A    ;NEW TIME IN B
  881.     ENDIF
  882. ;
  883. MSEC    LXI    D,50000    ;1 SEC DCR COUNT
  884. MWTI    LDA    MODCTLP    ;CHECK STATUS
  885.     ANI    MODRCVB    ;ISOLATE BIT
  886.     CPI    MODRCVR    ;READY?
  887.     JZ    MCHAR    ;GOT CHAR
  888.     DCR    E    ;COUNT..
  889.     JNZ    MWTI    ;..DOWN..
  890.     DCR    D    ;..FOR..
  891.     JNZ    MWTI    ;..TIMEOUT
  892.     DCR    B    ;MORE SECONDS?
  893.     JNZ    MSEC    ;YES, WAIT
  894. ;
  895. ;MODEM TIMED OUT RECEIVING
  896. ;
  897.     POP    D    ;RESTORE D,E
  898.     STC        ;CARRY SHOWS TIMEOUT
  899.     RET
  900. ;
  901. ;GOT CHAR FROM MODEM
  902. ;
  903. MCHAR    LDA    MODDATP    ;READ THE CHAR
  904.     POP    D    ;RESTORE DE
  905. ;
  906. ;CALC CHECKSUM
  907. ;
  908.     PUSH    PSW    ;SAVE THE CHAR
  909.     ADD    C    ;ADD TO CHECKSUM
  910.     MOV    C,A    ;SAVE CHECKSUM
  911. ;
  912. ;CHECK IF MONITORING REC'D DATA
  913. ;
  914.     LDA    RSEEFLG    ;SEE RECEIVED..
  915.     ORA    A    ;..DATA?
  916.     JZ    MONIN    ;..YES
  917. ;
  918. ;CHECK IF "VIEWING" AND THIS IS A DATA CHAR
  919. ;
  920.     LDA    VSEEFLG    ;VIEWING..
  921.     ORA    A    ;..DATA?
  922.     JNZ    NOMONIN    ;..NO
  923. ;
  924. ;"VIEW" REQUESTED.  SHOW THE CHAR IT IS DATA
  925. ;
  926.     LDA    DATAFLG    ;GET DATA FLAG
  927.     ORA    A    ;TEST IT
  928.     JZ    NOMONIN    ;..OFF, NOT DATA
  929. ;
  930. MONIN    POP    PSW    ;..IS DATA,
  931.     PUSH    PSW    ;GET IT,
  932.     CALL    SHOW    ;..AND SHOW IT
  933. ;
  934. NOMONIN    POP    PSW    ;RESTORE CHAR
  935.     ORA    A    ;CARRY OFF: NO ERROR
  936.     RET        ;FROM "RECV"
  937. ;
  938. ;---->    SEND: SEND A CHARACTER TO THE MODEM
  939. ;
  940. SEND    PUSH    PSW    ;SAVE THE CHAR
  941. ;
  942. ;CHECK IF MONITORING SENT DATA
  943. ;
  944.     LDA    SSEEFLG    ;CHECK IF MONITORING..
  945.     ORA    A    ;..SENT DATA
  946.     JZ    MONOUT    ;..YES
  947. ;
  948. ;CHECK IF "VIEWING" THE FILE
  949. ;
  950.     LDA    VSEEFLG    ;GET VIEW FLAG
  951.     ORA    A    ;TEST IT
  952.     JNZ    NOMONOT    ;NO
  953.     LDA    DATAFLG    ;IS THIS
  954.     ORA    A    ;..DATA?
  955.     JZ    NOMONOT    ;..NO.
  956. ;
  957. MONOUT    POP    PSW    ;GET THE CHAR
  958.     PUSH    PSW    ;SAVE IT
  959.     CALL    SHOW    ;SHOW IT
  960. ;
  961. NOMONOT    POP    PSW    ;RESTORE CHAR
  962.     PUSH    PSW    ;SAVE IT
  963.     ADD    C    ;CALC CKSUM
  964.     MOV    C,A    ;SAVE CKSUM
  965. SENDW    LDA    MODCTLP    ;GET STATUS
  966.     ANI    MODSNDB    ;ISOLATE READY BIT
  967.     CPI    MODSNDR    ;READY?
  968.     JNZ    SENDW    ;..NO, WAIT
  969.     POP    PSW    ;GET CHAR
  970.     STA    MODDATP    ;OUTPUT IT
  971.     RET        ;FROM "SEND"
  972. ;
  973. ;---->    WAITNAK: WAITS FOR INITIAL NAK
  974. ;
  975. ;TO ENSURE NO DATA IS SENT UNTIL THE RECEIVING
  976. ;PROGRAM IS READY, THIS ROUTINE WAITS FOR THE
  977. ;THE FIRST TIMEOUT-NAK FROM THE RECEIVER.
  978. ;(E) CONTAINS THE # OF SECONDS TO WAIT.
  979. ;
  980. WAITNAK    LDA    VSEEFLG    ;VIEWING?
  981.     ORA    A
  982.     JZ    WAITNPR    ;PRINT MSG
  983.     LDA    QFLG    ;QUIET..
  984.     ORA    A    ;..MODE?
  985.     JZ    WAITNLP    ;YES, SKIP MSG
  986. ;
  987. WAITNPR    CALL    ILPRT    ;PRINT:
  988.     DB    'AWAITING INITIAL NAK',CR,LF,0
  989. ;
  990. WAITNLP    MVI    B,1    ;TIMEOUT DELAY
  991.     CALL    RECV    ;DID WE GET..
  992.     CPI    NAK    ;..A NAK?
  993.     RZ        ;YES, SEND BLOCK
  994.     DCR    E    ;80 TRIES?
  995.     JZ    ABORT    ;YES, ABORT
  996.     JMP    WAITNLP    ;NO, LOOP
  997. ;
  998. ;---->    INITADR: INIT'S CP/M BDOS ADDRESSES
  999. ;
  1000. ;THIS ROUTINE FILLS IN THE ADDRESSES OF VARIOUS
  1001. ;JMP AND CALL INSTRUCTIONS, SO THAT CP/M BDOS
  1002. ;IS BYPASSED WHILE ACCESSING THE CONSOLE.  THIS
  1003. ;IS DONE TO ALLOW CHARACTERS SUCH AS CONTROL-C
  1004. ;AND CONTROL-S TO BE KEYED WHILE IN TERMINAL
  1005. ;MODE, WITHOUT CP/M INTERPRETING THEM.
  1006. ;
  1007. INITADR    LHLD    BASE+1    ;GET WARM BOOT ADDR
  1008.     LXI    D,3    ;LENGTH OF A 'JMP'
  1009.     DAD    D    ;TO CONSOLE STAT
  1010.     SHLD    VSTAT+1    ;MODIFY CALL
  1011.     DAD    D    ;TO CONSOLE IN
  1012.     SHLD    VKEYIN+1 ;MODIFY CALL
  1013.     DAD    D    ;TO CONSOLE OUT
  1014.     SHLD    VTYPE+1    ;MODIFY CALL
  1015.     RET
  1016. ;
  1017. ;---->    PROCOPT: PROCESS COMMAND OPTIONS
  1018. ; 
  1019. ;1) SAVES THE PRIMARY OPTION IN 'OPTION';
  1020. ;2) SCANS THE SUB-OPTION CHARACTERS, AND FOR
  1021. ;EACH FOUND, ZEROS THE APPROPRIATE ENTRY IN
  1022. ;THE OPTION TABLE.  FOR EXAMPLE, IF 'D' IS 
  1023. ;CODED (DISCONNECT) THEN THE 'D' STORED AT
  1024. ;'DISCFLG' IS SET TO 0 SO IT CAN BE TESTED
  1025. ;LATER.
  1026. ;
  1027. PROCOPT    LXI    D,FCB+1    ;TO PRIMARY OPT.
  1028.     LDAX    D    ;GET PRIMARY
  1029.     STA    OPTION    ;SAVE IT
  1030. ;
  1031. OPTLP    INX    D    ;TO SECONDARY OPTION
  1032.     LDAX    D    ;GET CHAR
  1033. ;
  1034. ;IF YOU MOD THIS PROGRAM FOR >7 OPTIONS,
  1035. ;YOU MUST CHANGE THE FOLLOWING, SINCE
  1036. ;THERE WON'T BE A ' ' AFTER THE OPTION
  1037. ;IF A BAUD RATE WAS SPECIFIED.
  1038. ;
  1039.     CPI    ' '    ;NO MORE OPT'NS?
  1040.     JZ    ENDOPT    ;..YES
  1041. ;SET THE APPROP. OPT: STORE 0 IN IT
  1042.     LXI    H,OPTBL    ;HL = ADDR OF 'OAQDSRV'
  1043.     MVI    B,OPTBE-OPTBL ;OPT TABLE LEN
  1044. ;
  1045. OPTCK    CMP    M    ;FOUND THE OPTION?
  1046.     JNZ    OPTNO    ;NO, DON'T SET IT
  1047.     MVI    M,0    ;SET THE OPTION
  1048.     JMP    OPTLP    ;GET NEXT OPTION
  1049. ;
  1050. OPTNO    INX    H    ;TO NEXT
  1051.     DCR    B    ;MORE?
  1052.     JNZ    OPTCK
  1053. ;OPTION NOT IN TABLE
  1054.     JMP    BADOPT    ;SHOW BAD SUB OPTION
  1055. ;
  1056. ;IF "VIEW" WAS ASKED FOR, SET QUIET FLAG
  1057. ;
  1058. ENDOPT    LDA    VSEEFLG    ;VIEW..
  1059.     ORA    A    ;..ASKED FOR?
  1060.     RNZ        ;..NO, RET FROM 'PROCOPT'
  1061.     STA    QFLG    ;YES, NO HDR/CKSUM PRT
  1062.     RET        ;FROM 'PROCOPT'
  1063. ;
  1064. ;DONE - CLOSE UP SHOP
  1065. ;
  1066. DONE    LDA    VSEEFLG    ;VIEWING?
  1067.     ORA    A
  1068.     JZ    DONETC    ;SHOW MSG
  1069.     LDA    QFLG    ;QUIET
  1070.     ORA    A    ;..MODE?
  1071.     JZ    DONECTE    ;YES, CK TERM/ECHO
  1072. ;
  1073. DONETC    CALL    ILPRT
  1074.     DB    CR,LF,'TRANSFER COMPLETE' 
  1075.     DB    CR,LF,0
  1076. ;
  1077. ;CHECK IF TERMINAL OR ECHO SUB COMMAND
  1078. ;WAS SPECIFIED
  1079. ;
  1080. DONECTE    LDA    TERMFLG    ;TERM?
  1081.     ORA    A
  1082.     JZ    TERM    ;..YES
  1083.     LDA    ECHOFLG    ;ECHO?
  1084.     ORA    A
  1085.     JZ    TRMECHO    ;..YES
  1086. ;
  1087. ;FALL INTO 'CKDIS'
  1088. ;
  1089. ;---->    CKDIS: CHECK IF DISCONNECT REQUESTED
  1090. ;
  1091. ;THIS ROUTINE IS JUMPED TO AT THE END OF
  1092. ;PROCESSING, AND DISCONNECTS THE PHONE IF
  1093. ;'D' WAS SPECIFIED AS A SUB-OPTION.
  1094. ;
  1095. CKDIS    LDA    DISCFLG    ;CHECK 'D' FLAG
  1096.     ORA    A    ;REQUESTED?
  1097. ;
  1098.     IF    MMII
  1099.     JNZ    NDIS    ;..NO, JUST EXIT
  1100.     ENDIF
  1101. ;
  1102.     IF    NOT MMII
  1103.     JNZ    EXIT
  1104.     ENDIF
  1105. ;
  1106. ;AWAIT C/R TO DISC. SO WE DON'T LOSE THE PHONE
  1107. ;
  1108.     CALL    ILPRT
  1109.     DB    CR,LF,'PRESS RETURN TO DISCONNECT:',0
  1110.     CALL    KEYIN
  1111.     PUSH    PSW
  1112.     CALL    CRLF
  1113.     POP    PSW
  1114.     CPI    CR
  1115.     JNZ    CKDIS    ;ASK AGAIN
  1116. ;
  1117. ;---->    DISCONN: DISCONNECT THE PHONE
  1118. ;
  1119. DISCONN    EQU    $
  1120. ;
  1121.     IF    MMII
  1122.     XRA    A    ;GET DISCONNECT VALUE
  1123.     STA    MODCTL2    ;DISCONNECT
  1124.     ENDIF
  1125. ;
  1126.     CALL    ILPRT    ;PRINT:
  1127.     DB    '++DISCONNECTED++',0
  1128.     JMP    EXIT
  1129. ;
  1130. ;NO DISCONNECT, TYPE MSG AS REMINDER THAT PHONE'S
  1131. ;OFF HOOK
  1132. ;
  1133.     IF    MMII
  1134. NDIS    LDA    QFLG    ;QUIET..
  1135.     ORA    A    ;..MODE?
  1136.     JZ    EXIT    ;..YES, NO MSG
  1137.     CALL    ILPRT
  1138.     DB    CR,LF,'++DON''T FORGET - THE MODEM IS '
  1139.     DB    'NOT DISCONNECTED++',CR,LF
  1140.     DB    'USE "MODEM D" TO DISCONNECT',CR,LF,0
  1141.     JMP    EXIT
  1142. ;
  1143.     ENDIF
  1144. ;
  1145. ;---->    INITMOD: INITIALIZES THE MODEM
  1146. ;
  1147. ;THIS ROUTINE IS USED TO INITIALIZE SERIAL
  1148. ;BOARDS, OR SETUP S-100 MODEM BOARDS.
  1149. ;JUST RETURNS IF NO INITIALIZATION REQUIRED.
  1150. ;
  1151. INITMOD:
  1152. ;
  1153.     IF    INITREQ  ;REQUIRE INIT?
  1154.     MVI    A,INITC1 ;GET 1ST INIT CHAR
  1155.     STA    MODCTLP     ;OUTPUT IT
  1156.     NOP ! NOP! NOP     ;DELAY FOR USART
  1157.     NOP ! NOP
  1158.     MVI    A,INITC2 ;GET 2ND INIT CHAR
  1159.     STA    MODCTLP     ;OUTPUT IT
  1160.     NOP ! NOP! NOP     ;DELAY FOR USART
  1161.     NOP ! NOP
  1162.     ENDIF
  1163. ;
  1164.     IF    MMII
  1165.     CALL    GETBAUD    ;GET BAUD RATE
  1166.     LDA    ANSWFLG        ;ANSWER..
  1167.     ORA    A
  1168.     MVI    B,ANSWMOD    ;SET ANSWER MODE
  1169.     JZ    INITM1
  1170.     LDA    ORIGFLG        ;GET ORIGINATE FLAG
  1171.     ORA    A
  1172.     MVI    B,ORIGMOD    ;SET ORIGINATE MODE
  1173.     JZ    INITM1
  1174.     LDA    HOLDD        ;NEITHER - GET LAST VALUE
  1175.     MOV    B,A        ;STORE IN"B
  1176. ;
  1177. INITM1:    MOV    A,B        ;GET MODE
  1178.     STA    HOLDD        ;SAVE VALUE
  1179.     MOV    A,C        ;GET BAUD RATE INDICATOR
  1180.     ORA    A        ;ZEBO IF 110 BAUD
  1181.     MOV    A,B        ;GET MODE
  1182.     JZ    OFFHOOK        ;DO OFFHOOK
  1183.     ORI    1        ;SET 300 BAUD
  1184. ;GO OFFHOOK IN REQUESTED (ORIG/ANSW) MODE
  1185. ;
  1186. OFFHOOK    LXI    H,4000    ;DELAY AMT
  1187. ;
  1188. OFFDLY    DCR    L
  1189.     JNZ    OFFDLY
  1190.     DCR    H
  1191.     JNZ    OFFDLY
  1192.     STA    MODCTL2    ;GO OFF HOOK
  1193.     RET
  1194.     ENDIF        ;MMII
  1195. ;
  1196.     IF    MMII
  1197. GETBAUD    LDA    FCB+9    ;GET FILETYPE
  1198.     CPI    ' '    ;DEFAULT?
  1199.     JNZ    GETBAU1    ;NO - DO BAUD RATE STUFF
  1200.     MVI    C,1    ;SET 300 BAUD
  1201.     MVI    B,15H    ;SET 1 STOP BIT
  1202.     JMP    GETBAU2
  1203. ;
  1204. ; CONVERT BAUD RATE TO BINARY
  1205. GETBAU1    CALL    CVBIN    ;CONVERT TO BINARY
  1206.     PUSH    H    ;SAVE BAUD RATE
  1207.     MVI    C,0    ;ANTICIPATE 110 BAUD
  1208.     MVI    B,15H    ;SET 2 STOP BITS
  1209.     LXI    D,-110    ;GET CONSTANT
  1210.     DAD    D    ;SUBTRACT
  1211.     MOV    A,H
  1212.     ORA    L
  1213.     POP    H
  1214.     JZ    GETBAU2    ;110 BAUD
  1215.     MVI    B,15H    ;SET 1 STOP BIT
  1216.     INR    C
  1217.     LXI    D,-300    ;GET CONSTANT
  1218.     DAD    D
  1219.     MOV    A,H
  1220.     ORA    L
  1221.     JNZ    BADRATE    ;INVALID
  1222. ;
  1223. GETBAU2    MOV    A,B    ;GET SET UP
  1224.     STA    MODCTLP    ;INITIALIZE MODEM FOR STOP BITS..
  1225.     RET        ;..DATA BITS, ETC.
  1226.     ENDIF        ;DCH
  1227. ;
  1228.     IF COMCARD    ;APPLE COMMUNCATIONS CARD
  1229. GETBAUD    LDA    FCB+9    ;GET FILETYPE
  1230.     CPI    ' '    ;DEFAULT?
  1231.     JNZ    GETBAU1 ;NO - DO BAUD RATE STUFF
  1232.     MVI    B,11H    ;300 BAUD STATUS CODE
  1233.     JMP    GETBAU2
  1234. ;  CONVERT BAUD RATE TO BINARY
  1235. GETBAU1    CALL    CVBIN    ;CONVERT TO BINARY
  1236.     PUSH    H    ;SAVE BAUD RATE
  1237.     MVI    B,52H    ;ANTICIPATE 110 BAUD
  1238.     LXI    D,-110    ;GET CONSTANT
  1239.     DAD    D    ;SUBTRACT
  1240.     MOV    A,H    
  1241.     ORA    L
  1242.     POP    H
  1243.     JZ    GETBAU2    ;110 BAUD
  1244.     MVI    B,11H    ;300 BAUD STATUS CODE
  1245.     INR    C
  1246.     LXI    D,-300    ;GET CONSTANT
  1247.     DAD    D
  1248.     MOV    A,H
  1249.     ORA    L
  1250.     JNZ    BADRATE    ;INVALID RATE (300 OR 110 ONLY)
  1251. GETBAU2    MOV    A,B    ;GET SET UP
  1252.     STA    MODCTLP    ;STORE TO STATUS PORT
  1253.     RET
  1254.     ENDIF    ;COMCARD
  1255. ;
  1256.     IF    COMCARD OR MMII
  1257. ; ROUTINE TO CONVERT BAUD RATE TO BINARY
  1258. ;
  1259. CVBIN:    LXI    D,FCB+9    ;TO ASCII VALUE
  1260.     LXI    H,0    ;INIT BINARY RESULT
  1261. ;
  1262. DECLP    LDAX    D    ;GET ASCII DIGIT
  1263.     INX    D    ;TO NEXT DIGIT
  1264.     CPI    ' '    ;BLANK ONE?
  1265.     JZ    DECLP    ;..YES, SKIP IT
  1266.     CPI    '0'    ;VALIDATE IT
  1267.     JC    BADRATE    ;ERROR
  1268.     CPI    '9'+1    ;VALIDATE
  1269.     JNC    BADRATE    ;ERROR
  1270.     SUI    '0'    ;MAKE DIGIT BINARY
  1271. ;
  1272. ;MULTIPLY PREV VALUE BY 10
  1273. ;
  1274.     MOV    B,H    ;SET UP FOR
  1275.     MOV    C,L    ;MULTIPLY BY 10
  1276.     DAD    H    ;MULTIPLY BY 2
  1277.     DAD    H    ;X 2 = 4
  1278.     DAD    B    ;+ 1 = 5
  1279.     DAD    H    ;X 2 = 10
  1280.     ADD    L    ;ADD IN DIGIT
  1281.     MOV    L,A    ;SAVE BACK
  1282.     JNZ    DIGNC    ;NO CARRY?
  1283.     INR    H    ;ADD IN CARRY
  1284. ;CHECK IF DONE?
  1285. DIGNC    MOV    A,E    ;SEE IF PAST
  1286.     CPI    FCB+12    ;..LAST DIGIT
  1287.     JNZ    DECLP    ;NO, LOOP
  1288.     RET
  1289. ;
  1290. ;INVALID BAUD RATE
  1291. ;
  1292. BADRATE    CALL    ERXIT
  1293.     DB    '++INVALID BAUD RATE++$'
  1294.     ENDIF        ;PMMI OR DCH
  1295. ;
  1296. ;THE FOLLOWING PROVIDES A RETURN FROM INITMOD
  1297.     IF    NOT MMII AND NOT COMCARD
  1298.     RET        ;**THIS MUST BE HERE**
  1299.     ENDIF        ;NOT PMMI AND NOT DCH
  1300. ;
  1301. ;---->  CONNCT: AUTODIAL ROUTINE FOR THE DC HAYES
  1302. ;
  1303.     IF    MMII
  1304. CONNCT    CALL    ILPRT    ;PRINT MESSAGE
  1305.     DB    'Number to dial: ',0
  1306.     LXI    D,NUMBUF ;POINT TO BUFFER
  1307. GETDIG    CALL    KEYIN    ;GET CHAR FROM KEYBOARD
  1308.     CPI    CR    ;IS IT END OF LINE?
  1309.     JZ    DIAL    ;..YES, DIAL THE NUMBER
  1310.     CPI    8    ;BACKSPACE
  1311.     JZ    DERD    ;DECREMENT BUFFER
  1312.     STAX    D    ;..NO, STORE IN BUFFER
  1313.     INX    D    ;D:=D+1
  1314.     CALL     TYPE    ;TYPE IT TO CONSOLE
  1315.     JMP    GETDIG    ;LOOP BACK FOR MORE INPUT
  1316. DERD    DCX    D
  1317.     CALL    TYPE    ;BACKSPACE TO CONSOLE
  1318.     JMP    GETDIG    ;LOOP BACK
  1319. DIAL    INX    D    ;D:=D+1
  1320.     MVI    B,CR    ;EOLN MARKER
  1321.     MOV    A,B
  1322.     STAX    D    ;STORE IT IN BUFFER
  1323.     CALL    ILPRT
  1324.     DB    CR,LF,'Dialing...',0
  1325.     MVI    B,OFHKFLG ;80H
  1326.     MOV    A,B
  1327.     CALL    DLTONE    ;GET DIALTONE
  1328.     LXI    D,NUMBUF ;POINT TO BUFFER
  1329. NXTDIG  LDAX    D    ;GET A DIGIT
  1330.     INX    D    ;INCREMENT REGISTERS
  1331.     ORA    A    ;SOMETHING THERE?
  1332.     JZ    NONUM    ;..NO, EXIT WITH ERROR
  1333.     CPI    CR    ;DONE?
  1334.     JZ    GETCAR    ;GET CARRIER
  1335.     MOV    C,A    ;SAVE IT
  1336.     CALL     TYPE    ;TYPE TO CONSOLE
  1337.     MOV     A,C    ;RESTORE TO A
  1338.     CPI    3AH    ;IGNORE ALL BUT DIGITS
  1339.     JNC    NXTDIG    ;LOOP BACK
  1340.     CPI    '0'
  1341.     JC    NXTDIG
  1342.     MOV     C,A
  1343.     CALL    PULSE    ;DIAL IT
  1344.     JMP    NXTDIG    ;LOOP BACK FOR MORE FROM BUFFER
  1345. ;
  1346. PULSE    PUSH    B    ;SAVE BC
  1347.     MOV    A,C
  1348.     MVI    B,10    ;PRE LOAD PULSE REGISTER
  1349.     ANI    0FH    ;KILL ASCII BIAS
  1350.     CPI    0    ;IF NUM A 0 THEN WANT 10 PULSES
  1351.     JZ    PULS1    
  1352.     MOV    B,A    ;LOAD PULSE COUNT FROM DIAL
  1353. PULS1    MVI    C,0    ;ON HOOK
  1354.     MOV     A,C    
  1355.     STA    MODCTL2    ;GO ON HOOK
  1356.     CALL     DELAY    ;50 MS
  1357.     MVI    C,80H    ;OFF HOOK
  1358.     MOV    A,C    
  1359.     STA    MODCTL2    ;GO OFF HOOK
  1360.     CALL     DELAY    ;50 MS
  1361.     DCR    B    ;COUNT DOWN 1 PULSE
  1362.     JNZ    PULS1    ;NOT ZERO, MAKE ANOTHER PULSE
  1363.     CALL    KDELAY    ;500 MS INTERDIGIT DELAY
  1364.     POP    B    ;RESTORE BC
  1365.     RET
  1366. ;
  1367. ; 50MS DELAY ROUTINE
  1368. DELAY    PUSH    PSW
  1369.     PUSH    B
  1370.     LXI    B,5000
  1371. DELAY1    DCX    B
  1372.     MOV    A,B
  1373.     ORA    C
  1374.     JNZ    DELAY1
  1375.     POP    B
  1376.     POP    PSW
  1377.     RET
  1378. ;
  1379. ;1 SEC DELAY ROUTINE
  1380. KDELAY    MVI    L,15
  1381. KD1    DCR    L
  1382.     JZ    FINIS
  1383.     CALL     DELAY
  1384.      JMP    KD1
  1385. FINIS    RET
  1386. ;
  1387. DLTONE    CALL    OFFHOOK    ;GO OFFHOOK
  1388.     CALL    KDELAY
  1389.     CALL    KDELAY
  1390.     CALL    KDELAY
  1391.     CALL    KDELAY     ;WAIT 4 SEC BEFORE DIALING
  1392.     RET
  1393. ;
  1394. GETCAR    CALL    ILPRT
  1395.     DB    CR,LF,'++AWAITING CARRIER',CR,LF,0
  1396.     MVI    C,30    ;WAIT 30 SEC FOR CARRIER
  1397. GETCAR1    MVI    B,3    ;RESET MODEM
  1398.     MOV    A,B
  1399.     STA    MODCTLP
  1400.     MVI    B,8DH    ;OFF HOOK, ORIG., BUT NO CARRIER
  1401.     MOV    A,B
  1402.     STA    MODCTL2    ;RESET MODEM STATUS
  1403.     MVI    B,0
  1404.     MOV    A,B
  1405.     CALL    KDELAY    ;WAIT AGAIN
  1406.     LDA    MODCTLP    ;CHECK STATUS
  1407.     ANI    04    ;ISOLATE NO CARRIER BIT
  1408.     XRI    04    ;REVERSE LOGIC
  1409.     JNZ    CERTIFY    ;CARRIER FOUND...MAYBE
  1410. NOPE    CALL    DELAY    ;IT WASN'T A CARRIER
  1411.     DCR    C    ;COUNTDOWN
  1412.      JNZ    GETCAR1    ;LOOP     
  1413.     CALL    ILPRT
  1414.     DB    '++TIMED OUT LOOKING FOR CARRIER',CR,LF,0
  1415.     CALL    DISCONN    ;HANG UP
  1416. CERTIFY    CALL    KDELAY    ;MAKE SURE CARRIER IS REALLY THERE
  1417.     CALL     KDELAY
  1418.     LDA    MODCTLP    ;CHECK STATUS
  1419.     ANI    04    ;ISOLATE NO CARRIER BIT
  1420.     XRI    04    ;REVERSE LOGIC
  1421.     JZ    NOPE    ;IT WAS SPURIOUS,LOOP BACK
  1422. GOTCAR    CALL     ILPRT
  1423.     DB    '++CARRIER DETECTED',CR,LF,0
  1424.     JMP    RTNC    ;GO BACK TO START FOR TERMINAL MODE
  1425. ;
  1426. NONUM    CALL    ILPRT    
  1427.     DB    '++NO NUMBER WAS FOUND FOR DIALING++',CR,LF,0
  1428.     JMP    EXIT
  1429.     ENDIF        ;MMII
  1430. ;
  1431. ;---->    MOVEFCB: MOVES FCB(2) TO FCB
  1432. ;
  1433. ;I ATTEMPTED TO MAKE THE MODEM COMMAND 'NATURAL',
  1434. ;I.E. MODEM SEND FILENAME (MODEM S FN.FT) RATHER
  1435. ;THAT MODEM FILENAME SEND (MODEM FN.FT S) SO THIS
  1436. ;ROUTINE MOVES THE FILENAME FROM THE SECOND FCB
  1437. ;TO THE FIRST
  1438. ;
  1439. MOVEFCB    LXI    H,FCB+16 ;FROM
  1440.     LXI    D,FCB    ;TO
  1441.     MVI    B,16    ;LEN
  1442.     CALL    MOVE    ;DO THE MOVE
  1443.     XRA    A    ;GET 0
  1444.     STA    FCBSNO    ;ZERO SECTOR #
  1445.     STA    FCBEXT    ;..AND EXTENT
  1446.     RET
  1447. ;
  1448. ;---->    SHOW: SHOWS CHAR SENT/RECEIVED
  1449. ;
  1450. ;CR, LF, AND TAB ARE SHOWN.  ALL OTHER
  1451. ;NON-PRINTABLE CHARACTERS ARE SHOWN IN
  1452. ;HEX AS (XX)
  1453. ;
  1454. SHOW    CPI    LF    ;LF?
  1455.     JZ    CTYPE    ;..YES, TYPE IT
  1456.     CPI    CR    ;CR?
  1457.     JZ    CTYPE    ;..YES, TYPE IT
  1458.     CPI    09    ;TAB
  1459.     JZ    CTYPE    ;..YES, TYPE IT
  1460.     CPI    ' '    ;CTL-CHR?
  1461.     JC    SHOWHEX    ;YES, SHOW IN HEX
  1462.     CPI    7FH    ;DEL?
  1463.     JC    CTYPE    ;NO, TYPE THE CHAR
  1464. ;
  1465. SHOWHEX    PUSH    PSW    ;SAVE THE CHAR
  1466.     MVI    A,'('    ;TYPE..
  1467.     CALL    CTYPE    ;..'('
  1468.     POP    PSW    ;THEN..
  1469.     CALL    HEXO    ;..THE CHAR
  1470.     MVI    A,')'    ;THEN..
  1471.     JMP    CTYPE    ;..')' AND RETURN.
  1472. ;
  1473. ;---->    CTYPE: TYPES VIA CP/M SO TABS ARE EXPANDED
  1474. ;
  1475. CTYPE    PUSH    B    ;SAVE..
  1476.     PUSH    D    ;..ALL..
  1477.     PUSH    H    ;..REGS
  1478.     MOV    E,A    ;CHAR TO E
  1479.     MVI    C,WRCON    ;GET BDOS FNC
  1480.     CALL    BDOS    ;PRIN THE CHR
  1481.     POP    H    ;RESTORE..
  1482.     POP    D    ;..ALL..
  1483.     POP    B    ;..REGS
  1484.     RET        ;FROM "CTYPE"
  1485. ;
  1486. CRLF    MVI    A,CR
  1487.     CALL    TYPE
  1488.     MVI    A,LF
  1489. ;
  1490. ;---->    TYPE: TYPE VIA DIRECT CBIOS ACCESS
  1491. ;WE ASSUME CBIOS MAY DESTROY SOME REGISTERS,
  1492. ;SO SAVE THEM ALL.
  1493. ;
  1494. ;THIS ROUTINE BYPASSES CP/M'S CTL-S, CTL-C
  1495. ;TESTS.
  1496. ;
  1497. TYPE    PUSH    PSW    ;SAVE CHAR
  1498.     PUSH    B    ;AND OTHER REGISTERS
  1499.     PUSH    D
  1500.     PUSH    H
  1501.     MOV    C,A    ;FOR BIOS
  1502. VTYPE    CALL    $-$    ;MODIFIED AT INIT
  1503.     POP    H    ;RESTORE REGISTERS
  1504.     POP    D
  1505.     POP    B
  1506.     POP    PSW    ;..AND CHAR
  1507.     RET        ;FROM "TYPE"
  1508. ;
  1509. ;---->  STAT: KEYBOARD STATUS
  1510. ;
  1511. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1512. ;CBIOS CLOBBERS THEM.
  1513. ;
  1514. STAT    PUSH    B
  1515.     PUSH    D
  1516.     PUSH    H
  1517. VSTAT    CALL    $-$    ;ADDR SET AT INIT
  1518.     POP    H
  1519.     POP    D
  1520.     POP    B
  1521.     ORA    A    ;0 => NOT READY
  1522.     RET
  1523. ;
  1524. ;---->  KEYIN: KEYBOARD INPUT
  1525. ;
  1526. ;SAVE ALL REGISTERS, EXCEPT A, IN CASE
  1527. ;CBIOS CLOBBERS THEM.
  1528. ;
  1529. KEYIN    PUSH    B
  1530.     PUSH    D
  1531.     PUSH    H
  1532. VKEYIN    CALL    $-$    ;ADDR SET AT INIT
  1533.     POP    H
  1534.     POP    D
  1535.     POP    B
  1536.     ANI    7FH    ;STRIP PARITY IF THERE
  1537.     RET        ;FROM KEYIN
  1538. ;
  1539. ;---->  HEXO: HEX OUTPUT
  1540. ;
  1541. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1542.     RAR        ;RIGHT..
  1543.     RAR        ;..JUSTIFY..
  1544.     RAR        ;..LEFT..
  1545.     RAR        ;..DIGIT..
  1546.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1547.     POP    PSW    ;RESTORE RIGHT
  1548. ;
  1549. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1550.     CPI    10    ;IS IS <10?
  1551.     JC    ISNUM    ;YES, NOT ALPHA
  1552.     ADI    7    ;ADD ALPHA BIAS
  1553. ;
  1554. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1555.     JMP    TYPE    ;..THEN TYPE IT
  1556. ;
  1557. ;---->    CKQUIT: QUIT/RETRY AFTER MULTIPLE ERRS.
  1558. ;
  1559. ;RETURNS W/ ZERO SET IF "RETRY" ASKED FOR
  1560. ;
  1561. CKQUIT    XRA    A    ;ZERO..
  1562.     STA    ERRCT    ;..ERROR COUNT
  1563.     CALL    ILPRT    ;PRINT:
  1564.     DB    'MULTIPLE ERRORS ENCOUNTERED.  '
  1565.     DB    'TYPE Q TO QUIT, R TO RETRY: ',0
  1566.     CALL    KEYIN    ;QUIT/RETRY
  1567.     PUSH    PSW
  1568.     CALL    TYPE
  1569.     CALL    CRLF
  1570.     POP    PSW
  1571.     ANI    5FH    ;MAKE UPPER CASE
  1572.     CPI    'R'    ;RETRY?
  1573.     RZ        ;'KEEP ON TRUCKIN'
  1574.     CPI    'Q'    ;QUIT?
  1575.     JNZ    CKQUIT    ;NO, ASK AGAIN
  1576.     ORA    A    ;SET NON-ZERO
  1577.     RET
  1578. ;
  1579. ;---->    ILPRT: INLINE PRINT OF MSG
  1580. ;
  1581. ;THE CALL TO ILPRT IS FOLLOWED BY A MESSAGE,
  1582. ;BINARY 0 AS THE END.  BINARY 1 MAY BE USED TO
  1583. ;PAUSE (MESSAGE 'PRESS RETURN TO CONTINUE')
  1584. ;
  1585. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1586. ;
  1587. ILPLP    MOV    A,M    ;GET CHAR
  1588.     ORA    A    ;END OF MSG?
  1589.     JZ    ILPRET    ;..YES, RETURN
  1590.     CPI    1    ;PAUSE?
  1591.     JZ    ILPAUSE    ;..YES
  1592.     CALL    CTYPE    ;TYPE THE MSG
  1593. ;
  1594. ILPNEXT    INX    H    ;TO NEXT CHAR
  1595.     JMP    ILPLP    ;LOOP
  1596. ;
  1597. ;PAUSE WHILE TYPING HELP SO INFO DOESN'T
  1598. ;    SCROLL OFF OF VIDEO SCREENS
  1599. ;
  1600. ILPAUSE    CALL    ILPRT    ;PRINT:
  1601.     DB    CR,LF,'PRESS RETURN TO CONTINUE'
  1602.     DB    CR,LF,0
  1603.     CALL    KEYIN    ;GET ANY CHAR
  1604.     CPI    'C'-40H    ;REBOOT?
  1605.     JZ    EXIT    ;YES.
  1606.     JMP    ILPNEXT    ;LOOP
  1607. ;
  1608. ILPRET    XTHL        ;RESTORE HL
  1609.     RET        ;PAST MSG
  1610. ;
  1611. ;---->    PRTMSG: PRINTS MSG POINTED TO BY (DE)
  1612. ;
  1613. ;A '$' IS THE ENDING DELIMITER FOR THE PRINT.
  1614. ;NO REGISTERS SAVED.
  1615. ;
  1616. PRTMSG    MVI    C,PRINT    ;GET BDOS FNC
  1617.     JMP    BDOS    ;PRINT MESSAGE, RETURN
  1618. ;
  1619. ;---->    ERXIT: EXIT PRINTING MSG FOLLOWING CALL
  1620. ;
  1621. ERXIT    POP    D    ;GET MESSAGE
  1622.     CALL    PRTMSG    ;PRINT IT
  1623.     CALL    CKDIS    ;DISCONNECT?
  1624. ;
  1625. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1626.     SPHL        ;RESTORE IT
  1627.     RET        ;--EXIT-- TO CP/M
  1628. ;
  1629. ;MOVE 128 CHARACTERS
  1630. ;
  1631. MOVE128    MVI    B,128    ;SET MOVE COUNT
  1632. ;
  1633. ;MOVE FROM (HL) TO (DE) LENGTH IN (B)
  1634. ;
  1635. MOVE    MOV    A,M    ;GET A CHAR
  1636.     STAX    D    ;STORE IT
  1637.     INX    H    ;TO NEXT "FROM"
  1638.     INX    D    ;TO NEXT "TO"
  1639.     DCR    B    ;MORE?
  1640.     JNZ    MOVE    ;..YES, LOOP
  1641.     RET        ;..NO, RETURN
  1642. ;    ----------------
  1643. OPTION    DB    0    ;PRIMARY OPTION
  1644. ;
  1645. ;DATAFLG IS USED BY THE "V" SUBCOMMAND -
  1646. ;IT IS 0 WHEN A HEADER OR CKSUM IS BEING
  1647. ;SENT/RCD, AND 1 IF "VIEWABLE" DATA (THE
  1648. ;SECTOR ITSELF) IS
  1649. ;
  1650. DATAFLG    DB    0    ;AT HEADER, FIRST
  1651. ;
  1652. ;
  1653. ;SUB-OPTION TABLE.  IF AN OPTION IS IN EFFECT,
  1654. ;    THE CHARACTER IS SET TO BINARY 0
  1655. ;
  1656. OPTBL    EQU    $
  1657. ANSWFLG    DB    'A'    ;ANSWER MODE
  1658. DISCFLG    DB    'D'    ;DISCONNECT WHEN DONE
  1659. ECHOFLG    DB    'E'    ;TO ECHO AFTER XFER
  1660. ORIGFLG    DB    'O'    ;ORIGINATE MODE
  1661. QFLG    DB    'Q'    ;QUIET TRANSFER (NO MSGS)
  1662. RSEEFLG    DB    'R'    ;SEE WHAT'S RECEIVED
  1663. SSEEFLG    DB    'S'    ;SEE WHAT'S SENT
  1664. TERMFLG    DB    'T'    ;TO TERM AFTER XFER
  1665. VSEEFLG    DB    'V'    ;VIEW MESSAGES (NO HDR, ETC)
  1666. OPTBE    EQU    $    ;END OF OPTIONS
  1667. ;
  1668. RCVSNO    DB    0    ;SECT # RECEIVED
  1669. SECTNO    DB    0    ;CURRENT SECTOR NUMBER 
  1670. ERRCT    DB    0    ;ERROR COUNT
  1671. HOLDD    DB    8EH    ;HOLD AREA - LAST DC HAYES CONT CHAR.
  1672. ;FOLLOWING 3 USED BY DISK BUFFERING ROUTINES
  1673. EOFLG    DB    0    ;EOF FLAG (1=TRUE)
  1674. SECPTR    DW    DBUF
  1675. SECINBF    DB    0    ;# OF SECTORS IN BUFFER
  1676.     DS    60    ;STACK AREA
  1677. STACK    DS    2    ;STACK POINTER
  1678. NUMBUF    DS    15    ;BUFFER TO HOLD PHONE NUMBER FOR DIALING
  1679. ;
  1680. ;16 SECTOR DISK BUFFER (OVERLAYS HELP MSGS)
  1681. ;
  1682. DBUF    EQU    $    ;16 SECTOR DISK BUFFER
  1683. ;
  1684. ;INVALID COMMAND
  1685. ;
  1686. BADOPT    CALL    TYPE
  1687.     CALL    ILPRT    ;EXIT W/ERROR
  1688.     DB    ': INVALID OPTION ON MODEM '
  1689.     DB    'COMMAND - ',CR,LF
  1690.  DB 'PRESS RETURN FOR HELP, CTL-C IF NOT',CR,LF,1,0
  1691. ;
  1692. HELP    CALL    ILPRT
  1693.  DB 'Format for command is:',cr,lf,cr,lf
  1694.  DB 'MODEM # FILENAME',CR,LF,CR,LF
  1695.  DB 'Where # is a 1 character primary option,',cr,lf
  1696.  DB ' which may be followed by sub-options,',cr,lf
  1697.  DB ' and by ".xxx" to set baud rate to xxx'
  1698.  DB cr,lf,cr,lf,1
  1699.  DB 'Primary Options:',cr,lf
  1700.  DB '    S to send a file',cr,lf
  1701.  DB '    R to receive a file',cr,lf
  1702.  DB '    T to act as a terminal',cr,lf
  1703.  DB '    E to act as a computer (echo data)',cr,lf
  1704.  DB '    C to connect (Micromodem autodial)',cr,lf
  1705.  DB '    D to disconnect the phone '
  1706.  DB '(Micromodem ][ only)',cr,lf
  1707.  DB '    H to print this help file'
  1708.  DB cr,lf,cr,lf,1
  1709.  DB 'Secondary options:',cr,lf
  1710.  DB '    A answer mode',cr,lf
  1711.  DB '    O originate mode',cr,lf
  1712.  DB '    D disconnect after execution',cr,lf
  1713.  DB '    T go to terminal mode after file xfer',cr,lf
  1714.  DB '    E go to echo mode after file xfer',cr,lf
  1715.  DB '    Q quiet mode - no status msgs',cr,lf
  1716.  DB '    R show chars received',cr,lf
  1717.  DB '    S show chars sent',cr,lf
  1718.  DB '    V view file sent/received (no status)',cr,lf
  1719.  DB CR,LF,'FOR EXAMPLES, TYPE: MODEM X',cr,lf,0
  1720.     JMP    EXIT
  1721. ;
  1722. EXAM    CALL    ILPRT
  1723.  DB 'Send file, originate mode, 300 baud:',CR,LF
  1724.  DB '    MODEM SO fn.ft',cr,lf
  1725.  DB 'Send another file:',CR,LF
  1726.  DB '    MODEM S fn.ft',cr,lf
  1727.  DB 'Then send a third file at 110 baud and disconnect:'
  1728.  DB CR,LF,'    MODEM SD.110 fn.ft',cr,lf
  1729.  DB 'Act as a terminal, originate mode, at 110 baud:',cr,lf
  1730.  DB '    MODEM TO.110',CR,LF
  1731.  DB '    (Use ctl-D to disconnect)',cr,lf
  1732.  DB 'Receive file, answer mode, view it, 110 baud:',cr,lf
  1733.  DB '    MODEM RAV.110 fn.ft',cr,lf
  1734.  DB 'Autodial a number, and connect at .110 baud ',cr,lf
  1735.  DB '        (300 baud is default)',CR,LF
  1736.  DB '    MODEM C.110',CR,LF,0
  1737.     JMP EXIT
  1738. ;
  1739. ; BDOS EQUATES (VERSION 2)
  1740. ;
  1741. RDCON    EQU    1
  1742. WRCON    EQU    2
  1743. PRINT    EQU    9
  1744. CONST    EQU    11    ;CONSOLE STAT
  1745. OPEN    EQU    15    ;0FFH=NOT FOUND
  1746. CLOSE    EQU    16    ;    "    "
  1747. SRCHF    EQU    17    ;    "    "
  1748. SRCHN    EQU    18    ;    "    "
  1749. ERASE    EQU    19    ;NO RET CODE
  1750. READ    EQU    20    ;0=OK, 1=EOF
  1751. WRITE    EQU    21    ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  1752. MAKE    EQU    22    ;0FFH=BAD
  1753. REN    EQU    23    ;0FFH=BAD
  1754. STDMA    EQU    26    ;SET DMA
  1755. BDOS    EQU    BASE+5
  1756. REIPL    EQU    BASE
  1757. FCB    EQU    BASE+5CH    ;SYSTEM FCB
  1758. FCBEXT    EQU    FCB+12        ;FILE EXTENT
  1759. FCBSNO    EQU    FCB+32        ;SECTOR #
  1760. FCB2    EQU    BASE+6CH    ;SECOND FCB
  1761.     END
  1762.  
  1763.  
  1764.  
  1765.  
  1766.