CD-ROM Today - The Disc! 22/cdrt22.iso/pc/bugbook/startup.dir/00002_Script_2

Text File | 1995-06-27 | 5KB | 208 lines

on startMovie
  global homeDir,cdROMDrive,testFile,localDir,cdName

  set the colorDepth = 8

  if not(the machineType=256) then
    global black
    initRearWindow()
    coverDesktop(black)
  end if

  set homeDir=the pathName
  set localDir=the pathName

end startMovie




on quicktimeAvailible
  mci "open cdaudio"
  mci "capability AVIVIDEO has video"
  if (the result) = "TRUE" then
    set returnNum = 1
  else
    set returnNum = 0
  end if
  mci "close cdaudio"
  return returnNum
end quicktimeAvailible



on cdFileExists fileName
  set file = FileIO(mNew, "read",fileName)
  if ((file=-43) or (file=-35)) then
    return FALSE
  else
    file(mDispose)
    return TRUE
  end if
end cdFileExists

on fileExists fileName
  set file = FileIO(mNew, "read",fileName)
  if file=-43 then
    return FALSE
  else
    file(mDispose)
    return TRUE
  end if
end fileExists

on findMyFile testFile
  set asciiIndex=67
  set found=FALSE
  set driveLetter=""
  repeat while ( (asciiIndex < 91) and (not(found)) )

    set findThis=(numToChar(asciiIndex))&":\"&testFile

    if (fileExists(findThis)) then
      set driveLetter=numToChar(asciiIndex)
      set found=TRUE
    end if
    set asciiIndex=asciiIndex+1
  end repeat
  return driveLetter
end findMyFile

on playPuppet soundName
  puppetSound soundName
  updateStage
  repeat while soundBusy(1)
    --
  end repeat
  puppetSound 0
end playPuppet
--------------------------------------------------------------------------------
--               THIS CODE IS FOR THE REAR WINDOW XOBJECT
--                           DO NOT TOUCH
--------------------------------------------------------------------------------

-- RearWindow XObject
-- by David Jackson-Shields
-- vers. 1.0.2 (10/11/93)
--
-- ⌐ 1992-94 by Macromedia, Inc. and David Jackson-Shields
-- All Rights Reserved


on initRearWindow

  global rwObj, gMaxColors, deskTopPattern, black

  set x = the colorDepth

  -- assign maximum index colors for the color depth setting:
  if x >= 8 then set gMaxColors = 255
  if x = 4 then set gMaxColors =  15
  if x = 2 then set gMaxColors =   3
  if x = 1 then set gMaxColors =   0

  -- You must open an external library file if you do not have
  -- the "RearWindow" XCOD resource in the movie using ResEdit:
  if factory( "RearWindow" ) = 0 then
    OpenXLib "RearWindow.XObj"
  end if

  initGlobals
  if objectP( rwObj ) then rwObj( mDispose )
  makeObjIfNeeded

end initRearWindow

--

on releaseRearWindow
  if not(the machineType=256) then

    global rwObj
    if objectP( rwObj ) then
      rwObj( mDispose )
    end if

    -- You must Close the Xlib if you do not have
    -- the XCOD resource installed in the movie with ResEdit:
    CloseXLib
  end if


end releaseRearWindow

--

on initGlobals

  -- these 1-bit pattern values are constantized in this example movie
  -- for use when  calling the coverDesktop handler from button scripts:
  global white, ltGray, gray, dkGray, black, deskTopPattern

  set white   =  -1
  set ltGray  =  -2
  set Gray    =  -3
  set dkGray  =  -4
  set black   =  -5

  -- The Finder Desktop pattern is the default case. To specify the
  -- Finder Desktop, use any negative integer less than -5:

  set deskTopPattern = -99

end initGlobals


-- fills the RearWindow with 1-bit patterns or the DeskTop pattern:

on coverDesktop patVar

  global rwObj
  makeObjIfNeeded
  rwObj( mPatToWindow, patVar )

end coverDesktop

--


on makeObjIfNeeded

  global rwObj
  if not objectP( rwObj ) then

    -- "M" indicates multiple monitors, "S" is for single monitor configuration.
    -- ONLY use "S" if there is not enough room for multiple monitors.
    -- So first...letÆs try it with multiple-monitor configuration:
    set rwObj = RearWindow( mNew, "M" )
    if value( rwObj ) < 0 then
      alert "System error" && rwObj && ¼
            "trying to create the RearWindow object in RAM (multiple-monitor config)."
      stopMovie
      exit
    end if

    if the freeBlock < rwObj( mGetMemoryNeeded ) then
      -- delete the object and create it again with a single-monitor config...
      if objectP( rwObj ) then
        rwObj( mDispose )
        set rwObj = RearWindow( mNew, "S" )
      end if

      if value( rwObj ) < 0 then
        alert "System error" && rwObj && ¼
            "trying to create the RearWindow object in RAM (single-monitor config)."
        stopMovie
        exit
      end if

    end if
  end if

end makeObjIfNeeded



--------------------------------------------------------------------------------
--
--------------------------------------------------------------------------------