home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols000 / vol075 / mactime.asm < prev    next >
Assembly Source File  |  1984-04-29  |  5KB  |  253 lines
  1.  
  2.     title    'MACTIME as of April 6, 1982'
  3.  
  4. ; 
  5. ; 
  6. ;  Here  is  an  interesting  "patch"  to  Digital  Research's 
  7. ; MAC.COM, that incorporates a "real time clock display.  This 
  8. ; patch   works with MAC.COM version 2.0 ONLY.  Merge it  into 
  9. ; MAC.COM as follows:
  10. ; 
  11. ;      A>DDT MAC.COM<cr>
  12. ;      NEXT   PC
  13. ;      2F00  0100
  14. ;      -IMACTIME.HEX<cr>
  15. ;      -R<cr>
  16. ;      NEXT   PC
  17. ;      308E  0000
  18. ;      -^C
  19. ;      A>SAVE 48 MACTIME.COM<cr>
  20. ; 
  21. ;  Now  you have a new "MAC" command file called  MACTIME.COM; 
  22. ; now  re-assemble  MACTIME.ASM (assuming your  clock/calendar 
  23. ; board, and the time is properly set) with MACTIME.COM.
  24. ; 
  25. ;  Notice,  that  the date and time will be displayed  at  the 
  26. ; start  of execution.  Also because the "title" pseudo-op was 
  27. ; used,  the  time  is  listed  in the  ".PRN"  file  that  is 
  28. ; generated, on each page heading.
  29. ; 
  30. ;                         Best regards,
  31. ;           
  32. ;                         Kelly Smith, MP/M-Net (tm) Sysop
  33. ;                         (805) 527-9321 (Modem, 300 Baud)
  34. ;
  35. ;    06/Apr/82    Revised for Godbout System Support 1 clock
  36. ;            by Bill Bolton, Software Tools, Australia
  37. ;
  38. ;    20/Oct/80    Original version by Kelly Smith
  39. ;
  40. ;
  41. ;
  42. bdos    equ    5
  43. pbuf    equ    9
  44.  
  45. mac    equ    128h    ; MAC.COM entry address
  46. overlay    equ    2cd3H
  47.  
  48. cr    equ    0dh    ; ASCII carriage return
  49. lf    equ    0ah    ; ASCII line feed
  50.  
  51. true    equ    0ffh
  52. false    equ    not true; define false
  53. clkread    equ    10H
  54. timlen    equ    12
  55.  
  56. gbclkc    equ    06Ah    ; real time clock base port address
  57. gbclkd    equ    gbclkc+1
  58.  
  59.  
  60.     org     0100h
  61.  
  62.     jmp    start
  63.  
  64.     org    2f00h    ; version 2.0 mac.com entry address
  65.  
  66. start:
  67.     mvi    a,0+clkread
  68.     out    gbclkc
  69.     in    gbclkd
  70.     cpi    0ffh        ;clock board present?
  71.     jz    done        ;no, just run normally
  72.     call    rtime
  73.     lxi    h,time
  74.     mov    a,m
  75.     cpi    '0'
  76.     jnz    go$on
  77.     mvi    a,' '
  78. go$on:
  79.     sta    day
  80.     inx    h
  81.     mov    a,m
  82.     sta    day+1
  83.     inx    h
  84.     mov    a,m
  85.     sta    month
  86.     inx    h
  87.     mov    a,m
  88.     sta    month+1
  89.     inx    h
  90.     mov    a,m
  91.     sta    year
  92.     inx    h
  93.     mov    a,m
  94.     sta    year+1
  95.     inx    h
  96.     mov    a,m
  97.     sta    hour
  98.     inx    h
  99.     mov    a,m
  100.     sta    hour+1
  101.     inx    h
  102.     mov    a,m
  103.     sta    minutes
  104.     inx    h
  105.     mov    a,m
  106.     sta    minutes+1
  107.     inx    h
  108.     mov    a,m
  109.     sta    seconds
  110.     inx    h
  111.     mov    a,m
  112.     sta    seconds+1
  113. ;
  114. ; test the date, and convert it to four year calendar format
  115. ;
  116.     lda    month    ; get high byte of the month
  117.     cpi    '1'    ; in the range of january to september?
  118.     jnz    jansept ; yes
  119.     lda    month+1
  120.     cpi    '0'
  121.     lxi    d,oct    ; October?
  122.     jz    mmonth    ; print, if so
  123.     cpi    '1'    ; november?
  124.     lxi    d,nov
  125.     jz    mmonth    ; print, if so
  126.     lxi    d,dec    ; december.
  127.     jmp    mmonth    ; print it...
  128. ;
  129. jansept:
  130.     lda    month+1    ; it's january to september
  131.     cpi    '1'    ; january?
  132.     lxi    d,jan
  133.     jz    mmonth    ; print, if so
  134.     cpi    '2'    ; february?
  135.     lxi    d,feb
  136.     jz    mmonth    ; print, if so
  137.     cpi    '3'    ; march?
  138.     lxi    d,mar
  139.     jz    mmonth    ; print, if so
  140.     cpi    '4'    ; april?
  141.     lxi    d,apr
  142.     jz    mmonth    ; print, if so
  143.     cpi    '5'    ; may?
  144.     lxi    d,may
  145.     jz    mmonth    ; print, if so
  146.     cpi    '6'    ; june?
  147.     lxi    d,jun
  148.     jz    mmonth    ; print month
  149.     cpi    '7'    ; july?
  150.     lxi    d,jul
  151.     jz    mmonth    ; print, if so
  152.     cpi    '8'    ; august?
  153.     lxi    d,aug
  154.     jz    mmonth    ; print, if so
  155.     lxi    d,sep    ; it's september
  156. mmonth:    mvi    b,4    ; four characters to move
  157.     lxi    h,fakem    ; place to move real month
  158. movem:    ldax    d    ; get the character to move
  159.     mov    m,a    ; move it
  160.     inx    h    ; bump both pointers
  161.     inx    d
  162.     dcr    b    ; de-bump the count left to move..
  163.     jnz    movem    ; loop 'till all characters moved
  164.     lxi    h,overlay        ; point to overlay area
  165.     lxi    d,fakem        ; point to stuff to be moved
  166.     mvi    b,end$move-start$move    ; how much to move...
  167. move1:    ldax    d    ; get stuff to move
  168.     mov    m,a    ; move it...
  169.     inx    h    ; bump both pointers
  170.     inx    d
  171.     dcr    b    ; de-bump the move counter
  172.     jnz    move1    ; loop 'till it's all moved
  173. done:    jmp    mac    ; now jump into MAC...
  174.  
  175. rtime:
  176.     lxi    h,time        ;Address of time save area
  177.     lxi    d,atable    ;Address of digit table
  178.     mvi    b,timlen/2    ;Number of loops to do
  179. tloop:
  180.     call    rone        ;get digit value
  181.     ani    0fh        ;mask of high nibble
  182.     adi    '0'
  183.     mov    m,a
  184.     inx    h
  185.     call    rone
  186.     ani    0fh
  187.     adi    '0'
  188.     mov    m,a        ;save into table
  189.     inx    h        ;point to next digit
  190.     dcr    b        ;adjust loop count
  191.     jnz    tloop
  192.     ret
  193.  
  194. rone:
  195.     ldax    d        ;Get the digit address
  196.     inx    d        ;Point to next address
  197.     out    gbclkc        ;Output the digit address
  198.     cpi    5+clkread    ;Check for hours 10 digit
  199.     in    gbclkd        ;Get the digit
  200.     rnz            ;If not the hours ten digit
  201.     sui    8        ;Kill the 24 hour bit
  202.     ret
  203. ;
  204. ATABLE:
  205.     DB    8+clkread    ;digit address table
  206.     DB    7+clkread
  207.     DB    10+clkread
  208.     DB    9+clkread
  209.     DB    12+clkread
  210.     DB    11+clkread
  211.     DB    5+clkread
  212.     DB    4+clkread
  213.     DB    3+clkread
  214.     DB    2+clkread
  215.     DB    1+clkread
  216.     DB    0+clkread
  217. ;
  218. ; message buffers
  219. ;
  220.  
  221. time    db    0,0,0,0,0,0,0,0,0,0,0,0
  222.  
  223. start$move    equ    $    ; start moving from here
  224. fakem:    ds    2    ; storage for faked-out month,
  225.             ; which will overlay the next four bytes
  226. month:    ds    2    ; storage for the real month and date
  227. day:    ds    2
  228.     db    ', 19'
  229. year:    db    '82 '    ; the year...
  230. hour:    db    'xx:'    ; the hour...
  231. minutes:db    'xx:'    ; the minute...
  232. seconds:db    'xx'    ; the second...
  233.     db    0dh    ; string delimeter
  234. end$move    equ    $    ; end of move
  235.  
  236. errmsg:    db    cr,lf,'The Clock Board is NOT INSTALLED!',cr,lf,'$'
  237.  
  238. jan:    db    'Jan '
  239. feb:    db    'Feb '
  240. mar:    db    'Mar '
  241. apr:    db    'Apr '
  242. may:    db    'May '
  243. jun:    db    'Jun '
  244. jul:    db    'Jul '
  245. Aug:    db    'Aug '
  246. sep:    db    'Sep '
  247. oct:    db    'Oct '
  248. nov:    db    'Nov '
  249. dec:    db    'Dec '
  250.  
  251.     end
  252.  
  253.