home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol068 / mft46a.asm < prev    next >
Assembly Source File  |  1984-04-29  |  18KB  |  935 lines
  1. ;;;     mft - multiple file transfer (for single drive systems)
  2. ;
  3. ;     **Based on article in Dr. Dobbs Journal of Computer**
  4. ; **Calisthenics & Orthodontia #49, Box E, Menlo Park, Ca. 94025**
  5. ;        -------------------------
  6. ;
  7. ;    Version 4.6A - gfn3 routine restored to version 4.5 -
  8. ;    4.6 revision did not handle eight char. filenames.
  9. ;    I could not reproduce the error reported by cml when
  10. ;    copying ufn.<sp><sp><sp>. (CHS) 4/30/81
  11. ;
  12. ;    Modified to VER. 4.6 to strip off $R/O attribute
  13. ;    in output filename.  If source was R/O then cp/m 
  14. ;    gave a "Bdos error on $R/O file" when an attempt was
  15. ;    made to write to the newly created file.
  16. ;
  17. ;    Changed 'jz    gfn4' in rtn. gfn3
  18. ;    to    'jz    gfn3' in order to ignore spaces
  19. ;    in the file type. Before, whenever an extension
  20. ;    was '.<sp><sp><sp>' multiple copies of the file
  21. ;    name were built in the ifnt.
  22. ;
  23. ;    Added equate 'nosys' and associated rtn. in section
  24. ;    'cfnt3:' in order to ignore all files with a 'sys'
  25. ;    attribute.  This will allow the user to mask-off
  26. ;    any file(s) he doesn't want to copy.
  27. ;           cml  4/10/81
  28. ;
  29. ;        -------------------------
  30. ; 
  31. ;       Version 4.5 - 10/29/80 - Deleted system disk request of V4.0
  32. ;        to shorten messages, minor changes in abort options and
  33. ;        other messages. Moved disk reset of V4.1 to point
  34. ;        before directory search. (CHS)
  35. ;
  36. ;       Version 4.4 - 10/28/80 - Modified to bail out with message 
  37. ;        if no FCB is specified. Updates rearranged with most
  38. ;        recent first for reader convenience. (Charles H. Strom)
  39. ;
  40. ;       VERSION 4.3 BY LEWIS MOSELEY, JR.  3/22/80
  41. ;       FIXED BUG WHICH SHOWED UP WHEN MULTIPLE COPIES WERE
  42. ;       MADE OF A MULTIPLE EXTENT FILE, IN THAT CP/M OPEN
  43. ;       THE NEXT EXTENT USING THE DATA AREA TO SEARCH THE
  44. ;       DIRECTORY, SCREWING UP THE DATA BLOCK THAT IS THERE.
  45. ;
  46. ;       VERSION 4.2 BY LEWIS MOSELEY, JR.  2/23/80
  47. ;       FIXED BUG THAT OCCURRED WHEN ONLY A SINGLE FILE
  48. ;               WAS SPECIFIED AND THAT FILE WAS NOT FOUND:
  49. ;               PROGRAM HUNG IN A LOOP
  50. ;
  51. ;       VERSION 4.1 BY LES FREED AND LEWIS MOSELEY 2/11/80
  52. ;       ADDED DISK RESET ON DISK CHANGE TO ALLOW
  53. ;               CHANGING DENSITY BETWEEN DISKS
  54. ;       ADDED CTL-C ABORT 
  55. ;
  56. ;       VERSION 4.0 BY LEWIS MOSELEY, JR.  12/79
  57. ;       ADDED OPTION FOR MULTIPLE OUTPUT COPIES
  58. ;       ADDED REQUEST FOR SYSTEM DISK BEFORE REBOOT
  59. ;
  60. ;       l.e. hughes     9/79
  61. ;       mycroft labs
  62. ;       atlanta, ga
  63. ;       MODIFIED FOR SOL & COMPATABLE COMPUTERS BY
  64. ;       LEWIS MOSELEY, JR. - ATLANTA,GA.
  65. ;
  66.  
  67. VERSION EQU    4
  68. MODLEV    EQU    6
  69. ;
  70. entry    equ    0005H        ;bdos entry point
  71. tfcb    equ    005CH        ;system file control block
  72. dbuf    equ    0080H        ;system disk buffer
  73. ;    
  74. true    equ    0ffh
  75. false    equ    0h
  76. ;
  77. nosys    equ    false        ;true to ignore all $SYS files
  78. ;
  79. CR    equ    0DH
  80. LF    equ    0AH
  81. ;    
  82. rcfc    equ    01        ;read console
  83. wcfc    equ    02        ;write console
  84. rdfc    equ    13        ;reset disk
  85. offc    equ    15        ;open file
  86. cffc    equ    16        ;close file
  87. sffc    equ    17        ;search first
  88. snfc    equ    18        ;search next
  89. dffc    equ    19        ;delete file
  90. rrfc    equ    20        ;read record
  91. wrfc    equ    21        ;write record
  92. mffc    equ    22        ;make file
  93. safc    equ    26        ;set address
  94. ;    
  95. fn    equ    01        ;file name offset
  96. ft    equ    09        ;file type offset
  97. ex    equ    12        ;extent number offset
  98. nr    equ    32        ;next record offset
  99. ;    
  100.     org    100H
  101. mft:    lxi    sp,stack+64
  102.     lxi    h,msg1        ;print 'MFT V4.0'
  103.     call    wasc
  104.     xra    a        ;clear break flags
  105.     sta    ibflg
  106.     sta    obflg
  107.     STA    NDFLG        ;CLEAR NO DUP FLAG
  108. ;    
  109.     LDA    TFCB+1        ;If no FCB specified
  110.     CPI    ' '        ;then say so
  111.     JNZ    OK
  112.     LXI    H,MSGK        ;and bail out
  113.     CALL    WASC        ;here
  114.     JMP    0H
  115. ;
  116. ;    calculate buffer size = fwa(BDOS) - fwa(MBUF)
  117. ;    
  118. OK    lhld    entry+1     ;hl = (entry+1) - 6
  119.     lxi    d,-6
  120.     dad    d
  121.     mov    a,l
  122.     ani    80H        ;hl = hl mod 128
  123.     mov    l,a
  124.     lxi    d,mbuf        ;hl = hl - fwa(MBUF)
  125.     mov    a,l
  126.     sub    e
  127.     mov    l,a
  128.     mov    a,h
  129.     sbb    d
  130.     mov    h,a
  131.     dad    h        ;hl = hl / 128
  132.     mov    l,h
  133.     mvi    a,0
  134.     aci    0
  135.     mov    h,a
  136.     dcx    h        ;subtract one
  137.     shld    space        ;save as buffer size
  138.     lxi    h,msg2        ;write 'Buffer size = '
  139.     call    wasc
  140.     lhld    space        ;write size of buffer
  141.     call    wdwc
  142.     lxi    h,msg3        ;write ' sectors'
  143.     call    wasc
  144. ;    
  145. ;    ask user to mount input disk
  146. ;    
  147. mft1:    lxi    h,msg4        ;write 'Mount input disk, type CR'
  148.     call    wasc
  149.     call    racc        ;read response
  150.     CPI    03        ;CTL-C ?
  151.     JZ    MFTL        ;ABORT WITH MESSAGE
  152.     cpi    CR        ;loop if anything but CR
  153.     jnz    mft1
  154.     call    weolc        ;echo CR,LF
  155.     CALL    RESET        ;adjust density
  156.     lda    ibflg        ;jump if ibflg set
  157.     ora    a
  158.     jnz    mft2a
  159. ;    
  160. ;    copy command line into cbuf
  161. ;    
  162.     lxi    h,dbuf        ;fwa of command line image
  163.     lxi    d,cbuf        ;fwa of command buffer
  164.     mov    b,m        ;fetch command line image length
  165.     inx    h
  166. mft2:    mov    a,m        ;fetch next byte from cli
  167.     inx    h
  168.     stax    d        ;store in dbuf
  169.     inx    d
  170.     dcr    b        ;decrement count
  171.     jnz    mft2        ;loop until zero
  172.     xra    a        ;store zero byte at end
  173.     stax    d
  174.     lxi    h,cbuf        ;reset cbufp
  175.     shld    cbufp
  176.     call    cfnt        ;create file name table
  177.     lxi    h,fnt        ;reset fnt pointers
  178.     shld    ifntp
  179.     shld    ofntp
  180. mft2a:    lxi    h,mbuf        ;reset mbuf pointer
  181.     shld    mbufp
  182.     lhld    space        ;reset msize
  183.     shld    msize
  184.     lda    ibflg        ;jump if ibflg not set
  185.     ora    a
  186.     jz    mft3
  187.     lxi    h,ifcb        ;copy IFCB into TFCB
  188.     lxi    d,tfcb
  189.     mvi    b,33
  190.     call    move
  191.     xra    a        ;clear ibflg
  192.     sta    ibflg
  193.     inr    a        ;set obflg
  194.     sta    obflg
  195.     lhld    ifntp        ;back ifntp up 4 bytes
  196.     lxi    d,-4
  197.     dad    d
  198.     shld    ifntp
  199.     lxi    h,tfcb+fn    ;write filename
  200.     call    wfnc
  201.     lxi    h,msg6        ;write ' - '
  202.     call    wasc
  203.     lhld    ifntp        ;DE = ifntp
  204.     xchg
  205.     jmp    mft4        ;continue reading previous file
  206. ;    
  207. ;    parse off next name from cbuf
  208. ;    
  209. mft3:    lhld    ifntp        ;fetch input fnt pointer
  210.     mov    a,m        ;jump if end of table
  211.     cpi    0FFH
  212.     jz    mft9
  213.     mvi    m,1        ;set 'file read' flag
  214.     inx    h
  215.     lxi    d,tfcb+fn    ;copy filename into tfcb
  216.     mvi    b,11
  217.     call    move
  218.     shld    ifntp        ;save input fnt pointer
  219.     lxi    h,tfcb+fn    ;write filename
  220.     call    wfnc
  221.     lxi    h,msg6        ;write ' - '
  222.     call    wasc
  223.     xra    a        ;setup tfcb
  224.     sta    tfcb
  225.     sta    tfcb+ex
  226.     sta    tfcb+nr
  227.     call    open        ;open file
  228.     lhld    ifntp
  229.     xchg
  230. mft4:    lhld    mbufp
  231.     mov    a,h        ;copy into fnt entry
  232.     stax    d
  233.     inx    d
  234.     mov    a,l
  235.     stax    d
  236.     inx    d
  237.     xchg            ;save fnt pointer
  238.     shld    ifntp
  239.     lxi    h,0        ;file size (in sectors) = 0
  240.     shld    fsize
  241. ;    
  242. ;    read next file from input disk
  243. ;    
  244. mft6:    lhld    mbufp
  245.     xchg
  246.     call    setdma
  247.     call    read        ;read next sector
  248.     ora    a        ;jump if normal transfer
  249.     jz    mft7
  250.     cpi    1        ;jump if EOF
  251.     jz    mft8
  252.     lxi    h,msg8        ;write 'read error - '
  253.     call    wasc
  254.     jmp    mft8        ;continue as if EOF
  255. mft7:    lhld    mbufp        ;mbufp = mbufp + 128
  256.     lxi    d,128
  257.     dad    d
  258.     shld    mbufp
  259.     lhld    fsize        ;fsize = fsize + 1
  260.     inx    h
  261.     shld    fsize
  262.     lhld    msize        ;decrement msize
  263.     dcx    h
  264.     shld    msize
  265.     mov    a,h        ;loop if still positive
  266.     ora    l
  267.     jnz    mft6
  268.     lxi    h,tfcb        ;copy tfcb into ifcb
  269.     lxi    d,ifcb
  270.     mvi    b,33
  271.     call    move
  272.     mvi    a,1        ;set ibflg
  273.     sta    ibflg
  274. mft8:    lxi    d,dbuf        ;reset dma pointer
  275.     call    setdma
  276.     call    close        ;close file
  277.     lhld    fsize        ;write file size
  278.     call    wdwc
  279.     lxi    h,msg9        ;write ' sectors read'
  280.     call    wasc
  281. ;    
  282. ;    update fnt, loop
  283. ;    
  284.     lhld    fsize        ;DE = file size
  285.     xchg
  286.     lhld    ifntp        ;store file size in fnt entry
  287.     mov    m,d
  288.     inx    h
  289.     mov    m,e
  290.     inx    h
  291.     shld    ifntp        ;save fnt pointer
  292.     lda    ibflg        ;loop if ibflg not set
  293.     ora    a
  294.     jz    mft3
  295. ;
  296. ;    FLAG THAT THE MEMORY BUFFER HAS BEEN EXCEEDED, AND
  297. ;    TELL USER THAT DUPLICATE COPIES CANNOT BE MADE
  298.     LDA    NDFLG        ;TOLD HIM ALREADY?
  299.     ORA    A
  300.     JNZ    MFT9        ;JUMP IF SO
  301.     LXI    H,MSGH        ;IF NOT, TELL HIM
  302.     CALL    WASC
  303.     MVI    A,1        ;SET NDFLG THIS TIME
  304.     STA    NDFLG
  305. ;
  306. ;    Ask user to mount output disk
  307. ;    
  308. mft9:    lxi    h,msgA        ;write 'Mount output disk, type CR'
  309.     call    wasc
  310.     call    racc        ;read response
  311.     CPI    03        ;CTL-C?
  312.     JZ    MFTL        ;ABORT WITH MESSAGE IF SO
  313.     cpi    CR        ;loop if anything but CR
  314.     jnz    mft9
  315.     call    weolc        ;echo CR,LF
  316.     call    reset        ;reset disk system 
  317.                 ;make r/w and check density
  318.     lda    obflg        ;jump if obflg not set
  319.     ora    a
  320.     jz    mftA
  321.     lxi    h,ofcb        ;copy ofcb into tfcb
  322.     lxi    d,tfcb
  323.     mvi    b,33
  324.     call    move
  325.     call    open        ;open previous file
  326.     lhld    ofntp        ;backup output fnt pointer 4 bytes
  327.     lxi    d,-4
  328.     dad    d
  329.     shld    ofntp
  330.     lxi    h,tfcb+fn    ;write file name
  331.     call    wfnc
  332.     lxi    h,msg6        ;write ' - '
  333.     call    wasc
  334.     jmp    mftb        ;continue writing previous file
  335. ;    
  336. ;    write next file to output disk
  337. ;    
  338. mftA:    lhld    ofntp
  339.     mov    a,m
  340.     ora    a
  341.     jz    mftF
  342.     cpi    0FFH
  343.     jz    mftF
  344.     inx    h
  345.     lxi    d,tfcb+fn
  346.     mvi    b,11
  347.     call    move
  348.     shld    ofntp
  349.     lxi    h,tfcb+ft    ;pt to $R/O byte
  350.     mov    a,m        ;get it from storage
  351.     ani    7fh        ;force it to $R/W
  352.     mov    m,a        ;put it back
  353.     lxi    h,tfcb+fn
  354.     call    wfnc
  355.     lxi    h,msg6
  356.     call    wasc
  357.     xra    a
  358.     sta    tfcb
  359.     sta    tfcb+ex
  360.     sta    tfcb+nr
  361.     call    delt        ;try to create output file
  362.     call    make
  363.     cpi    255        ;jump if ok
  364.     jnz    mftB
  365.     lxi    h,msgB        ;write 'unable to create'
  366.     call    wasc
  367.     jmp    mftG
  368. mftB:    lhld    ofntp
  369.     mov    d,m        ;fetch fwa of file from fnt
  370.     inx    h
  371.     mov    e,m
  372.     inx    h
  373.     xchg
  374.     shld    mbufp        ;save it
  375.     xchg
  376.     mov    d,m        ;fetch size of file from fnt
  377.     inx    h
  378.     mov    e,m
  379.     inx    h
  380.     xchg
  381.     shld    fsize        ;save it
  382.     shld    xsize        ;save for printout
  383.     xchg
  384.     shld    ofntp
  385.     lhld    fsize        ;jump if fsize=0
  386.     mov    a,h
  387.     ora    l
  388.     jz    mftDA
  389. mftC:    lhld    mbufp        ;set dma address to mbufp
  390.     xchg
  391.     call    setdma
  392.     call    write        ;write next sector
  393.     ora    a        ;jump if ok
  394.     jz    mftD
  395.     lxi    h,msgC        ;write 'error writing file'
  396.     call    wasc
  397.     jmp    mftG
  398. mftD:    lhld    mbufp        ;mbufp = mbufp + 128
  399.     lxi    d,128
  400.     dad    d
  401.     shld    mbufp
  402.     lhld    fsize        ;fsize = fsize - 1
  403.     dcx    h
  404.     shld    fsize
  405.     mov    a,h        ;loop until zero
  406.     ora    l
  407.     jnz    mftC
  408. mftDA:    lxi    h,tfcb        ;copy tfcb into ofcb
  409.     lxi    d,ofcb
  410.     mvi    b,33
  411.     call    move
  412.     lxi    d,dbuf        ;reset dma pointer
  413.     call    setdma
  414.     call    close        ;try to close file
  415.     cpi    255        ;jump if ok
  416.     jnz    mftE
  417.     lxi    h,msgD        ;write 'unable to close'
  418.     call    wasc
  419. mftE:    lhld    xsize        ;write number of sectors written
  420.     call    wdwc
  421.     lxi    h,msgE        ;write ' sectors written'
  422.     call    wasc
  423.     jmp    mftA
  424. mftF:    lda    ibflg        ;loop if ibflg set
  425.     ora    a
  426.     jnz    mft1
  427. ;Terminate program here on irrecoverable error or
  428. ;when all files have been copied.  Must reload system
  429. ;disk to avoid crash when copying to someone else's disk.
  430. ;If normal end, and if buffer has not been exceeded, give
  431. ;user the option of making another copy of the same
  432. ;set of files.
  433. mftG:    LXI    H,MSGF        ;SEE IF OPTION IS ALLOWED
  434.     LDA    NDFLG
  435.     ORA    A
  436.     JNZ    MFTH        ;JUMP IF NOT ALLOWED
  437.     CALL    WASC        ;ELSE TELL ABOUT OPTION
  438. MFTH:    LXI    H,MSGG        ;ASK FOR SYSTEM DISK
  439.     call    wasc
  440.     call    racc        ;wait for response
  441.     CPI    03H        ;WARM BOOT IF ^C
  442.     JZ    0
  443.     CPI    CR        ;ATTEMPT REPEAT IF <RETURN>
  444.     JZ    MFTJ
  445.     JMP    MFTG        ;ELSE LOOP TILL GOOD RESPONSE
  446. ;
  447. MFTJ:    CALL    WEOLC        ;ACKNOWLEDGE COMMAND
  448.     LDA    NDFLG        ;REPEAT ALLOWED?
  449.     ORA    A
  450.     JNZ    MFTK        ;JUMP IF NOT
  451.     LXI    H,FNT        ;ELSE RESET FNT POINTER
  452.     SHLD    OFNTP
  453.     LXI    H,MBUF        ;RESET MEM BUF POINTER
  454.     SHLD    MBUFP
  455.     XRA    A        ;RESET OUTPUT INTERRUPTED FLAG
  456.     STA    OBFLG
  457.     JMP    MFT9        ;AND DO AGAIN
  458. ;
  459. MFTK:    LXI    H,MSGH        ;CANNOT REPEAT, TELL HIM AGAIN
  460.     CALL    WASC
  461.     JMP    MFTG        ;AND WAIT FOR SYSTEM DISK
  462. ;    
  463. MFTL:    LXI    H,MSGJ        ;ABORT MESSAGE
  464.     CALL    WASC
  465.     JMP    0H        ;WARM BOOT
  466.  
  467. ;    subroutines
  468. ;    
  469. move:    mov    a,m
  470.     inx    h
  471.     stax    d
  472.     inx    d
  473.     dcr    b
  474.     jnz    move
  475.     ret
  476. ;    
  477. ;;    gfn - get file name
  478. ;    
  479. ;    
  480. gfn:    mov    a,m
  481.     ora    a
  482.     rz
  483.     cpi    ' '
  484.     jnz    gfn0
  485.     inx    h
  486.     jmp    gfn
  487. gfn0:    lxi    d,xfcb
  488.     xra    a
  489.     stax    d
  490.     inx    d
  491.     push    d
  492.     mvi    b,11
  493.     mvi    a,' '
  494. gfn6:    stax    d
  495.     inx    d
  496.     dcr    b
  497.     jnz    gfn6
  498.     pop    d
  499.     mvi    b,9
  500. gfn1:    mov    a,m
  501.     ora    a
  502.     jz    gfn4
  503.     inx    h
  504.     cpi    ' '
  505.     jz    gfn4
  506.     cpi    '.'
  507.     jz    gfn2
  508.     cpi    '*'
  509.     jz    gfn7
  510.     stax    d
  511.     inx    d
  512.     dcr    b
  513.     jz    gfn5
  514.     jmp    gfn1
  515. gfn7:    dcr    b
  516.     jz    gfn9
  517.     mvi    a,'?'
  518.     stax    d
  519.     inx    d
  520.     jmp    gfn7
  521. gfn9:    mov    a,m
  522.     cpi    '.'
  523.     jnz    gfn4
  524.     inx    h
  525. gfn2:    lxi    d,xfcb+ft
  526.     mvi    b,4
  527. gfn3:    mov    a,m
  528.     ora    a
  529.     jz    gfn4
  530.     inx    h
  531.     cpi    ' '
  532.     jz    gfn4
  533.     cpi    '*'
  534.     jz    gfn8
  535.     stax    d
  536.     inx    d
  537.     dcr    b
  538.     jz    gfn5
  539.     jmp    gfn3
  540. gfn8:    dcr    b
  541.     jz    gfn4
  542.     mvi    a,'?'
  543.     stax    d
  544.     inx    d
  545.     jmp    gfn8
  546. gfn4:    xra    a
  547.     ret
  548. gfn5:    stc
  549.     ret
  550. ;    
  551. ;;    cfnt - create file name table
  552. ;    
  553. ;    
  554. cfnt:    lxi    h,fnt        ;reset ifntp
  555.     shld    ifntp
  556.     MVI    M,0FFH        ;VER 4.2 BUG FIX 
  557. cfnt1:    lhld    cbufp        ;get cbufp
  558.     mov    a,m        ;exit if end of list
  559.     ora    a
  560.     rz
  561.     call    gfn        ;get next afn
  562.     shld    cbufp        ;save command buffer ptr
  563.     jnc    cfnt2        ;jump if filename ok
  564.     lxi    h,msg5        ;write 'Syntax error in filename'
  565.     call    wasc
  566.     jmp    cfnt1        ;loop
  567. cfnt2:    xra    a        ;clear xfcb extent field
  568.     sta    xfcb+ex
  569.     lxi    d,xfcb        ;search for first occurance
  570.     call    srchf
  571.     cpi    255        ;jump if found
  572.     jnz    cfnt3
  573.     lxi    h,xfcb+fn    ;write filename
  574.     call    wfnc
  575.     lxi    h,msg7        ;write ' not found'
  576.     call    wasc
  577.     jmp    cfnt1        ;loop
  578. cfnt3:    ani    3        ;index into cbuf
  579.     mov    l,a
  580.     mvi    h,0
  581.     dad    h
  582.     dad    h
  583.     dad    h
  584.     dad    h
  585.     dad    h
  586.     lxi    d,dbuf
  587.     dad    d
  588. ;
  589.     if    nosys
  590.  
  591.     push    h
  592.     push    d
  593.     lxi    d,10
  594.     dad    d
  595.     mov    a,m        ;get 't2'
  596.     ani    80h        ;look at sys bit
  597.     pop    d
  598.     pop    h
  599.     jnz    cfnt4        ;'sys file'-ignore
  600.  
  601.     endif
  602. ;
  603.     xchg            ;copy filename into fnt
  604.     lhld    ifntp
  605.     xchg
  606.     mvi    b,12
  607.     call    move
  608.     lxi    h,zeros        ;zero fill rest of entry
  609.     mvi    b,4
  610.     call    move
  611.     xchg
  612.     shld    ifntp        ;save input fnt pointer
  613.     mvi    m,0FFH        ;insure FF byte at end
  614. cfnt4:    lxi    d,xfcb        ;search for next occurance
  615.     call    srchn
  616.     cpi    255        ;jump if found
  617.     jnz    cfnt3
  618.     jmp    cfnt1        ;go get next afn
  619. ;    
  620. ;;    wasc - write ascii string to console
  621. ;    
  622. ;    
  623. wasc:    mov    a,m
  624.     ora    a
  625.     rz
  626.     call    wacc
  627.     inx    h
  628.     jmp    wasc
  629. ;    
  630. ;    
  631. ;;    wfnc - write file name to console
  632. ;Note: Under SOLOS and CUTER, 01 is the cursor-left character.
  633. ;When MFTing a multi-extent file, the extent character must
  634. ;be filtered out of the file-name-block to avoid wierd
  635. ;console output.
  636. ;
  637. wfnc:    mov    a,m
  638.     ora    a        ;0=thru
  639.     rz
  640.     cpi    20h        ;skip print if < space
  641.     jc    wfnc1
  642.     call    wacc
  643. wfnc1    inx    h
  644.     jmp    wfnc
  645. ;    
  646. ;;    weolc - write end of line to console
  647. ;    
  648. ;    
  649. weolc:    mvi    a,CR
  650.     call    wacc
  651.     mvi    a,LF
  652.     jmp    wacc
  653. ;    
  654. ;;    wdwc - write decimal word to console
  655. ;    
  656. ;    
  657. wdwc:    push    h
  658.     push    d
  659.     push    b
  660.     mvi    b,0        ;clear 'digit written' flag
  661.     lxi    d,10000        ;write 1st digit
  662.     call    wndd
  663.     lxi    d,1000        ;write 2nd digit
  664.     call    wndd
  665.     lxi    d,100        ;write 3rd digit
  666.     call    wndd
  667.     lxi    d,10        ;write 4th digit
  668.     call    wndd
  669.     lxi    d,1        ;write 5th digit
  670.     mvi    b,1        ;force last digit to print
  671.     call    wndd
  672.     pop    b
  673.     pop    d
  674.     pop    h
  675.     ret
  676. ;    
  677. wndd:    mvi    c,0        ;c=0
  678. wndd1:    mov    a,l        ;hl = hl - de
  679.     sub    e
  680.     mov    l,a
  681.     mov    a,h
  682.     sbb    d
  683.     mov    h,a
  684.     jc    wndd2        ;jump if < 0
  685.     inr    c        ;c = c + 1
  686.     jmp    wndd1        ;loop
  687. wndd2:    dad    d        ;hl = hl + de
  688.     mov    a,c        ;jump if c non-zero
  689.     ora    c
  690.     jnz    wndd4
  691.     mov    a,b        ;jump if digit written
  692.     ora    b
  693.     jnz    wndd4
  694.     mvi    a,' '        ;write one space
  695.     jmp    wacc
  696. wndd4:    mvi    b,1        ;set 'digit written' flag
  697.     mov    a,c        ;encode c into decimal ascii
  698.     adi    '0'
  699.     jmp    wacc        ;go write it
  700. ;    
  701. ;;    wacc - write ascii character to console
  702. ;    
  703. ;    
  704. wacc:    push    h
  705.     push    d
  706.     push    b
  707.     push    psw
  708.     mvi    c,wcfc
  709.     mov    e,a
  710.     call    entry
  711.     pop    psw
  712.     pop    b
  713.     pop    d
  714.     pop    h
  715.     ret
  716. ;    
  717. ;;    racc - read ascii character from console
  718. ;    
  719. ;    
  720. racc:    push    h
  721.     push    d
  722.     push    b
  723.     mvi    c,rcfc
  724.     call    entry
  725.     pop    b
  726.     pop    d
  727.     pop    h
  728.     ret
  729. ;    
  730. ;;    reset - reset disk system
  731. ;    
  732. ;    
  733. reset:    push    h
  734.     push    d
  735.     push    b
  736.     mvi    c,rdfc
  737.     call    entry
  738.     pop    b
  739.     pop    d
  740.     pop    h
  741.     ret
  742. ;    
  743. ;;    open - open disk file
  744. ;    
  745. ;    
  746. open:    push    h
  747.     push    d
  748.     push    b
  749.     lxi    d,tfcb
  750.     mvi    c,offc
  751.     call    entry
  752.     pop    b
  753.     pop    d
  754.     pop    h
  755.     ret
  756. ;    
  757. ;;    read - read record from disk file
  758. ;    
  759. ;    
  760. read:    push    h
  761.     push    d
  762.     push    b
  763.     lxi    d,tfcb
  764.     mvi    c,rrfc
  765.     call    entry
  766.     pop    b
  767.     pop    d
  768.     pop    h
  769.     ret
  770. ;    
  771. ;;    close - close disk file
  772. ;    
  773. ;    
  774. close:    push    h
  775.     push    d
  776.     push    b
  777.     lxi    d,tfcb
  778.     mvi    c,cffc
  779.     call    entry
  780.     pop    b
  781.     pop    d
  782.     pop    h
  783.     ret
  784. ;    
  785. ;;    delt - delete disk file
  786. ;    
  787. ;    
  788. delt:    push    h
  789.     push    d
  790.     push    b
  791.     lxi    d,tfcb
  792.     mvi    c,dffc
  793.     call    entry
  794.     pop    b
  795.     pop    d
  796.     pop    h
  797.     ret
  798. ;    
  799. ;;    make - make new disk file
  800. ;    
  801. ;    
  802. make:    push    h
  803.     push    d
  804.     push    b
  805.     lxi    d,tfcb
  806.     mvi    c,mffc
  807.     call    entry
  808.     pop    b
  809.     pop    d
  810.     pop    h
  811.     ret
  812. ;    
  813. ;;    write - write record to file
  814. ;    
  815. ;    
  816. write:    push    h
  817.     push    d
  818.     push    b
  819. ;
  820. ;;    REVISION 4.3 MODS
  821. ;
  822.     LDA    tfcb+nr        ;LAST RECORD IN EXTENT?
  823.     CPI    7FH
  824.     JNZ    WRITE1        ;NO, CONTINUE
  825.     LHLD    mbufp        ;EXISTING DATA AREA
  826.     LXI    D,dbuf        ;POINT TO SAFE AREA
  827.     CALL    SETDMA        ;TELL CP/M WHERE TO GET DATA
  828.     MVI    B,80H        ;LENGTH TO MOVE
  829.     CALL    MOVE        ;MOVE DATA AWAY SO...
  830. ;CP/M DOESN'T OVERWRITE THE REAL DATA IN OPENING NEXT EXTENT
  831. ;END REVISION 4.3 MODS
  832.  
  833. WRITE1: lxi    d,tfcb
  834.     mvi    c,wrfc
  835.     call    entry
  836.     pop    b
  837.     pop    d
  838.     pop    h
  839.     ret
  840. ;    
  841. ;;    setdma - set dma address
  842. ;    
  843. ;    
  844. setdma: push    h
  845.     push    d
  846.     push    b
  847.     mvi    c,safc
  848.     call    entry
  849.     pop    b
  850.     pop    d
  851.     pop    h
  852.     ret
  853. ;    
  854. ;;    srchf - search for first occurance of afn
  855. ;    
  856. ;    
  857. srchf:    push    h
  858.     push    d
  859.     push    b
  860.     mvi    c,sffc
  861.     call    entry
  862.     pop    b
  863.     pop    d
  864.     pop    h
  865.     ret
  866. ;    
  867. ;;    srchn - search for next occurance of afn
  868. ;    
  869. ;    
  870. srchn:    push    h
  871.     push    d
  872.     push    b
  873.     mvi    c,snfc
  874.     call    entry
  875.     pop    b
  876.     pop    d
  877.     pop    h
  878.     ret
  879. ;    
  880. msg1:    db    CR,LF,'MFT V'
  881.     DB    VERSION+'0'    ;VERSION #
  882.     DB    '.',MODLEV+'0'    ;MODIFICATION LEVEL
  883.     DB    CR,LF
  884.     db    'Multi-File-Transfer for single disk,',CR,LF
  885.     db    'With multiple-copy option.',CR,LF,LF,0
  886. msg2:    db    'Buffer size = ',0
  887. msg3:    db    ' sectors',CR,LF,LF,0
  888. msg4:    db    'Mount INPUT disk, type RETURN (or ^C to reboot)',0
  889. msg5:    db    'Syntax error in filename',CR,LF,0
  890. msg6:    db    ' - ',0
  891. msg7:    db    ' not found',CR,LF,0
  892. msg8:    db    'read error - ',0
  893. msg9:    db    ' sectors read',CR,LF,0
  894. msgA:    db    'Mount OUTPUT disk, type RETURN (or ^C to reboot)',0
  895. msgB:    db    'unable to create',CR,LF,0
  896. msgC:    db    'error writing file',CR,LF,0
  897. msgD:    db    'unable to close',CR,LF,0
  898. msgE:    db    ' sectors written',CR,LF,0
  899. MSGF:    db    CR,LF,'Completed. '
  900.     db    'Type RETURN for another copy, OR...',0
  901. MSGG:    db    CR,LF,'type ^C to reboot.',CR,LF,0
  902. MSGH:    db    CR,LF,'++Memory buffer exceeded, cannot ',CR,LF
  903.     db    'make duplicate copies this time;',CR,LF
  904.     DB    'last ouput file is incomplete++',CR,LF,LF,0
  905. MSGJ    DB    CR,LF,'++PROGRAM ABORTED++',CR,LF,0
  906. MSGK    DB    CR,LF,'No file name specified',CR,LF,0
  907. ;
  908. ;
  909. zeros:    db    0,0,0,0
  910. ;    
  911.     org    ($+15)/16*16
  912. ;    
  913. fnt:    ds    16*64+1
  914. ;    
  915. stack:    ds    64
  916. space:    ds    2        ;available space
  917. msize:    ds    2        ;memory size
  918. cbuf:    ds    80        ;command buffer
  919. cbufp:    ds    2        ;command buffer pointer
  920. fsize:    ds    2        ;file size in sectors
  921. xsize:    ds    2        ;file size for printout
  922. ifntp:    ds    2        ;input fnt pointer
  923. ofntp:    ds    2        ;output fnt pointer
  924. mbufp:    ds    2        ;memory buffer pointer
  925. ifcb:    ds    33        ;input fcb
  926. ofcb:    ds    33        ;output fcb
  927. xfcb:    ds    33        ;temporary fcb
  928. ibflg:    ds    1        ;input break flag
  929. obflg:    ds    1        ;output break flag
  930. NDFLG:    DS    1        ;NO DUPLICATE ALLOWED FLAG
  931. ;    
  932. mbuf    equ    $
  933. ;    
  934.     end    mft
  935.