home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / eispack-1.0-src.tgz / tar.out / contrib / eispack / combak.f < prev    next >
Text File  |  1996-09-28  |  3KB  |  90 lines
  1.       subroutine combak(nm,low,igh,ar,ai,int,m,zr,zi)
  2. c
  3.       integer i,j,m,la,mm,mp,nm,igh,kp1,low,mp1
  4.       double precision ar(nm,igh),ai(nm,igh),zr(nm,m),zi(nm,m)
  5.       double precision xr,xi
  6.       integer int(igh)
  7. c
  8. c     this subroutine is a translation of the algol procedure combak,
  9. c     num. math. 12, 349-368(1968) by martin and wilkinson.
  10. c     handbook for auto. comp., vol.ii-linear algebra, 339-358(1971).
  11. c
  12. c     this subroutine forms the eigenvectors of a complex general
  13. c     matrix by back transforming those of the corresponding
  14. c     upper hessenberg matrix determined by  comhes.
  15. c
  16. c     on input
  17. c
  18. c        nm must be set to the row dimension of two-dimensional
  19. c          array parameters as declared in the calling program
  20. c          dimension statement.
  21. c
  22. c        low and igh are integers determined by the balancing
  23. c          subroutine  cbal.  if  cbal  has not been used,
  24. c          set low=1 and igh equal to the order of the matrix.
  25. c
  26. c        ar and ai contain the multipliers which were used in the
  27. c          reduction by  comhes  in their lower triangles
  28. c          below the subdiagonal.
  29. c
  30. c        int contains information on the rows and columns
  31. c          interchanged in the reduction by  comhes.
  32. c          only elements low through igh are used.
  33. c
  34. c        m is the number of eigenvectors to be back transformed.
  35. c
  36. c        zr and zi contain the real and imaginary parts,
  37. c          respectively, of the eigenvectors to be
  38. c          back transformed in their first m columns.
  39. c
  40. c     on output
  41. c
  42. c        zr and zi contain the real and imaginary parts,
  43. c          respectively, of the transformed eigenvectors
  44. c          in their first m columns.
  45. c
  46. c     questions and comments should be directed to burton s. garbow,
  47. c     mathematics and computer science div, argonne national laboratory
  48. c
  49. c     this version dated august 1983.
  50. c
  51. c     ------------------------------------------------------------------
  52. c
  53.       if (m .eq. 0) go to 200
  54.       la = igh - 1
  55.       kp1 = low + 1
  56.       if (la .lt. kp1) go to 200
  57. c     .......... for mp=igh-1 step -1 until low+1 do -- ..........
  58.       do 140 mm = kp1, la
  59.          mp = low + igh - mm
  60.          mp1 = mp + 1
  61. c
  62.          do 110 i = mp1, igh
  63.             xr = ar(i,mp-1)
  64.             xi = ai(i,mp-1)
  65.             if (xr .eq. 0.0d0 .and. xi .eq. 0.0d0) go to 110
  66. c
  67.             do 100 j = 1, m
  68.                zr(i,j) = zr(i,j) + xr * zr(mp,j) - xi * zi(mp,j)
  69.                zi(i,j) = zi(i,j) + xr * zi(mp,j) + xi * zr(mp,j)
  70.   100       continue
  71. c
  72.   110    continue
  73. c
  74.          i = int(mp)
  75.          if (i .eq. mp) go to 140
  76. c
  77.          do 130 j = 1, m
  78.             xr = zr(i,j)
  79.             zr(i,j) = zr(mp,j)
  80.             zr(mp,j) = xr
  81.             xi = zi(i,j)
  82.             zi(i,j) = zi(mp,j)
  83.             zi(mp,j) = xi
  84.   130    continue
  85. c
  86.   140 continue
  87. c
  88.   200 return
  89.       end
  90.