home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / eispack-1.0-src.tgz / tar.out / contrib / eispack / corth.f < prev    next >
Text File  |  1996-09-28  |  4KB  |  135 lines
  1.       subroutine corth(nm,n,low,igh,ar,ai,ortr,orti)
  2. c
  3.       integer i,j,m,n,ii,jj,la,mp,nm,igh,kp1,low
  4.       double precision ar(nm,n),ai(nm,n),ortr(igh),orti(igh)
  5.       double precision f,g,h,fi,fr,scale,pythag
  6. c
  7. c     this subroutine is a translation of a complex analogue of
  8. c     the algol procedure orthes, num. math. 12, 349-368(1968)
  9. c     by martin and wilkinson.
  10. c     handbook for auto. comp., vol.ii-linear algebra, 339-358(1971).
  11. c
  12. c     given a complex general matrix, this subroutine
  13. c     reduces a submatrix situated in rows and columns
  14. c     low through igh to upper hessenberg form by
  15. c     unitary similarity transformations.
  16. c
  17. c     on input
  18. c
  19. c        nm must be set to the row dimension of two-dimensional
  20. c          array parameters as declared in the calling program
  21. c          dimension statement.
  22. c
  23. c        n is the order of the matrix.
  24. c
  25. c        low and igh are integers determined by the balancing
  26. c          subroutine  cbal.  if  cbal  has not been used,
  27. c          set low=1, igh=n.
  28. c
  29. c        ar and ai contain the real and imaginary parts,
  30. c          respectively, of the complex input matrix.
  31. c
  32. c     on output
  33. c
  34. c        ar and ai contain the real and imaginary parts,
  35. c          respectively, of the hessenberg matrix.  information
  36. c          about the unitary transformations used in the reduction
  37. c          is stored in the remaining triangles under the
  38. c          hessenberg matrix.
  39. c
  40. c        ortr and orti contain further information about the
  41. c          transformations.  only elements low through igh are used.
  42. c
  43. c     calls pythag for  dsqrt(a*a + b*b) .
  44. c
  45. c     questions and comments should be directed to burton s. garbow,
  46. c     mathematics and computer science div, argonne national laboratory
  47. c
  48. c     this version dated august 1983.
  49. c
  50. c     ------------------------------------------------------------------
  51. c
  52.       la = igh - 1
  53.       kp1 = low + 1
  54.       if (la .lt. kp1) go to 200
  55. c
  56.       do 180 m = kp1, la
  57.          h = 0.0d0
  58.          ortr(m) = 0.0d0
  59.          orti(m) = 0.0d0
  60.          scale = 0.0d0
  61. c     .......... scale column (algol tol then not needed) ..........
  62.          do 90 i = m, igh
  63.    90    scale = scale + dabs(ar(i,m-1)) + dabs(ai(i,m-1))
  64. c
  65.          if (scale .eq. 0.0d0) go to 180
  66.          mp = m + igh
  67. c     .......... for i=igh step -1 until m do -- ..........
  68.          do 100 ii = m, igh
  69.             i = mp - ii
  70.             ortr(i) = ar(i,m-1) / scale
  71.             orti(i) = ai(i,m-1) / scale
  72.             h = h + ortr(i) * ortr(i) + orti(i) * orti(i)
  73.   100    continue
  74. c
  75.          g = dsqrt(h)
  76.          f = pythag(ortr(m),orti(m))
  77.          if (f .eq. 0.0d0) go to 103
  78.          h = h + f * g
  79.          g = g / f
  80.          ortr(m) = (1.0d0 + g) * ortr(m)
  81.          orti(m) = (1.0d0 + g) * orti(m)
  82.          go to 105
  83. c
  84.   103    ortr(m) = g
  85.          ar(m,m-1) = scale
  86. c     .......... form (i-(u*ut)/h) * a ..........
  87.   105    do 130 j = m, n
  88.             fr = 0.0d0
  89.             fi = 0.0d0
  90. c     .......... for i=igh step -1 until m do -- ..........
  91.             do 110 ii = m, igh
  92.                i = mp - ii
  93.                fr = fr + ortr(i) * ar(i,j) + orti(i) * ai(i,j)
  94.                fi = fi + ortr(i) * ai(i,j) - orti(i) * ar(i,j)
  95.   110       continue
  96. c
  97.             fr = fr / h
  98.             fi = fi / h
  99. c
  100.             do 120 i = m, igh
  101.                ar(i,j) = ar(i,j) - fr * ortr(i) + fi * orti(i)
  102.                ai(i,j) = ai(i,j) - fr * orti(i) - fi * ortr(i)
  103.   120       continue
  104. c
  105.   130    continue
  106. c     .......... form (i-(u*ut)/h)*a*(i-(u*ut)/h) ..........
  107.          do 160 i = 1, igh
  108.             fr = 0.0d0
  109.             fi = 0.0d0
  110. c     .......... for j=igh step -1 until m do -- ..........
  111.             do 140 jj = m, igh
  112.                j = mp - jj
  113.                fr = fr + ortr(j) * ar(i,j) - orti(j) * ai(i,j)
  114.                fi = fi + ortr(j) * ai(i,j) + orti(j) * ar(i,j)
  115.   140       continue
  116. c
  117.             fr = fr / h
  118.             fi = fi / h
  119. c
  120.             do 150 j = m, igh
  121.                ar(i,j) = ar(i,j) - fr * ortr(j) - fi * orti(j)
  122.                ai(i,j) = ai(i,j) + fr * orti(j) - fi * ortr(j)
  123.   150       continue
  124. c
  125.   160    continue
  126. c
  127.          ortr(m) = scale * ortr(m)
  128.          orti(m) = scale * orti(m)
  129.          ar(m,m-1) = -g * ar(m,m-1)
  130.          ai(m,m-1) = -g * ai(m,m-1)
  131.   180 continue
  132. c
  133.   200 return
  134.       end
  135.