home *** CD-ROM | disk | FTP | other *** search
/ Game Killer / Game_Killer.bin / 1001.INT13.ASM < prev    next >
Assembly Source File  |  1986-08-10  |  10KB  |  298 lines
  1. PAGE 64,132
  2. ;
  3. ;         This program intercepts Int 13H calls and prints
  4. ;         the drive, side, track, sector, # of sectors, operation,
  5. ;         and return code.
  6. ; 
  7. cseg    segment 
  8.         org 100h
  9. INT13   proc far
  10.         assume cs:cseg,ds:cseg
  11. ;
  12.         jmp install                    ;install and make routine resident
  13. ;
  14. redef13      label      word
  15. oldint13     dd         0              ;save area for old int13 vector
  16. int13loc     equ        13h*4h         ;vector location for int13h
  17. drive_a      equ         'A'
  18. drive_b      equ         'B'
  19. drive_c      equ         'C'
  20. drive_d      equ         'D'
  21. drive_x      equ         'X'
  22. save_ip      dw         0              ;save area for calling pgm's IP
  23. save_cs      dw         0              ;save area for calling pgm's CS
  24. ;
  25. message      db 'Drv: '
  26. drive        db ?
  27.              db ' Side: '
  28. side1        db ?
  29. side2        db ?
  30.              db '   Tr: '
  31. track1       db ?
  32. track2       db ?
  33.              db ' Sec: '
  34. sector1      db ?
  35. sector2      db ?
  36.              db '  # secs: '
  37. sec_cnt1     db ?
  38. sec_cnt2     db ?
  39.              db ' Op: '
  40. op_1         db ?
  41. op_2         db ?
  42.              db '   Retcd: '
  43. status1      db ?
  44. status2      db ?
  45.              db '  Addr: '
  46. cs_1         db ?
  47. cs_2         db ?
  48. cs_3         db ?
  49. cs_4         db ?
  50.              db ':'
  51. ip_1         db ?
  52. ip_2         db ?
  53. ip_3         db ?
  54. ip_4         db ?
  55.              db 0ah,0dh
  56. ;------------------------------
  57. inst_msg     db 'INT13 is now installed.......$'
  58. ;
  59. newint13:
  60.         sti
  61.         push ax
  62.         push bp
  63.         mov bp,sp                      
  64.         mov ax,[bp+4]                  ;Retrieve return IP value 
  65.         mov cs:save_ip,ax              ;    from stack.
  66.         mov ax,[bp+6]                  ;Retrieve return CS value
  67.         mov cs:save_cs,ax              ;    from stack.
  68.         pop bp                         ;Save anything which will be
  69.         pop ax                         ;    be changed during
  70.         pushf                          ;    processing.
  71.         push di
  72.         push si
  73.         push ds
  74.         push es
  75.         push bx
  76.         push cx
  77.         push dx
  78.         push ax
  79.         mov ax,cs
  80.         mov ds,ax
  81. ;---------------DRIVE------------------
  82.         cmp dl,00h                     ;Drive A? (dl=00)
  83.         jne chk1                       ; Note: processing is in place for
  84.         mov drive,drive_a              ;    logging disk activity on all
  85.         jmp drv_exit                   ;    drives, if desired.  See below
  86. chk1:   cmp dl,01h                     ;Drive B?
  87.         jne chk2
  88.         mov drive,drive_b
  89.         jmp drv_exit
  90. chk2:   cmp dl,02h                     ;Drive C?
  91.         jne chk3
  92.         mov drive,drive_c
  93.         jmp drv_exit
  94. chk3:   cmp dl,03h
  95.         jne chkx
  96.         mov drive,drive_d
  97.         jmp drv_exit
  98. chkx:   mov drive,drive_x
  99. drv_exit:
  100. ;---------------SIDE  (DH) ------------
  101.         mov ah,dh                      ;record side being requested-left digit
  102.         call leftdig                   ;convert to ASCII code for printing
  103.         mov cs:side1,ah                ;move code to message area
  104.         mov ah,dh                      ;same for right digit
  105.         call rightdig
  106.         mov cs:side2,ah
  107. ;---------------TRACK NO. (CH)----------
  108.         mov ah,ch
  109.         call leftdig
  110.         mov cs:track1,ah
  111.         mov ah,ch
  112.         call rightdig
  113.         mov cs:track2,ah
  114. ;----------------------------------------
  115. ;
  116. ;----------------SECTOR NO. (CL)---------
  117.         mov ah,cl
  118.         call leftdig
  119.         mov cs:sector1,ah
  120.         mov ah,cl
  121.         call rightdig
  122.         mov cs:sector2,ah
  123. ;------------------------------------------
  124. ;
  125. ;----------------NO. OF SECTORS (AL)-------
  126. ;
  127.         pop ax      ;recall ax
  128.         push ax     ;save it again
  129.         mov ah,al
  130.         call leftdig
  131.         mov cs:sec_cnt1,ah
  132.         pop ax
  133.         push ax
  134.         mov ah,al
  135.         call rightdig
  136.         mov cs:sec_cnt2,ah
  137. ;--------------------------------------------------
  138. ;
  139. ;--------------OPERATION TYPE (AH)-----------------
  140. ; 00:reset 01:read status 02:read sectors 03:write sec. 04:verify 05:format
  141. ;
  142.  
  143.         pop ax      ;recall ax
  144.         push ax     ;save it again
  145.         call leftdig
  146.         mov cs:op_1,ah
  147.         pop ax
  148.         push ax
  149.         call rightdig
  150.         mov cs:op_2,ah
  151. ;-------------- RETURN ADDRESS CS:IP -------------------
  152. ;
  153.         mov ax,cs:save_ip
  154.         call leftdig
  155.         mov cs:ip_1,ah
  156.         mov ax,cs:save_ip
  157.         call rightdig
  158.         mov cs:ip_2,ah
  159.         mov ax,cs:save_ip
  160.         xchg ah,al
  161.         call leftdig
  162.         mov cs:ip_3,ah
  163.         mov ax,cs:save_ip
  164.         xchg ah,al
  165.         call rightdig
  166.         mov cs:ip_4,ah
  167. ;
  168.         mov ax,cs:save_cs
  169.         call leftdig
  170.         mov cs:cs_1,ah
  171.         mov ax,cs:save_cs
  172.         call rightdig
  173.         mov cs:cs_2,ah
  174.         mov ax,cs:save_cs
  175.         xchg ah,al
  176.         call leftdig
  177.         mov cs:cs_3,ah
  178.         mov ax,cs:save_cs
  179.         xchg ah,al
  180.         call rightdig
  181.         mov cs:cs_4,ah
  182. ;--------------------------------
  183.              pop ax                    ;Restore the things which were
  184.              pop dx                    ;    saved
  185.              pop cx
  186.              pop bx
  187.              pop es
  188.              pop ds
  189.              pop si
  190.              pop di
  191.              popf
  192. ;--------------------
  193.              pushf           ; Put flags, CS and IP onto stack for return to
  194.              push cs         ;  routine below after standard int 13h processing
  195.              call intcall    ; IP will point to next instruction
  196. ;
  197. ;---------------------------Report status of int 13h call----------
  198. ;
  199.              pushf
  200.              push ax                   ;Save it again
  201.              call leftdig
  202.              mov cs:status1,ah
  203.              pop ax
  204.              push ax
  205.              call rightdig
  206.              mov cs:status2,ah
  207.              pop ax
  208. ;------------  PRINT THE MESSAGE --------------------------
  209.              cmp dl,00h  ;******** REMOVE THESE TWO LINES IF YOU WISH
  210.              jne goback  ;********   ALL DISK ACTIVITY TO BE LOGGED
  211.              push ax
  212.              push cx
  213.              push dx
  214.              push si
  215.              mov cx,52h                ; Length of message
  216.              mov si,offset message
  217.              xor dx,dx
  218. prnloop:     mov ah,00h
  219.              mov al,cs:[si]  
  220.              int 17h
  221.              inc si
  222.              loop prnloop
  223.              pop si
  224.              pop dx
  225.              pop cx
  226.              pop ax
  227. goback:      popf
  228. ;-------------------------------------------------------
  229.              ret  2          ; Go back to calling program.
  230.                              ; Note:"iret" is not used because the flags
  231.                              ;   would be popped (and we wish to pass back
  232.                              ;   the changed set of flags).  The "2" ensures
  233.                              ;   that the stack is restored by incrementing
  234.                              ;   the stack pointer by two extra bytes.
  235. ;-----------------------
  236. intcall      PROC near     ; get set to go to standard int 13h routine
  237.              pushf
  238.              push cs:[redef13 + 2]     ; "cs" of int 13h routine
  239.              push cs:[redef13]         ; "ip" of int 13h routine
  240.              iret                      ; Branch to normal int13h code in ROM
  241. intcall      endp 
  242. ;--------------------------
  243. ;   Routine to convert high-order digit in AH to an ASCII character
  244. ;
  245. leftdig      PROC
  246.              and ah,11110000b ; Mask right 4 bits
  247.              shr ah,1         ; Move high-order digit to low-order pos.
  248.              shr ah,1
  249.              shr ah,1
  250.              shr ah,1
  251.              cmp ah,0ah       ; Check for value 0 through 9
  252.              jnb b37          ; If value hex A through F, jump 
  253.              add ah,30h       ; Add 30h to make ASCII character
  254.              jmp b2
  255.        b37:  add ah,37h       ; If hex A-F, add 37h to make ASCII character
  256.         b2:  ret
  257. leftdig      endp
  258. ;-----------------------
  259. ;   Routine to convert low-order digit in AH to an ASCII character
  260. ;
  261. rightdig     PROC near
  262.              and ah,00001111b ; mask left 4 bits
  263.              cmp ah,0ah
  264.              jnb a37
  265.              add ah,30h
  266.              jmp a1
  267.        a37:  add ah,37h
  268.         a1:  ret
  269. rightdig     endp
  270. ;-----------------------
  271. install:
  272.              mov ax,0
  273.              mov es,ax
  274.              mov di,int13loc           ;Save old 
  275.              mov ax,es:[di]            ;   interrupt 13h
  276.              mov bx,es:[di+2]          ;   vector
  277.              mov si,offset oldint13    ;     "
  278.              mov [si],ax               ;     "
  279.              mov [si+2],bx             ;     "
  280.              mov ax,0                  
  281.              mov es,ax
  282.              mov bx,ds
  283.              cli                       ;Turn off interrupts
  284.              mov di,int13loc           ;Change int13h ....
  285.              mov ax,offset newint13    ;   vector to...
  286.              mov es:[di],ax            ;   point to...
  287.              mov es:[di+2],bx          ;   this program.
  288.              sti                       ;Turn interrupts back on
  289.              mov dx,offset inst_msg
  290.              mov ah,09h                ;Print string function
  291.              int 21h                   ;Print "install" message
  292.              mov dx,offset install     ;Address of end of resident routine
  293.              int 27h                   ;Terminate and stay resident
  294. INT13        endp
  295. ;------------------------------
  296. cseg         ends
  297. end          INT13
  298.