home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 32 / 64er_Magazin_Sonderheft_32_19xx_Markt__Technik_de_Side_B.d64 / geocheck (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  66 lines
  1. 100 rem ***     geocheck    ***
  2. 110 rem *** florian mueller ***
  3. 120 rem
  4. 130 rem requests check scrap created by geocheck part two
  5. 140 :
  6. 150 clr:dim ib$(256)
  7. 160 printchr$(14)"[147]geo[195]heck     (installiert [199][197][207][211]-[204]istings)"
  8. 170 print"  von   [198]lorian [205]ueller ([205]arkt&[212]echnik)"
  9. 180 print" [193]utor von '[195]64 - [193]lles ueber [199][197][207][211] 1.2'"
  10. 190 print"       und '[195]64 - [199][197][207][211] 1.3 deutsch'"
  11. 200 print" [195]opyright ([195]) 1988 by [210]edaktion 64'er"
  12. 210 print"[194]itte eine [196]iskette mit [208]rogramm  und"
  13. 220 print"'check scrap' einlegen."
  14. 230 print"<shift>":poke653,0:wait653,1:print"[147]"
  15. 240 open1,8,0,"check scrap,p,r"
  16. 250 get#1,fg$,dy$,dm$,dd$,dh$,mi$,b1$,b2$
  17. 251 fg=asc(fg$+chr$(0)):dy=asc(dy$+chr$(0)):dm=asc(dm$+chr$(0))
  18. 252 dd=asc(dd$+chr$(0)):dh=asc(dh$+chr$(0)):mi=asc(mi$+chr$(0))
  19. 253 b1=asc(b1$+chr$(0)):b2=asc(b2$+chr$(0))
  20. 260 print"geos-filetyp #"fg
  21. 270 if fg=5 thenprint"= hilfsmittel (desk accessory)"
  22. 280 if fg=6 thenprint"= anwendung (application)"
  23. 290 if fg=9 thenprint"druckertreiber"
  24. 300 print"datum:"dd"."dm"."1900+dy
  25. 310 print"uhrzeit:"dh"uhr"mi
  26. 320 :
  27. 330 for f=1 to 256:get#1,ib$(f)
  28. 333 if ib$(f)="" then ib$(f)=chr$(0)
  29. 335 next
  30. 340 close1
  31. 350 print"[206]un kann das [200]auptprogramm mit allen"
  32. 360 print"[199][197][207][211]-spezifischen [196]aten versehen werden."
  33. 370 print"[196][193][211] [200][193][213][208][212][208][210][207][199][210][193][205][205][160][205][213][211][211] [211][201][195][200] [201][205][160][196][201][210][197][195][212][207][210][217]"
  34. 380 print"[193][206] [193][204][204][197][210][197][210][211][212][197][210][146] [208][207][211][201][212][201][207][206] [194][197][198][201][206][196][197][206]!"
  35. 390 print"[215]eiter = <[210][197][212][213][210][206]>, <[210][213][206]/[211][212][207][208]> = [193]bbruch"
  36. 400 poke198,0
  37. 410 geta$:ifa$<>chr$(13)then410
  38. 420 print"jetzt wird der info-sektor auf diskette"
  39. 430 print"untergebracht."
  40. 440 open1,8,15,"i":open2,8,2,"#"
  41. 450 it=1:is=0
  42. 460 print#1,"b-a 0";it;is:input#1,a,b$,it,is
  43. 470 if a=0 then it=1:is=0:goto 510
  44. 480 if it=18 then it=19:is=0:print#1,"b-a 0";it;is:input#1,a,b$,it,is
  45. 490 if a=65 and it=0 then print"kein platz fuer info-block":stop
  46. 500 if a=65 then print#1,"b-a 0";it;is
  47. 510 print"info-block kommt auf spur"it"/sektor"is
  48. 520 print#1,"b-p 2 0":for f=1 to 256
  49. 525 if ib$(f)<>"" then print#2,ib$(f);:goto 527
  50. 526 print#2,chr$(0);
  51. 527 next
  52. 530 print#1,"u2:2 0";it;is
  53. 540 print#1,"u1 2 0 18 1"
  54. 550 print#1,"b-p 2 21":print#2,chr$(it);chr$(is);chr$(0);chr$(fg);
  55. 560 print#2,chr$(dy);chr$(dm);chr$(dd);chr$(dh);chr$(mi);
  56. 570 print#1,"u2:2 0 18 1"
  57. 572 print#1,"u1 2 0 17 0":print#1,"b-p 2 2":print#2,chr$(b1);chr$(b2);
  58. 573 print#1,"u2 2 0 17 0"
  59. 580 close1:close2
  60. 590 print"installation fertig. jetzt unter desktop"
  61. 600 print"die funktion 'validate' (aufraeumen)"
  62. 610 print"anwaehlen und die installierte datei"
  63. 620 print"umkopieren."
  64. 630 print"geocheck"
  65. 640 end
  66.