home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / eispack-1.0-src.tgz / tar.out / contrib / eispack / cortb.f < prev    next >
Text File  |  1996-09-28  |  3KB  |  99 lines
  1.       subroutine cortb(nm,low,igh,ar,ai,ortr,orti,m,zr,zi)
  2. c
  3.       integer i,j,m,la,mm,mp,nm,igh,kp1,low,mp1
  4.       double precision ar(nm,igh),ai(nm,igh),ortr(igh),orti(igh),
  5.      x       zr(nm,m),zi(nm,m)
  6.       double precision h,gi,gr
  7. c
  8. c     this subroutine is a translation of a complex analogue of
  9. c     the algol procedure ortbak, num. math. 12, 349-368(1968)
  10. c     by martin and wilkinson.
  11. c     handbook for auto. comp., vol.ii-linear algebra, 339-358(1971).
  12. c
  13. c     this subroutine forms the eigenvectors of a complex general
  14. c     matrix by back transforming those of the corresponding
  15. c     upper hessenberg matrix determined by  corth.
  16. c
  17. c     on input
  18. c
  19. c        nm must be set to the row dimension of two-dimensional
  20. c          array parameters as declared in the calling program
  21. c          dimension statement.
  22. c
  23. c        low and igh are integers determined by the balancing
  24. c          subroutine  cbal.  if  cbal  has not been used,
  25. c          set low=1 and igh equal to the order of the matrix.
  26. c
  27. c        ar and ai contain information about the unitary
  28. c          transformations used in the reduction by  corth
  29. c          in their strict lower triangles.
  30. c
  31. c        ortr and orti contain further information about the
  32. c          transformations used in the reduction by  corth.
  33. c          only elements low through igh are used.
  34. c
  35. c        m is the number of columns of zr and zi to be back transformed.
  36. c
  37. c        zr and zi contain the real and imaginary parts,
  38. c          respectively, of the eigenvectors to be
  39. c          back transformed in their first m columns.
  40. c
  41. c     on output
  42. c
  43. c        zr and zi contain the real and imaginary parts,
  44. c          respectively, of the transformed eigenvectors
  45. c          in their first m columns.
  46. c
  47. c        ortr and orti have been altered.
  48. c
  49. c     note that cortb preserves vector euclidean norms.
  50. c
  51. c     questions and comments should be directed to burton s. garbow,
  52. c     mathematics and computer science div, argonne national laboratory
  53. c
  54. c     this version dated august 1983.
  55. c
  56. c     ------------------------------------------------------------------
  57. c
  58.       if (m .eq. 0) go to 200
  59.       la = igh - 1
  60.       kp1 = low + 1
  61.       if (la .lt. kp1) go to 200
  62. c     .......... for mp=igh-1 step -1 until low+1 do -- ..........
  63.       do 140 mm = kp1, la
  64.          mp = low + igh - mm
  65.          if (ar(mp,mp-1) .eq. 0.0d0 .and. ai(mp,mp-1) .eq. 0.0d0)
  66.      x      go to 140
  67. c     .......... h below is negative of h formed in corth ..........
  68.          h = ar(mp,mp-1) * ortr(mp) + ai(mp,mp-1) * orti(mp)
  69.          mp1 = mp + 1
  70. c
  71.          do 100 i = mp1, igh
  72.             ortr(i) = ar(i,mp-1)
  73.             orti(i) = ai(i,mp-1)
  74.   100    continue
  75. c
  76.          do 130 j = 1, m
  77.             gr = 0.0d0
  78.             gi = 0.0d0
  79. c
  80.             do 110 i = mp, igh
  81.                gr = gr + ortr(i) * zr(i,j) + orti(i) * zi(i,j)
  82.                gi = gi + ortr(i) * zi(i,j) - orti(i) * zr(i,j)
  83.   110       continue
  84. c
  85.             gr = gr / h
  86.             gi = gi / h
  87. c
  88.             do 120 i = mp, igh
  89.                zr(i,j) = zr(i,j) + gr * ortr(i) - gi * orti(i)
  90.                zi(i,j) = zi(i,j) + gr * orti(i) + gi * ortr(i)
  91.   120       continue
  92. c
  93.   130    continue
  94. c
  95.   140 continue
  96. c
  97.   200 return
  98.       end
  99.