home *** CD-ROM | disk | FTP | other *** search
/ CP/M / CPM_CDROM.iso / simtel / sigm / vols200 / vol218 / mxm-pc10.asm < prev    next >
Assembly Source File  |  1994-07-13  |  10KB  |  315 lines
  1. ;    TITLE    'MEX POPCOM OVERLAY V1.3'
  2. ;
  3. ; (un-DELETE ABOVE TITLE LINE IF ASSEMBLING WITH mac)
  4. ;
  5. ; PopCom overlay for MEX: revision 1.0
  6. ; adapted from smartmodem overlay Written 04/16/84 by Ronald G. Fowler
  7. ;
  8. ; 10/25/84: adapted smartmodem rev 1.3 for compatability with PopCom
  9. ;        using numeric result codes exclusively. (Howard Vigorita)
  10. ; 
  11. ; 07/16/84: Added equate NUMRES to enable/disable numeric result code 
  12. ;        interpretation.  Under TurboDos, the first digit of the 
  13. ;        phone number was being interpreted as a result code as it 
  14. ;        was echoed by the Anchor modem as it dialed.  Set NUMRES false
  15. ;        to disable numeric results. (Bob Puckett)
  16. ;
  17. ; 06/06/84: Fixed problem for Anchor users, where, when the modem returned
  18. ;        "DIAL TONE", the "N" in "TONE" was being regarded as a NO-CONNECT
  19. ;        code.  Now we flush the entire result line before reading another.
  20. ;        Also added code for numeric version of "CONNECT 1200".  --RGF
  21. ;
  22. ; Small bug repaired: (V1.1) 05/14/84 (Steve Grandi): Smartmodem was not being 
  23. ;    flushed after a dial string so that last digit of the phone number 
  24. ;    was being interpreted as a numeric result code causing the program, 
  25. ;    for certain numbers, to give up even as the modem merrily dialed away.
  26. ;
  27. ; This modules adapts MEX for the PopCom modem.
  28. ; The main function of this module is to pro-
  29. ; vide dialing capability; the disconnect vector is ancillary.
  30. ; You may use this module as a model to develop dialing routines
  31. ; for non-standard modems (e.g., the Racal-Vadic).  The only
  32. ; pertinent entry point is the DIAL routine; you'll find entry
  33. ; specs for that below.
  34. ;
  35. ; The only conditional you might want to change in this
  36. ; module is the DISC equate below -- if left on, MEX will
  37. ; use the Smartmodem's disconnect code.  If you prefer to
  38. ; provide your own in your overlay's DISCV vector (e.g.,
  39. ; by dropping DTR), then set DISC to FALSE and re-assemble.
  40. ; (If you don't understand this, then play it safe, and
  41. ; leave the equate set as it is).
  42. ;
  43. ; This overlay will work with any modem overlay that terminates
  44. ; prior to 0B00H
  45. ;
  46. FALSE    EQU    0
  47. TRUE    EQU    1
  48. ;
  49. NUMRES    EQU    TRUE        ; TRUE = INTERPRET NUMERIC RESULT CODES
  50.                 ; FALSE = IGNORE NUMERIC RESULT CODES
  51. ;
  52. DISC    EQU    TRUE        ;<<== CHANGE TO FALSE IF YOU DISC. WITH DTR
  53. ;
  54. ; SYSTEM CONSTANTS
  55. ;
  56. TPULSE    EQU    0105H        ;TONE/PULSE FLAG IN MODEM OVERLAY
  57. DIALV    EQU    0162H        ;LOCATION OF DIAL VECTOR IN OVERLAY
  58. DISCV    EQU    0165H        ;LOCATION OF DISCONNECT VECTOR IN OVERLAY
  59. DIALOC    EQU    0B00H        ;DIALING CODE GOES HERE
  60. MEX    EQU    0D00H        ;"CALL MEX"
  61. ;
  62. ; FOLLOWING ARE FUNCTION CODES FOR THE MEX SERVICE CALL PROCESSOR
  63. ;
  64. INMDM    EQU    255        ;RETURN CHAR FROM MDM IN A, CY=NO CHR IN 100MS
  65. TIMER    EQU    254
  66. TMDINP    EQU    253        ;B=# SECS TO WAIT FOR CHAR, CY=NO CHAR
  67. CHEKCC    EQU    252        ;CHECK FOR ^C FROM KBD, Z=PRESENT
  68. SNDRDY    EQU    251        ;TEST FOR MODEM-SEND READY
  69. RCVRDY    EQU    250        ;TEST FOR MODEM-RECEIVE READY
  70. SNDCHR    EQU    249        ;SEND A CHARACTER TO THE MODEM (AFTER SNDRDY)
  71. RCVCHR    EQU    248        ;RECV A CHAR FROM MODEM (AFTER RCVRDY)
  72. ;
  73. CR    EQU    13
  74. LF    EQU    10
  75. ;
  76. ;
  77. ;
  78.     ORG    DIALV        ;OVERLAY THE DIALING VECTOR
  79.     JMP    DIAL
  80. ;    
  81.     IF    DISC        ;IF PROVIDING DISCONNECT CODE
  82.     ORG    DISCV        ;OVERLAY THE VECTOR
  83.     JMP    DISCON
  84.     ENDIF
  85. ;
  86. ; This is the DIAL routine called by MEX to dial a digit. The digit
  87. ; to be dialed is passed in the A register.  Note that two special
  88. ; codes must be intercepted as non-digits: 254 (start dial sequence)
  89. ; and 255 (end-dial sequence).  Mex will always call DIAL with 254
  90. ; in the accumulator prior to dialing a number.  Mex will also call
  91. ; dial with 255 in A as an indication that dialing is complete. Thus,
  92. ; the overlay may use these values to "block" the number, holding it
  93. ; in a buffer until it is completely assembled (in fact, that's the
  94. ; scheme employed here for the Smartmodem).
  95. ;
  96. ; After the 254-start-dial sequence, MEX will call the overlay with
  97. ; digits, one-at-a-time.  MEX will make no assumptions about the dig-
  98. ; its, and will send each to the DIAL routine un-inspected (some modems,
  99. ; like the Smartmodem, allow special non-numeric characters in the
  100. ; phone number, and MEX may make no assumptions about these).
  101. ;
  102. ; After receiving the end-dial sequence (255) the overlay must take
  103. ; whatever end-of-dial actions are necessary *including* waiting for
  104. ; carrier at the distant end.  The overlay should monitor the keyboard
  105. ; during this wait (using the MEX keystat service call), and return
  106. ; an exit code to MEX in the A register, as follows:
  107. ;
  108. ;    0 - Carrier detected, connection established
  109. ;    1 - Far end busy (only for modems that can detect this condition)
  110. ;    2 - No answer (or timed out waiting for modem response)
  111. ;    3 - Keyboard abort (^C only: all others should be ignored)
  112. ;    4 - Error reported by modem
  113. ;
  114. ; <No other codes should be returned after an end-dial sequence>
  115. ;
  116. ; The overlay should not loop forever in the carrier-wait routine, but
  117. ; instead use either the overlay timer vector, or the INMDMV (timed 100
  118. ; ms character wait) service call routine.
  119. ;
  120. ; The DIAL routine is free to use any of the registers, but must return
  121. ; the above code after an end-dial sequence
  122. ;
  123.     ORG    DIALOC
  124. ;
  125. DIAL:    LHLD    DIALPT        ;FETCH POINTER
  126.     CPI    254        ;START DIAL?
  127.     JZ    STDIAL        ;JUMP IF SO
  128.     CPI    255        ;END DIAL?
  129.     JZ    ENDIAL        ;JUMP IF SO
  130. ;
  131. ; Not start or end sequence, must be a digit to be sent to the modem
  132. ;
  133.     MOV    M,A        ;PUT CHAR IN BUFFER
  134.     INX    H        ;ADVANCE POINTER
  135.     SHLD    DIALPT        ;STUFF PNTR
  136.     RET            ;ALL DONE
  137. ;
  138. ; Here on a start-dial sequence
  139. ;
  140. STDIAL:    LXI    H,DIALBF    ;SET UP BUFFER POINTER
  141.     SHLD    DIALPT
  142.     RET
  143. ;
  144. ; Here on an end-dial sequence
  145. ;
  146. ENDIAL:    MVI    M,CR        ;STUFF END-OF-LINE INTO BUFFER
  147.     INX    H        ;FOLLOWED BY TERMINATOR
  148.     MVI    M,0
  149.     LDA    TPULSE        ;GET OVERLAY'S TOUCH-TONE FLAG
  150.     STA    SMDIAL1        ;PUT INTO STRING
  151.     LXI    H,SMDIAL    ;POINT TO DIALING STRING
  152.     CALL    SMSEND        ;SEND IT
  153. WAITSM:    MVI    C,INMDM
  154.     CALL    MEX        ;CATCH ANY OUTPUT FROM THE MODEM
  155.     JNC    WAITSM        ;LOOP UNTIL NO MORE CHARACTERS
  156. ;
  157. ; THE FOLLOWING LOOP WAITS FOR A RESULT FROM THE MODEM (UP TO
  158. ; 60 SECONDS: YOU MAY CHANGE THIS VALUE IN THE FOLLOWING LINE).
  159. ; NOTE THAT THE SMARTMODEM HAS AN INTERNAL 30 SECOND TIMEOUT WHILE
  160. ; FOR A CARRIER ON THE OTHER END.  YOU CAN CHANGE BY PLAYING WITH THE
  161. ; S7 VARIABLE (I.E. SEND THE SMARTMODEM "AT S7=20" TO LOWER THE 30 SECOND
  162. ; WAIT TO 20 SECONDS).
  163. ;
  164. RESULT:    MVI    C,60        ;<<== MAXIMUM TIME TO WAIT FOR RESULT
  165. SMWLP:    PUSH    B
  166.     MVI    B,1        ;CHECK FOR A CHAR, UP TO 1 SEC WAIT
  167.     MVI    C,TMDINP    ;DO TIMED INPUT
  168.     CALL    MEX
  169.     POP    B
  170.     JNC    SMTEST        ;JUMP IF MODEM HAD A CHAR
  171.     PUSH    B        ;NO, TEST FOR CONTROL-C FROM CONSOLE
  172.     MVI    C,CHEKCC
  173.     CALL    MEX
  174.     POP    B
  175.     JNZ    SMNEXT        ;IF NOT, JUMP
  176.     MVI    B,CR        ;YES, SHUT DOWN THE MODEM
  177.     MVI    C,SNDCHR
  178.     CALL    MEX
  179.     call    discon        ;disconnect the modem & restore verbose results
  180.     MVI    A,3        ;RETURN ABORT CODE
  181.     RET
  182. SMNEXT:    DCR    C        ;NO
  183.     JNZ    SMWLP        ;CONTINUE
  184. ;
  185. ; ONE MINUTE WITH NO MODEM RESPONSE (OR NO CONNECTION)
  186. ;
  187. SMTIMO:    MVI    A,2        ;RETURN TIMEOUT CODE
  188.     RET
  189. ;
  190. ; MODEM GAVE US A RESULT, CHECK IT
  191. ;
  192. SMTEST:    ANI    7FH        ;IGNORE ANY PARITY
  193.     CALL    SMANAL        ;TEST THE RESULT
  194.     MOV    A,B        ;A=RESULT (CY SIGNIFICANT HERE TOO)
  195.     PUSH    PSW        ;SAVE IT
  196. SMTLP:    MVI    C,INMDM        ;FLUSH ANY REMAINING COMMAND LINE
  197.     CALL    MEX
  198.     JC    SMCHEK        ;JUMP IF NO INPUT
  199.     CPI    LF        ;GOT SOME ... WAITING FOR EOL
  200.     JNZ    SMTLP        ;EAT ANY IN-BETWEEN
  201. SMCHEK:    POP    PSW        ;A HAS MEX RETURN-CODE, CY=1 IF UNKNOWN
  202.     JC    RESULT        ;IF RESULT UNKNOWN, IGNORE IT
  203.     RET
  204. ;
  205. SMANAL:    MVI    B,0        ;PREP CONNECT CODE
  206. ;
  207. ;
  208.  
  209. ; PopCom numeric result code table:
  210. ;
  211. IF     NUMRES
  212.  
  213.     ; connection responses
  214.  
  215.     CPI    '1'    ! LXI d,Pop300    ! JZ SendMsg    ;300  baud
  216.     CPI    '5'    ! LXI d,Pop1200 ! JZ SendMsg    ;1200 baud
  217.  
  218.     INR    b    ; busy signal responses
  219.         ;    note that POPCOM "Voice" result placed here because
  220.         ;    many busy signals are observed to fall in it's
  221.         ;    voice frequency range & misinterpreted
  222.  
  223.     CPI    ':'    ! RZ    ;correct busy signal interpretation
  224.     CPI    ';'    ! LXI d,PopV    ! JZ SendMsg    ; voice frequency
  225.  
  226.    INR    b    ; no connection responses
  227.  
  228.     CPI    '3'    ! RZ                ; no connection
  229.     CPI    '2'    ! LXI d,Pop2    ! JZ SendMsg    ; local phone ringing
  230.     CPI    '6'    ! LXI d,Pop6    ! JZ SendMsg    ; remote set 1200
  231.     CPI    '7'    ! LXI d,Pop7    ! JZ SendMsg    ; remote set 300
  232.     CPI    '8'    ! LXI d,Pop8    ! JZ SendMsg    ; wierd continuous tone
  233.     CPI    '9'    ! LXI d,Pop9    ! JZ SendMsg    ; no tone
  234.     CPI    '='    ! LXI d,PopP    ! JZ SendMsg    ; local phone offhook
  235.     CPI    '<'    ! LXI d,PopR    ! JZ SendMsg    ; too many rings
  236.     CPI    '?'    ! LXI d,PopL    ! JZ SendMsg    ; line current no good
  237.  
  238.    INR    b    ; error response
  239.  
  240.     CPI    '4'    ! RZ
  241. ENDIF
  242.  
  243.  
  244.  
  245.  
  246.     STC            ;UNKNOWN...
  247.     RET
  248.  
  249. SendMsg:
  250.     MVI    c,9
  251.     CALL    MEX
  252.     RET
  253.  
  254. ;
  255. ; FOLLOWING ROUTINE DISCONNECTS THE MODEM USING SMARTMODEM
  256. ; CODES. ALL REGISTERS ARE AVAILABLE FOR THIS FUNCTION.
  257. ; NOTHING RETURNED TO CALLER.
  258. ;
  259.     IF    DISC
  260. ;
  261. DISCON:    MVI    B,20
  262.     MVI    C,TIMER        ;WAIT 2 SECONDS
  263.     CALL    MEX
  264.     LXI    H,SMATN        ;SEND '+++'
  265.     CALL    SMSEND
  266.     MVI    B,20        ;WAIT 2 MORE SECONDS
  267.     MVI    C,TIMER
  268.     CALL    MEX
  269. DISC2:    LXI    H,SMDISC    ;SEND 'ATH'
  270.     CALL    SMSEND
  271.     MVI    B,10        ;WAIT 1 SECOND
  272.     MVI    C,TIMER
  273.     CALL    MEX
  274.     RET
  275. ;
  276. SMATN:    DB    '+++',0
  277. SMDISC:    DB    'ATH0V1',CR,0    ;disconnect & switch to verbose responses
  278. ;
  279.     ENDIF
  280. ;
  281. ; SMARTMODEM UTILITY ROUTINE: SEND STRING TO MODEM
  282. ;
  283. SMSEND:    MVI    C,SNDRDY    ;WAIT FOR MODEM READY
  284.     CALL    MEX
  285.     JNZ    SMSEND
  286.     MOV    A,M        ;FETCH NEXT CHARACTER
  287.     INX    H
  288.     ORA    A        ;END?
  289.     RZ            ;DONE IF SO
  290.     MOV    B,A        ;NO, POSITION FOR SENDING
  291.     MVI    C,SNDCHR    ;NOPE, SEND THE CHARACTER
  292.     CALL    MEX
  293.     JMP    SMSEND
  294. ;
  295. ; DATA AREA
  296. ;
  297. SMDIAL: DB    'ATS18=0V0X2D'    ;Sw#18=Smartmodem protocol,numeric,PopCom resps
  298. SMDIAL1: DB    'T '
  299. DIALBF:    DS    52        ;2* 24 CHAR MAX, + CR + NULL + SLOP
  300. DIALPT:    DS    2        ;DIAL POSITION POINTER
  301. ;
  302.    ; additions to MEX responses
  303. Pop2:    DB    'Ring -  $'
  304. Pop6:    DB    'Set 1200 -  $'
  305. Pop7:    DB    'Set 300 -  $'
  306. Pop8:    DB    'Tone -  $'
  307. Pop9:    DB    'No Tone -  $'
  308. PopL:    DB    'Line -  $'
  309. PopR:    DB    'Remote Ring - $'
  310. PopP:    DB    'Phone -  $'
  311. Pop300: DB    '300 baud connection $',0
  312. Pop1200: DB    '1200 baud connection $',0
  313. PopV:    DB    'Voice or $'
  314.     END
  315.