home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 4: Demo 1 / almathera_demo1.bin / utils / rippers / sources / jamreplayer.s < prev    next >
Text File  |  1995-03-17  |  10KB  |  554 lines
  1. *
  2. * JamCracker V1.0 Replay routine, written by M. Gemmel
  3. *
  4. * Make sure you have read the ReadMe file on this disk too.
  5. *
  6. * This is not a demonstration source, showing how to write
  7. * a song-play routine.  This source is merely ment for
  8. * inclusion in other sources, or as assembly module for
  9. * linkage with other programs.
  10. *
  11. * This source was modified for the MasterSeka V1.53 assembler
  12. * and can be easily modified for other assemblers. (Not true, it's a lot of work - Arcade)
  13. * The song should be inserted at 'mysong' near the bottom of
  14. * this source, in chip memory.
  15. *
  16. *                  Modified for MasterSeka 1.53 by Arcade of CADCAM
  17. * 
  18. * Note from Arcade: I saved all of you who want to use the replayer
  19. * with MasterSeka a lot of work. So leave this text here, I want the credits.
  20.  
  21. * This is the correct calling procedure
  22. * Don't forget to save any important registers
  23. * because I don't care
  24.  
  25. Start    bsr.s    pp_init            ;First, initialize
  26.  
  27. here    bsr    pp_play            ;Then, play every 1/50 sec.
  28. hi    cmpi.b    #1,$dff006        ;wait for raster
  29.     bne.s    hi
  30.     btst    #6,$bfe001        ;Check left mouse button
  31.     bne.s    here
  32.     bsr    pp_end            ;Finally, stop playing
  33.  
  34.     rts
  35.  
  36. it_name        equ    0
  37. it_flags    equ    31
  38. it_size        equ    32
  39. it_address    equ    36
  40. it_sizeof    equ    40
  41.  
  42. pt_size        equ    0
  43. pt_address    equ    2
  44. pt_sizeof    equ    6
  45.  
  46. nt_period    equ    0
  47. nt_instr    equ    1
  48. nt_speed    equ    2
  49. nt_arpeggio    equ    3
  50. nt_vibrato    equ    4
  51. nt_phase    equ    5
  52. nt_volume    equ    6
  53. nt_porta    equ    7
  54. nt_sizeof    equ    8
  55.  
  56. pv_waveoffset    equ    0
  57. pv_dmacon    equ    2
  58. pv_custbase    equ    4
  59. pv_inslen    equ    8
  60. pv_insaddress    equ    10
  61. pv_peraddress    equ    14
  62. pv_pers        equ    18
  63. pv_por        equ    24
  64. pv_deltapor    equ    26
  65. pv_porlevel    equ    28
  66. pv_vib        equ    30
  67. pv_deltavib    equ    32
  68. pv_vol        equ    34
  69. pv_deltavol    equ    36
  70. pv_vollevel    equ    38
  71. pv_phase    equ    40
  72. pv_deltaphase    equ    42
  73. pv_vibcnt    equ    44
  74. pv_vibmax    equ    45
  75. pv_flags    equ    46
  76. pv_sizeof    equ    48
  77.  
  78. *** This is the actual replay routine
  79.  
  80. wavesize    equ    $40
  81.  
  82. pp_init    lea    mysong,a0
  83.     addq.w    #4,a0
  84.     move.w    (a0)+,d0
  85.     move.w    d0,d1
  86.     move.l    a0,instable
  87.     mulu    #it_sizeof,d0
  88.     adda.w    d0,a0
  89.  
  90.     move.w    (a0)+,d0
  91.     move.w    d0,d2
  92.     move.l    a0,patttable
  93.     mulu    #pt_sizeof,d0
  94.     adda.w    d0,a0
  95.  
  96.     move.w    (a0)+,d0
  97.     move.w    d0,songlen
  98.     move.l    a0,songtable
  99.     lsl.w    #1,d0
  100.     adda.w    d0,a0
  101.  
  102.     movea.l    patttable,a1
  103.     move.w    d2,d0
  104.     subq.w    #1,d0
  105. lab0    move.l    a0,pt_address(a1)
  106.     move.w    pt_size(a1),d3
  107.     mulu    #nt_sizeof*4,d3
  108.     adda.w    d3,a0
  109.     addq.w    #pt_sizeof,a1
  110.     dbf    d0,lab0
  111.  
  112.     movea.l    instable,a1
  113.     move.w    d1,d0
  114.     subq.w    #1,d0
  115. lab1    move.l    a0,it_address(a1)
  116.     move.l    it_size(a1),d2
  117.     adda.l    d2,a0
  118.     adda.w    #it_sizeof,a1
  119.     dbf    d0,lab1
  120.  
  121.  
  122.     move.l    songtable,pp_songptr
  123.     move.w    songlen,pp_songcnt
  124.     movea.l    pp_songptr,a0
  125.     move.w    (a0),d0
  126.     mulu    #pt_sizeof,d0
  127.     add.l    patttable,d0
  128.     movea.l    d0,a0
  129.     move.l    a0,pp_pattentry
  130.     move.b    pt_size+1(a0),pp_notecnt
  131.     move.l    pt_address(a0),pp_address
  132.     move.b    #6,pp_wait
  133.     move.b    #1,pp_waitcnt
  134.     clr.w    pp_nullwave
  135.     move.w    #$000f,$dff096
  136.  
  137.     lea    pp_variables,a0
  138.     lea    $dff0a0,a1
  139.     move.w    #$0001,d1
  140.     move.w    #2*wavesize,d2
  141.     move.w    #3,d0
  142. lab2    clr.w    8(a1)
  143.     move.w    d2,pv_waveoffset(a0)
  144.     move.w    d1,pv_dmacon(a0)
  145.     move.l    a1,pv_custbase(a0)
  146.     move.l    #pp_periods,pv_peraddress(a0)
  147.     move.w    #1019,pv_pers(a0)
  148.     clr.w    pv_pers+2(a0)
  149.     clr.w    pv_pers+4(a0)
  150.     clr.l    pv_por(a0)
  151.     clr.w    pv_porlevel(a0)
  152.     clr.l    pv_vib(a0)
  153.     clr.l    pv_vol(a0)
  154.     move.w    #$0040,pv_vollevel(a0)
  155.     clr.l    pv_phase(a0)
  156.     clr.w    pv_vibcnt(a0)
  157.     clr.b    pv_flags(a0)
  158.     adda.w    #pv_sizeof,a0
  159.     adda.w    #$0010,a1
  160.     lsl.w    #1,d1
  161.     addi.w    #wavesize,d2
  162.     dbf    d0,lab2
  163.     rts
  164.  
  165.  
  166. pp_end    clr.w    $dff0a8
  167.     clr.w    $dff0b8
  168.     clr.w    $dff0c8
  169.     clr.w    $dff0d8
  170.     move.w    #$000f,$dff096
  171.     rts
  172.  
  173.  
  174. pp_play    subq.b    #1,pp_waitcnt
  175.     bne.s    lab3
  176.     bsr    pp_nwnt
  177.     move.b    pp_wait,pp_waitcnt
  178.  
  179. lab3    lea    pp_variables,a1
  180.     bsr.s    pp_uvs
  181.     lea    pp_variables+pv_sizeof,a1
  182.     bsr.s    pp_uvs
  183.     lea    pp_variables+[2*pv_sizeof],a1
  184.     bsr.s    pp_uvs
  185.     lea    pp_variables+[3*pv_sizeof],a1
  186.  
  187.  
  188. pp_uvs    movea.l    pv_custbase(a1),a0
  189.  
  190. lab4    move.w    pv_pers(a1),d0
  191.     bne.s    lab5
  192.     bsr    pp_rot
  193.     bra.s    lab4
  194. lab5    add.w    pv_por(a1),d0
  195.     tst.w    pv_por(a1)
  196.     beq.s    lab5c
  197.     bpl.s    lab5a
  198.     cmp.w    pv_porlevel(a1),d0
  199.     bge.s    lab5c
  200.     bra.s    lab5b
  201. lab5a    cmp.w    pv_porlevel(a1),d0
  202.     ble.s    lab5c
  203. lab5b    move.w    pv_porlevel(a1),d0
  204.  
  205. lab5c    add.w    pv_vib(a1),d0
  206.     cmpi.w    #135,d0
  207.     bge.s    lab5d
  208.     move.w    #135,d0
  209.     bra.s    lab5e
  210. lab5d    cmpi.w    #1019,d0
  211.     ble.s    lab5e
  212.     move.w    #1019,d0
  213. lab5e    move.w    d0,6(a0)
  214.     bsr    pp_rot
  215.  
  216.  
  217.     move.w    pv_deltapor(a1),d0
  218.     add.w    d0,pv_por(a1)
  219.     cmpi.w    #-1019,pv_por(a1)
  220.     bge.s    lab6
  221.     move.w    #-1019,pv_por(a1)
  222.     bra.s    lab7
  223. lab6    cmpi.w    #1019,pv_por(a1)
  224.     ble.s    lab7
  225.     move.w    #1019,pv_por(a1)
  226.  
  227.  
  228. lab7    tst.b    pv_vibcnt(a1)
  229.     beq.s    lab8
  230.     move.w    pv_deltavib(a1),d0
  231.     add.w    d0,pv_vib(a1)
  232.     subq.b    #1,pv_vibcnt(a1)
  233.     bne.s    lab8
  234.     neg.w    pv_deltavib(a1)
  235.     move.b    pv_vibmax(a1),pv_vibcnt(a1)
  236.  
  237.  
  238. lab8    move.w    pv_dmacon(a1),d0
  239.     move.w    pv_vol(a1),8(a0)
  240.     move.w    pv_deltavol(a1),d0
  241.     add.w    d0,pv_vol(a1)
  242.     tst.w    pv_vol(a1)
  243.     bpl.s    lab9
  244.     clr.w    pv_vol(a1)
  245.     bra.s    lab10
  246. lab9    cmpi.w    #$40,pv_vol(a1)
  247.     ble.s    lab10
  248.     move.w    #$40,pv_vol(a1)
  249.  
  250.  
  251. lab10    btst    #1,pv_flags(a1)
  252.     beq.s    lab12
  253.     movea.l    pv_insaddress(a1),a0
  254.     move.w    pv_waveoffset(a1),d0
  255.     neg.w    d0
  256.     lea    0(a0,d0.w),a2
  257.     movea.l    a2,a3
  258.     move.w    pv_phase(a1),d0
  259.     lsr.w    #2,d0
  260.     adda.w    d0,a3
  261.  
  262.     move.w    #wavesize-1,d0
  263. lab11    move.b    (a2)+,d1
  264.     ext.w    d1
  265.     move.b    (a3)+,d2
  266.     ext.w    d2
  267.     add.w    d1,d2
  268.     asr.w    #1,d2
  269.     move.b    d2,(a0)+
  270.     dbf    d0,lab11
  271.  
  272.     move.w    pv_deltaphase(a1),d0
  273.     add.w    d0,pv_phase(a1)
  274.     cmpi.w    #wavesize*4,pv_phase(a1)
  275.     blt.s    lab12
  276.     subi.w    #wavesize*4,pv_phase(a1)
  277.  
  278. lab12    rts
  279.  
  280.  
  281. pp_rot    move.w    pv_pers(a1),d0
  282.     move.w    pv_pers+2(a1),pv_pers(a1)
  283.     move.w    pv_pers+4(a1),pv_pers+2(a1)
  284.     move.w    d0,pv_pers+4(a1)
  285.     rts
  286.  
  287.  
  288. pp_nwnt    movea.l    pp_address,a0
  289.     addi.l    #4*nt_sizeof,pp_address
  290.     subq.b    #1,pp_notecnt
  291.     bne.s    lab15
  292.  
  293. lab13    addq.l    #2,pp_songptr
  294.     subq.w    #1,pp_songcnt
  295.     bne.s    lab14
  296.     move.l    songtable,pp_songptr
  297.     move.w    songlen,pp_songcnt
  298. lab14    movea.l    pp_songptr,a1
  299.     move.w    (a1),d0
  300.     mulu    #pt_sizeof,d0
  301.     add.l    patttable,d0
  302.     movea.l    d0,a1
  303.     move.b    pt_size+1(a1),pp_notecnt
  304.     move.l    pt_address(a1),pp_address
  305.  
  306.  
  307. lab15    clr.w    pp_tmpdmacon
  308.     lea    pp_variables,a1
  309.     bsr    pp_nnt
  310.     addq.w    #nt_sizeof,a0
  311.     lea    pp_variables+pv_sizeof,a1
  312.     bsr    pp_nnt
  313.     addq.w    #nt_sizeof,a0
  314.     lea    pp_variables+[2*pv_sizeof],a1
  315.     bsr    pp_nnt
  316.     addq.w    #nt_sizeof,a0
  317.     lea    pp_variables+[3*pv_sizeof],a1
  318.     bsr    pp_nnt
  319.  
  320.  
  321.     move.w    pp_tmpdmacon,$dff096
  322.     move.w    #300,d0
  323. lab16    dbf    d0,lab16
  324.  
  325.     lea    pp_variables,a1
  326.     bsr    pp_scr
  327.     lea    pp_variables+pv_sizeof,a1
  328.     bsr.s    pp_scr
  329.     lea    pp_variables+[2*pv_sizeof],a1
  330.     bsr.s    pp_scr
  331.     lea    pp_variables+[3*pv_sizeof],a1
  332.     bsr.s    pp_scr
  333.  
  334.     bset    #7,pp_tmpdmacon
  335.     move.w    pp_tmpdmacon,$dff096
  336.     move.w    #300,d0
  337. lab17    dbf    d0,lab17
  338.  
  339.  
  340.     move.l    pp_variables+pv_insaddress,$dff0a0
  341.     move.w    pp_variables+pv_inslen,$dff0a4
  342.     move.l    pp_variables+pv_sizeof+pv_insaddress,$dff0b0
  343.     move.w    pp_variables+pv_sizeof+pv_inslen,$dff0b4
  344.     move.l    pp_variables+[2*pv_sizeof]+pv_insaddress,$dff0c0
  345.     move.w    pp_variables+[2*pv_sizeof]+pv_inslen,$dff0c4
  346.     move.l    pp_variables+[3*pv_sizeof]+pv_insaddress,$dff0d0
  347.     move.w    pp_variables+[3*pv_sizeof]+pv_inslen,$dff0d4
  348.  
  349.     rts
  350.  
  351.  
  352. pp_scr    move.w    pp_tmpdmacon,d0
  353.     and.w    pv_dmacon(a1),d0
  354.     beq.s    lab18
  355.  
  356.     movea.l    pv_custbase(a1),a0
  357.     move.l    pv_insaddress(a1),(a0)
  358.     move.w    pv_inslen(a1),4(a0)
  359.     move.w    pv_pers(a1),6(a0)
  360.     btst    #0,pv_flags(a1)
  361.     bne.s    lab18
  362.     move.l    #pp_nullwave,pv_insaddress(a1)
  363.     move.w    #1,pv_inslen(a1)
  364.  
  365. lab18    rts
  366.  
  367.  
  368. pp_nnt    move.b    nt_period(a0),d1
  369.     beq    lab22
  370.  
  371.     andi.l    #$000000ff,d1
  372.     lsl.w    #1,d1
  373.     addi.l    #pp_periods-2,d1
  374.     movea.l    d1,a2
  375.  
  376.     btst    #6,nt_speed(a0)
  377.     beq.s    lab21
  378.     move.w    (a2),pv_porlevel(a1)
  379.     bra    lab22
  380.  
  381.  
  382. lab21    move.w    pv_dmacon(a1),d0
  383.     or.w    d0,pp_tmpdmacon
  384.  
  385.     move.l    a2,pv_peraddress(a1)
  386.     move.w    (a2),pv_pers(a1)
  387.     move.w    (a2),pv_pers+2(a1)
  388.     move.w    (a2),pv_pers+4(a1)
  389.  
  390.     clr.w    pv_por(a1)
  391.  
  392.     move.b    nt_instr(a0),d0
  393.     ext.w    d0
  394.     mulu    #it_sizeof,d0
  395.     add.l    instable,d0
  396.     movea.l    d0,a2
  397.     tst.l    it_address(a2)
  398.     bne.s    lab20
  399.     move.l    #pp_nullwave,pv_insaddress(a1)
  400.     move.w    #1,pv_inslen(a1)
  401.     clr.b    pv_flags(a1)
  402.     bra.s    lab22
  403.  
  404. lab20    movea.l    it_address(a2),a3
  405.     btst    #1,it_flags(a2)
  406.     bne.s    lab19a
  407.     move.l    it_size(a2),d0
  408.     lsr.l    #1,d0
  409.     move.w    d0,pv_inslen(a1)
  410.     bra.s    lab19
  411. lab19a    move.w    pv_waveoffset(a1),d0
  412.     adda.w    d0,a3
  413.     move.w    #wavesize/2,pv_inslen(a1)
  414. lab19    move.l    a3,pv_insaddress(a1)
  415.     move.b    it_flags(a2),pv_flags(a1)
  416.     move.w    pv_vollevel(a1),pv_vol(a1)
  417.  
  418.  
  419. lab22    move.b    nt_speed(a0),d0
  420.     andi.b    #$0f,d0
  421.     beq.s    lab23
  422.     move.b    d0,pp_wait
  423.  
  424.  
  425. lab23    movea.l    pv_peraddress(a1),a2
  426.     move.b    nt_arpeggio(a0),d0
  427.     beq.s    lab25
  428.     cmpi.b    #$ff,d0
  429.     bne.s    lab24
  430.     move.w    (a2),pv_pers(a1)
  431.     move.w    (a2),pv_pers+2(a1)
  432.     move.w    (a2),pv_pers+4(a1)
  433.     bra.s    lab25
  434. lab24    andi.b    #$0f,d0
  435.     lsl.b    #1,d0
  436.     ext.w    d0
  437.     move.w    0(a2,d0.w),pv_pers+4(a1)
  438.     move.b    nt_arpeggio(a0),d0
  439.     lsr.b    #4,d0
  440.     lsl.b    #1,d0
  441.     ext.w    d0
  442.     move.w    0(a2,d0.w),pv_pers+2(a1)
  443.     move.w    (a2),pv_pers(a1)
  444.  
  445.  
  446. lab25    move.b    nt_vibrato(a0),d0
  447.     beq.s    lab27
  448.     cmpi.b    #$ff,d0
  449.     bne.s    lab26
  450.     clr.l    pv_vib(a1)
  451.     clr.b    pv_vibcnt(a1)
  452.     bra.s    lab27
  453. lab26    clr.w    pv_vib(a1)
  454.     andi.b    #$0f,d0
  455.     ext.w    d0
  456.     move.w    d0,pv_deltavib(a1)
  457.     move.b    nt_vibrato(a0),d0
  458.     lsr.b    #4,d0
  459.     move.b    d0,pv_vibmax(a1)
  460.     lsr.b    #1,d0
  461.     move.b    d0,pv_vibcnt(a1)
  462.  
  463.  
  464. lab27    move.b    nt_phase(a0),d0
  465.     beq.s    lab29
  466.     cmpi.b    #$ff,d0
  467.     bne.s    lab28
  468.     clr.l    pv_phase(a1)
  469.     bra.s    lab29
  470. lab28    andi.b    #$0f,d0
  471.     ext.w    d0
  472.     move.w    d0,pv_deltaphase(a1)
  473.     clr.w    pv_phase(a1)
  474.  
  475.  
  476. lab29    move.b    nt_volume(a0),d0
  477.     bne.s    lab29a
  478.     btst    #7,nt_speed(a0)
  479.     beq.s    lab33
  480.     bra.s    lab30a
  481. lab29a    cmpi.b    #$ff,d0
  482.     bne.s    lab30
  483.     clr.w    pv_deltavol(a1)
  484.     bra.s    lab33
  485. lab30    btst    #7,nt_speed(a0)
  486.     beq.s    lab31
  487. lab30a    move.b    d0,pv_vol+1(a1)
  488.     move.b    d0,pv_vollevel+1(a1)
  489.     clr.w    pv_deltavol(a1)
  490.     bra.s    lab33
  491. lab31    bclr    #7,d0
  492.     beq.s    lab32
  493.     neg.b    d0
  494. lab32    ext.w    d0
  495.     move.w    d0,pv_deltavol(a1)
  496.  
  497.  
  498. lab33    move.b    nt_porta(a0),d0
  499.     beq.s    lab36
  500.     cmpi.b    #$ff,d0
  501.     bne.s    lab34
  502.     clr.l    pv_por(a1)
  503.     bra.s    lab36
  504. lab34    clr.w    pv_por(a1)
  505.     btst    #6,nt_speed(a0)
  506.     beq.s    lab34a
  507.     move.w    pv_porlevel(a1),d1
  508.     cmp.w    pv_pers(a1),d1
  509.     bgt.s    lab34c
  510.     neg.b    d0
  511.     bra.s    lab34c
  512. lab34a    bclr    #7,d0
  513.     bne.s    lab35
  514.     neg.b    d0
  515.     move.w    #135,pv_porlevel(a1)
  516.     bra.s    lab34c
  517. lab35    move.w    #1019,pv_porlevel(a1)
  518. lab34c    ext.w    d0
  519. lab35a    move.w    d0,pv_deltapor(a1)
  520.  
  521.  
  522. lab36    rts
  523.  
  524.  
  525. * Replayer data
  526.  
  527. pp_periods    dc.w    1019,962,908,857,809,763,720,680,642,606,572,540
  528.         dc.w    509,481,454,428,404,381,360,340,321,303,286,270
  529.         dc.w    254,240,227,214,202,190,180,170,160,151,143,135
  530.         dc.w    135,135,135,135,135,135,135,135,135
  531.         dc.w    135,135,135,135,135,135
  532.  
  533. mysong        Incbin    "ST-00:Songs/DemoSong4"    ;Insert your song here!
  534.  
  535. songlen        ds.w    1
  536. songtable    ds.l    1
  537. instable    ds.l    1
  538. patttable    ds.l    1
  539.  
  540. pp_wait        ds.b    1
  541. pp_waitcnt    ds.b    1
  542. pp_notecnt    ds.b    1
  543.  
  544.         even
  545. pp_address    ds.l    1
  546. pp_songptr    ds.l    1
  547. pp_songcnt    ds.w    1
  548. pp_pattentry    ds.l    1
  549. pp_tmpdmacon    ds.w    1
  550. pp_variables    ds.b    4*48
  551.  
  552. pp_nullwave    ds.w    1
  553.  
  554.