home *** CD-ROM | disk | FTP | other *** search
/ Hacker Chronicles 2 / HACKER2.BIN / 924.NOM.LIB < prev    next >
Text File  |  1987-12-23  |  12KB  |  307 lines
  1. * Library of standard devices
  2. *
  3. * This is the master library for MicroSim's standard parts libraries.
  4. *   You are welcome to make as many copies of it as you find convenient.
  5. *
  6. * Release date: 87/12/22
  7. *
  8.  
  9. * Sample library of diode model parameters
  10. *
  11. * This is a reduced version of MicroSim's diode model library.
  12. *   You are welcome to make as many copies of it as you find convenient.
  13. *
  14. * The parameters in this model library were derived from the data
  15. * sheets for each part.  The methods used were as follows:
  16. *    IS        nominal leakage current
  17. *    RS        for zener diodes: nominal small-signal impedance
  18. *            at specified operating current
  19. *    IB        for zener diodes: set to nominal leakage current
  20. *    IBV        for zener diodes: at specified operating current
  21. *            IBV is adjusted to give the rated zener voltage
  22. *
  23. *
  24. *** Zener Diodes ***
  25. *
  26. * "A" suffix zeners have the same parameters (e.g., 1N750A has the same
  27. * parameters as 1N750)
  28. *
  29. .MODEL    D1N752        D (IS=0.5UA RS=6 BV=5.20 IBV=0.5UA)
  30. .MODEL    D1N754        D (IS=0.05UA RS=3 BV=6.41 IBV=0.05UA)
  31. .MODEL    D1N759        D (IS=0.05UA RS=15 BV=11.37 IBV=0.05UA)
  32. *
  33. *** 1N916 ***
  34. *
  35. .MODEL    D1N914        D (IS=100E-15 RS=16 CJO=2PF TT=12NS BV=100 IBV=100E-15)
  36. .MODEL    D1N916        D (IS=100E-15 RS=8 CJO=1PF TT=12NS BV=100 IBV=100E-15)
  37. *
  38. * End of library file
  39.  
  40. * Library of bipolar transistor model parameters
  41. *
  42. * This is a reduced version of MicroSim's bipolar transistor model library.
  43. *   You are welcome to make as many copies of it as you find convenient.
  44. *
  45. * The parameters in this model library were derived from the data sheets for
  46. * each part.  Where specified, the part was characterize using the Parts
  47. * option.  Otherwise, methods used were as follows:
  48. *
  49. *    NE, NC        Normally set to 4
  50. *    BF, ISE, IKF    These are adjusted to give the nominal beta vs.
  51. *            collector current curve.  BF controls the mid-
  52. *            range beta.  ISE/IS controls the low-current
  53. *            roll-off.  IKF controls the high-current rolloff.
  54. *    ISC        Set to ISE.
  55. *    IS, RB, RE, RC    These are adjusted to give the nominal VBE vs.
  56. *            IC and VCE vs. IC curves in saturation.  IS
  57. *            controls the low-current value of VBE.  RB+RE
  58. *            controls the rise of VBE with IC.  RE+RC controls
  59. *            the rise of VCE with IC.  RC is normally set to 0.
  60. *    VAF        Using the voltages specified on the data sheet
  61. *            VAF is set to give the nominal output impedance
  62. *            (RO on the .OP printout) on the data sheet.
  63. *    CJC, CJE    Using the voltages specified on the data sheet
  64. *            CJC and CJE are set to give the nominal input
  65. *            and output capacitances (CPI and CMU on the .OP
  66. *            printout; Cibo and Cobo on the data sheet).
  67. *    TF        Using the voltages and currents specified on the
  68. *            data sheet for FT, TF is adjusted to produce the
  69. *            nominal value of FT on the .OP printout.
  70. *    TR        Using the rise and fall time circuits on the
  71. *            data sheet, TR (and if necessary TF) are adjusted
  72. *            to give a transient analysis which shows the
  73. *            nominal values of the turn-on delay, rise time,
  74. *            storage time, and fall time.
  75. *    KF, AF        These parameters are only set if the data sheet has
  76. *            a spec for noise.  Then, AF is set to 1 and KF
  77. *            is set to produce a total noise at the collector
  78. *            which is greater than the generator noise at the
  79. *            collector by the rated number of decibels.
  80. *
  81. *
  82. *** 2N2222 ***
  83. *
  84. .model Q2N2222    NPN(Is=3.108f Xti=3 Eg=1.11 Vaf=131.5 Bf=217.5 Ne=1.541
  85. +        Ise=190.7f Ikf=1.296 Xtb=1.5 Br=6.18 Nc=2 Isc=0 Ikr=0 Rc=1
  86. +        Cjc=14.57p Vjc=.75 Mjc=.3333 Fc=.5 Cje=26.08p Vje=.75
  87. +        Mje=.3333 Tr=51.35n Tf=451p Itf=.1 Vtf=10 Xtf=2)
  88. *
  89. *** 2N2907
  90. *
  91. .model Q2N2907    PNP(Is=9.913f Xti=3 Eg=1.11 Vaf=90.7 Bf=197.8 Ne=2.264
  92. +        Ise=6.191p Ikf=.7322 Xtb=1.5 Br=3.369 Nc=2 Isc=0 Ikr=0 Rc=1
  93. +        Cjc=14.57p Vjc=.75 Mjc=.3333 Fc=.5 Cje=20.16p Vje=.75
  94. +        Mje=.3333 Tr=29.17n Tf=405.6p Itf=.4 Vtf=10 Xtf=2)
  95.  
  96. * Library of MOSFET model parameters (for "power" MOSFET devices)
  97. *
  98. * This is a reduced version of MicroSim's power MOSFET model library.
  99. *   You are welcome to make as many copies of it as you find convenient.
  100. *
  101. * The parameters in this model library were derived from the data
  102. * sheets for each part.  The methods used were as follows:
  103. *    LEVEL        Set to 3 (short-channel device).
  104. *    TOX        Determined from gate ratings.
  105. *    L, LD, W, WD    Assume L=2u.  Calculate from input capacitance.
  106. *    XJ, NSUB    Assume usual technology.
  107. *    IS, RD, RB    Determined from "source-drain diode forward voltage"
  108. *            specification or curve (Idr vs. Vsd).
  109. *    RS        Determine from Rds(on) specification.
  110. *    RDS        Calculated from Idss specification or curves.
  111. *    VTO, UO, THETA    Determined from "output characteristics" curve family
  112. *            (Ids vs. Vds, stepped Vgs).
  113. *    ETA, VMAX, CBS    Set for null effect.
  114. *    CBD, PB, MJ    Determined from "capacitance vs. Vds" curves.
  115. *    RG        Calculate from rise/fall time specification or curves.
  116. *    CGSO, CGDO    Determined from gate-charge, turn-on/off delay and
  117. *            rise time specifications.
  118. *
  119. * NOTE:    when specifying the instance of a device in your circuit file:
  120. *
  121. *    BE SURE to have the source and bulk nodes connected together, as this
  122. *    is the way the real device is constructed.
  123. *
  124. *    DO NOT include values for L, W, AD, AS, PD, PS, NRD, or NDS.
  125. *    The PSpice default values for these parameters are taken into account
  126. *    in the library model statements.  Of course, you should NOT reset
  127. *    the default values using the .OPTIONS statement, either.
  128. *
  129. * Example use:    M17    15 23 7 7    IRF150
  130. *
  131. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  132. *
  133. * The "power" MOSFET device models benefit from relatively complete specifi-
  134. * cation of static and dynamic characteristics by their manufacturers.  The
  135. * following effects are modeled:
  136. *    - DC transfer curves in forward operation,
  137. *    - gate drive characteristics and switching delay,
  138. *    - "on" resistance,
  139. *    - reverse-mode "body-diode" operation.
  140. *
  141. * The factors not modeled include:
  142. *    - maximum ratings (eg. high-voltage breakdown),
  143. *    - safe operating area (eg. power dissipation),
  144. *    - latch-up,
  145. *    - noise.
  146. *
  147. * For high-current switching applications, we advise that you include
  148. * series inductance elements, for the source and drain, in your circuit file.
  149. * In doing so, voltage spikes due to di/dt will be modeled.  According to the
  150. * 1985 International Rectifier databook, the following case styles have lead
  151. * inductance values of:
  152. *    TO-204 (modified TO-3)    source = 12.5nH        drain = 5.0nH
  153. *    TO-220            source =  7.5nH        drain = 3.5-4.5nH
  154. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  155. *
  156. * IRF150, from 1985 Siliconix databook, pages 1-7,8 and 5-22,3
  157. *
  158. .model IRF150    NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  159. +        Tox=100n Uo=600 Phi=.6 Rs=5.724m Kp=20.76u W=.31 L=2u
  160. +        Vto=2.759 Rd=2.6m Rds=400K Cbd=4.039n Pb=.8 Mj=.5 Fc=.5
  161. +        Cgso=8.984n Cgdo=1.62n Rg=18.6 Is=648.2E-18)
  162. *
  163. * IRF9130, from 1985 International Rectifier databook, pages D-187,92
  164. *
  165. .model IRF9130    PMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  166. +        Tox=100n Uo=300 Phi=.6 Rs=.1429 Kp=9.899u W=1.1 L=2u
  167. +        Vto=-3.418 Rd=74.02m Rds=400K Cbd=407.7p Pb=.8 Mj=.5 Fc=.5
  168. +        Cgso=1.996n Cgdo=147p Rg=8.696 Is=1E-30)
  169. *
  170. * End of library file
  171.  
  172. * Library of Op Amp subcircuit definitions
  173. *
  174. * This is a reduced version of MicroSim's opamp subcircuit library.
  175. *   You are welcome to make as many copies of it as you find convenient.
  176. *
  177. * The parameters in this opamp library were derived from the data
  178. * sheets for each part.  The macromodel used is described in:
  179. *
  180. *    Macromodeling of Integrated Circuit Operational Amplifiers
  181. *        by Graeme Boyle, Barry Cohn, Donald Pederson, and
  182. *           James Solomon
  183. *    IEEE Journal of Solid-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  184. *
  185. * Differences from the reference (above) occur in the output limiting stage
  186. * which was modified to reduce internally generated currents associated with
  187. * output voltage limiting, as well as short-circuit current limiting.
  188. *
  189. * The opamps are modelled at room temperature.  The macro model
  190. * does not track changes with temperature.  This library file contains
  191. * models for nominal, not worst case, devices.
  192. *
  193. * Note: Each macromodel consists of a subcircuit definition AND a set
  194. *    of .MODEL statements.  The .MODEL statements should be put into
  195. *    the main circuit file along with the subcircuit definition.
  196. *
  197. *
  198. *-----------------------------------------------------------------------------
  199. * connections:   non-inverting input
  200. *                | inverting input
  201. *                | | positive power supply
  202. *                | | | negative power supply
  203. *                | | | | output
  204. *                | | | | |
  205. .subckt uA741    1 2 3 4 5
  206. *
  207.   c1   11 12 8.661E-12
  208.   c2    6  7 30.00E-12
  209.   dc    5 53 dx
  210.   de   54  5 dx
  211.   dlp  90 91 dx
  212.   dln  92 90 dx
  213.   dp    4  3 dx
  214.   egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5
  215.   fb    7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6
  216.   ga    6  0 11 12 188.5E-6
  217.   gcm   0  6 10 99 5.961E-9
  218.   iee  10  4 dc 15.16E-6
  219.   hlim 90  0 vlim 1K
  220.   q1   11  2 13 qx
  221.   q2   12  1 14 qx
  222.   r2    6  9 100.0E3
  223.   rc1   3 11 5.305E3
  224.   rc2   3 12 5.305E3
  225.   re1  13 10 1.836E3
  226.   re2  14 10 1.836E3
  227.   ree  10 99 13.19E6
  228.   ro1   8  5 50
  229.   ro2   7 99 100
  230.   rp    3  4 18.16E3
  231.   vb    9  0 dc 0
  232.   vc    3 53 dc 1
  233.   ve   54  4 dc 1
  234.   vlim  7  8 dc 0
  235.   vlp  91  0 dc 40
  236.   vln   0 92 dc 40
  237. .model dx D(Is=800.0E-18)
  238. .model qx NPN(Is=800.0E-18 Bf=93.75)
  239. .ends
  240. *
  241. * End of library file
  242.  
  243. * Library of Comparator subcircuit definitions
  244. *
  245. * This is a reduced version of MicroSim's voltage comparator subcircuit
  246. *   library.  You are welcome to make as many copies of it as you find
  247. *   convenient.
  248. *
  249. * The parameters in this opamp library were derived from the data
  250. * sheets for each part.  The comparator macro model used is derived
  251. * from the op amp macro model used in the OPNOM.LIB file.  The op amp
  252. * macro model is described in:
  253. *
  254. *    Macromodeling of Integrated Circuit Operational Amplifiers
  255. *        by Graeme Boyle, Barry Cohn, Donald Pederson, and
  256. *           James Solomon
  257. *    IEEE Journal of Solid-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  258. *
  259. * Although we do not use it, a slightly more elaborate comparator macro
  260. * model is described in:
  261. *
  262. *    An Integrated-Circuit Comparator Macromodel
  263. *        by Ian Getreu, Andreas Hadiwidjaja, and Johan Brinch
  264. *    IEEE Journal of Solid-State Circuits, Vol. SC-11, no. 6, Dec. 1976
  265. *
  266. * This reference covers the considerations that go into duplicating the
  267. * behavior of voltage comparators.
  268. *
  269. * The comparators are modelled at room temperature.  The macro model
  270. * does not track changes with temperature.  This library file contains
  271. * models for nominal, not worst case, devices.
  272. *
  273. *-----------------------------------------------------------------------------
  274. * connections:   non-inverting input
  275. *                | inverting input
  276. *                | | positive power supply
  277. *                | | | negative power supply
  278. *                | | | | open collector output
  279. *                | | | | | output ground
  280. *                | | | | | |
  281. .subckt LM111    1 2 3 4 5 6
  282. *
  283.   f1    9  3 v1 1
  284.   iee   3  7 dc 100.0E-6
  285.   vi1  21  1 dc .45
  286.   vi2  22  2 dc .45
  287.   q1    9 21  7 qin
  288.   q2    8 22  7 qin
  289.   q3    9  8  4 qmo
  290.   q4    8  8  4 qmi
  291. .model qin PNP(Is=800.0E-18 Bf=833.3)
  292. .model qmi NPN(Is=800.0E-18 Bf=1002)
  293. .model qmo NPN(Is=800.0E-18 Bf=1000 Cjc=1E-15 Tr=118.8E-9)
  294.   e1   10  6  9  4  1
  295.   v1   10 11 dc 0
  296.   q5    5 11  6 qoc
  297. .model qoc NPN(Is=800.0E-18 Bf=34.49E3 Cjc=1E-15 Tf=364.6E-12 Tr=79.34E-9)
  298.   dp    4  3 dx
  299.   rp    3  4 6.122E3
  300. .model dx  D(Is=800.0E-18)
  301. *
  302. .ends
  303. *
  304. * End of library file
  305. *
  306. * End of library file
  307.