home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / gnat-2.06-src.tgz / tar.out / fsf / gnat / ada / lib-sort.adb < prev    next >
Text File  |  1996-09-28  |  6KB  |  145 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT COMPILER COMPONENTS                         --
  4. --                                                                          --
  5. --                             L I B . S O R T                              --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.8 $                              --
  10. --                                                                          --
  11. --           Copyright (c) 1992,1993,1994 NYU, All Rights Reserved          --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. --
  22. --                                                                          --
  23. ------------------------------------------------------------------------------
  24.  
  25. --  The algorithm used for the sort here is Floyd's Treesort3, called
  26. --  heap sort by Knuth in Art of Programming, with an optimization
  27. --  mentioned in a Knuth excercise and described and analyzed in detail
  28. --  in Dewar's Phd Thesis ("The Use of Computers to Solve the X-Ray
  29. --  Phase Problem", University of Chicago, 1968).
  30.  
  31. --  Definition: a heap is a tree structure in which every node has a value
  32. --  greater than or equal to its children (or child for a node that has
  33. --  only one child). A leaf node is always considered to be a heap.
  34.  
  35. --  Mapping: the array represents a binary tree, in which (assuming ones
  36. --  origin node numbering for a moment), the left son has a subscript equal
  37. --  to 2 * the parent subscript, and the right son has a subscript equal
  38. --  to the left son subscript plus one.
  39.  
  40. separate (Lib)
  41. procedure Sort (Tbl : in out Unit_Ref_Table) is
  42.  
  43.    T : Unit_Ref_Table (1 .. Tbl'Last - Tbl'First + 1);
  44.    --  Actual sort is done on this copy of the array with 1's origin
  45.    --  subscripts. The addressing of the table is much neater with 1's origin,
  46.    --  and it is cheaper to do an in-out copy than to fiddle with a low bound
  47.    --  that is othr than 1.
  48.  
  49.    Num : Nat := T'Last;
  50.    --  Number of elements in array. Gets reduced during second phase.
  51.  
  52.    Hole_Value : Unit_Number_Type;
  53.    --  Value proposed for placing in Hole
  54.  
  55.    procedure Heapify (N : Pos);
  56.    --  Make the subtree starting at node N into a heap by rearranging nodes
  57.    --  in the subtree as needed. The input assumption is that the subtrees
  58.    --  rooted at the children of the given node are already in heap form.
  59.    --  The given node must have at least one child. Before the call, the
  60.    --  caller moves the value of T(N) into Hole_Value.
  61.  
  62.    procedure Heapify (N : Pos) is
  63.       Hole : Pos;
  64.       --  Location in the tree of hole that needs to be filled by Heapify
  65.  
  66.       Son : Pos;
  67.       --  Location of larger son of hole position
  68.  
  69.       Father : Int;
  70.       --  Location of parent of hold on way back up
  71.  
  72.    begin
  73.       Hole := N;
  74.  
  75.       --  This loop moves the hole down the tree, pulling up the larger of
  76.       --  the two sons, and terminates at the bottom of the tree.
  77.  
  78.       loop
  79.          Son := Hole + Hole;
  80.          exit when Son > Num;
  81.  
  82.          if Son < Num
  83.            and then Uname_Gt (Units.Table (T (Son + 1)).Unit_Name,
  84.                               Units.Table (T (Son)).Unit_Name)
  85.          then
  86.             Son := Son + 1;
  87.          end if;
  88.  
  89.          T (Hole) := T (Son);
  90.          Hole := Son;
  91.       end loop;
  92.  
  93.       --  On exit from the loop, the hole is at the bottom of the tree, and
  94.       --  we must check successive fathers until we find one that is large
  95.       --  enough, smaller fathers get dragged back down.
  96.  
  97.       loop
  98.          Father := Hole / 2;
  99.  
  100.          exit when Father < N
  101.            or else Uname_Ge (Units.Table (T (Father)).Unit_Name,
  102.                              Units.Table (Hole_Value).Unit_Name);
  103.          T (Hole) := T (Father);
  104.          Hole := Father;
  105.       end loop;
  106.  
  107.       --  On exit from the second loop, the Hole is ready to be filled in
  108.  
  109.       T (Hole) := Hole_Value;
  110.    end Heapify;
  111.  
  112. --  Start of processing for Sort
  113.  
  114. begin
  115.    for I in T'Range loop
  116.       T (I) := Tbl (I - 1 + Tbl'First);
  117.    end loop;
  118.  
  119.    --  First phase of the sort converts the tree to a heap, by heapifying
  120.    --  nodes Num/2, (Num/2 - 1), (Num/2 - 2) etc. in sequence
  121.  
  122.    for J in reverse 1 .. Num / 2 loop
  123.       Hole_Value := T (J);
  124.       Heapify (J);
  125.    end loop;
  126.  
  127.    --  At this stage of sort, the root node is the largest node. Repeatedly
  128.    --  exchange it with the last node in the array, reduce the size of the
  129.    --  array, and re-heapify the tree from the root node.
  130.  
  131.    while Num > 1 loop
  132.       Hole_Value := T (Num);
  133.       T (Num) := T (1);
  134.       Num := Num - 1;
  135.       Heapify (1);
  136.    end loop;
  137.  
  138.    --  Sort is complete, copy result back into place
  139.  
  140.    for I in T'Range loop
  141.       Tbl (I - 1 + Tbl'First) := T (I);
  142.    end loop;
  143.  
  144. end Sort;
  145.