home *** CD-ROM | disk | FTP | other *** search
/ Hacker Chronicles 2 / HACKER2.BIN / 195.LOOPYAGI.BAS < prev    next >
BASIC Source File  |  1987-04-18  |  3KB  |  103 lines
  1. 5  REM  KAIGT PARAMETRIC DESIGN PROGRAM FOR LOOP YAGI
  2. 6 REM This program calculates dimensions for a UHF/microwave loop
  3. 7 REM Yagi antenna based on data obtained from a parametric design
  4. 8 REM study. For more information on the loop Yagi antenna see the
  5. 9 REM RSGB VHF/UHF Manual (obtainable from the ARRL).
  6. 10  DIM A(38)
  7. 20 A(1) = 3.1:A(2) = 4.05:A(3) = 5.17:A(4) = 6!
  8. 25 A(5) = 7.78:A(6) = 9.560001:A(7) = 10.81:A(8) = 13.12
  9. 30  FOR X = 1 TO 30
  10. 40 A(X + 8) = 13.12 + X * 3.56
  11. 50  NEXT 
  12. 60  INPUT "FREQUENCY OF USE ? (MHZ)";F
  13. 70 FC = 1296 / F
  14. 72  FOR X = 1 TO 38
  15. 75 A(X) = A(X) * FC
  16. 77  NEXT 
  17. 80 R1 = 9.67
  18. 90 DE = 9.229999
  19. 100  DIM B(36)
  20. 110  FOR X = 1 TO 11
  21. 120 B(X) = 8.25
  22. 130  NEXT 
  23. 140  INPUT "27 OR 38 ELEMENT VERSION ?";N
  24. 142  IF N <  > 27 THEN  IF N <  > 38 THEN  GOTO 140
  25. 150  FOR X = 12 TO 18
  26. 160 B(X) = 8!
  27. 170  NEXT 
  28. 180  IF N = 27 THEN  GOSUB 500
  29. 190  IF N = 38 THEN  GOSUB 600
  30. 200  FOR X = 1 TO 36
  31. 210 B(X) = B(X) * FC
  32. 215  NEXT 
  33. 220 R1 = R1 * FC
  34. 230 DE = DE * FC
  35. 240  INPUT "BOOM DIAMETER ? (IN)";B
  36. 250  INPUT "ELEMENT WIDTH ? (IN)";W
  37. 260  INPUT "ELEMENT THICKNESS ? (IN)";T
  38. 265  PRINT : PRINT 
  39. 270 B1 = B / FC:W1 = W / FC:T1 = T / FC
  40. 280  IF B1 < .5 THEN  GOSUB 700
  41. 290  IF B1 > 2.1 THEN  GOSUB 700
  42. 300  IF T1 < .028 THEN  GOSUB 750
  43. 310  IF T1 > .063 THEN  GOSUB 750
  44. 320  IF W1 < .1 THEN  GOSUB 800
  45. 330  IF W1 > .375 THEN  GOSUB 800
  46. 340 B2 = ((B1 - .5) + (B1 - .5) ^ 2) * 2.88
  47. 350  FOR X = 1 TO (N - 2)
  48. 360 B(X) = B(X) + (B(X) / 100) * B2
  49. 365  NEXT 
  50. 370 DE = DE + DE * B2 / 100
  51. 380 R1 = R1 + R1 * B2 / 100
  52. 390 W2 = (.1875 - W1) * 4.8
  53. 400  FOR X = 1 TO (N - 2)
  54. 410 B(X) = B(X) + (B(X) / 100) * W2
  55. 420  NEXT 
  56. 422 DE = DE + DE * W2 / 100
  57. 424 R1 = R1 + R1 * W2 / 100
  58. 430 T2 = (T1 - .028) * (.6 / .031)
  59. 440  FOR X = 1 TO (N - 2)
  60. 450 B(X) = B(X) + ((B(X) / 100) * T2)
  61. 460  NEXT 
  62. 470 DE = DE + DE * T2 / 100
  63. 475 R1 = R1 + R1 * T2 / 100
  64. 480 RA = 4.5:RB = 5.5
  65. 485 RA = RA * FC:RB = RB * FC
  66. 495  GOTO 1000
  67. 500  FOR X = 19 TO 25
  68. 510 B(X) = 8!
  69. 520  NEXT 
  70. 530  RETURN 
  71. 600  FOR X = 19 TO 36
  72. 610 B(X) = 7.7
  73. 620  NEXT 
  74. 630  RETURN 
  75. 700  PRINT "BOOM DIAMETER OUTSIDE RANGE OF PARAMETRIC STUDY. CALCULATION CONTINUES WITH EXTRAPOLATED DATA"
  76. 710  RETURN 
  77. 750  PRINT "MATERIAL THICKNESS OUTSIDE RANGE OF PARAMETRIC STUDY. CALCULATION CONTINUES WITH EXTRAPOLATED DATA"
  78. 760  RETURN 
  79. 800  PRINT "ELEMENT WIDTH OUTSIDE RANGE OF PARAMETRIC STUDY. CALCULATION CONTINUES WITH EXTRAPOLATED DATA"
  80. 810  RETURN 
  81. 1000  PRINT "DATA FOR LOOP YAGI FOR USE AT ";F;" MHZ"
  82. 1010  PRINT 
  83. 1020  PRINT "BOOM DIAMETER ";B;" IN"
  84. 1030  PRINT "ELEMENT WIDTH ";W;" IN"
  85. 1040  PRINT "ELEMENT THICKNESS ";T;" IN"
  86. 1045  PRINT "REFLECTING SCREEN ";( INT (RA * 1000)) / 1000;" X ";( INT (RB * 1000)) / 1000
  87. 1046  PRINT : PRINT "ALL DIMENSIONS IN INCHES": PRINT 
  88. 1047  PRINT "ELEMENT         DISTANCE        LENGTH"
  89. 1048  PRINT "                FROM SCREEN"
  90. 1049  PRINT "                                (CIRCUMFERENCE)": PRINT 
  91. 1050  PRINT "R1",( INT (A(1) * 1000)) / 1000,( INT (R1 * 1000)) / 1000
  92. 1060  PRINT "DE",( INT (A(2) * 1000)) / 1000,( INT (DE * 1000)) / 1000
  93. 1070  FOR X = 1 TO N - 2
  94. 1075 L = ( INT (B(X) * 1000)) / 1000
  95. 1076 L1 = ( INT (A(X + 2) * 1000)) / 1000
  96. 1080  PRINT "D";X,L1,L
  97. 1090  NEXT 
  98. 1100  END 
  99.  KA3NHB KA3NHB K
  100.  
  101. ka3nhb ka3nhb de w3hvm w3hvm kn
  102.  
  103. W3HV═á D┼á KA3NH┬á NAM┼á I╙ JEF╞á JEF╞á AN─á QT╚á I╙á GAITHERSBURG¼á MD«