home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / octave-1.1.1p1-src.tgz / tar.out / fsf / octave / libcruft / blas / dtrmm.f < prev    next >
Text File  |  1996-09-28  |  12KB  |  359 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE DTRMM ( SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA,
  5.      $                   B, LDB )
  6. *     .. Scalar Arguments ..
  7.       CHARACTER*1        SIDE, UPLO, TRANSA, DIAG
  8.       INTEGER            M, N, LDA, LDB
  9.       DOUBLE PRECISION   ALPHA
  10. *     .. Array Arguments ..
  11.       DOUBLE PRECISION   A( LDA, * ), B( LDB, * )
  12. *     ..
  13. *
  14. *  Purpose
  15. *  =======
  16. *
  17. *  DTRMM  performs one of the matrix-matrix operations
  18. *
  19. *     B := alpha*op( A )*B,   or   B := alpha*B*op( A ),
  20. *
  21. *  where  alpha  is a scalar,  B  is an m by n matrix,  A  is a unit, or
  22. *  non-unit,  upper or lower triangular matrix  and  op( A )  is one  of
  23. *
  24. *     op( A ) = A   or   op( A ) = A'.
  25. *
  26. *  Parameters
  27. *  ==========
  28. *
  29. *  SIDE   - CHARACTER*1.
  30. *           On entry,  SIDE specifies whether  op( A ) multiplies B from
  31. *           the left or right as follows:
  32. *
  33. *              SIDE = 'L' or 'l'   B := alpha*op( A )*B.
  34. *
  35. *              SIDE = 'R' or 'r'   B := alpha*B*op( A ).
  36. *
  37. *           Unchanged on exit.
  38. *
  39. *  UPLO   - CHARACTER*1.
  40. *           On entry, UPLO specifies whether the matrix A is an upper or
  41. *           lower triangular matrix as follows:
  42. *
  43. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  44. *
  45. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  46. *
  47. *           Unchanged on exit.
  48. *
  49. *  TRANSA - CHARACTER*1.
  50. *           On entry, TRANSA specifies the form of op( A ) to be used in
  51. *           the matrix multiplication as follows:
  52. *
  53. *              TRANSA = 'N' or 'n'   op( A ) = A.
  54. *
  55. *              TRANSA = 'T' or 't'   op( A ) = A'.
  56. *
  57. *              TRANSA = 'C' or 'c'   op( A ) = A'.
  58. *
  59. *           Unchanged on exit.
  60. *
  61. *  DIAG   - CHARACTER*1.
  62. *           On entry, DIAG specifies whether or not A is unit triangular
  63. *           as follows:
  64. *
  65. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  66. *
  67. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  68. *                                  triangular.
  69. *
  70. *           Unchanged on exit.
  71. *
  72. *  M      - INTEGER.
  73. *           On entry, M specifies the number of rows of B. M must be at
  74. *           least zero.
  75. *           Unchanged on exit.
  76. *
  77. *  N      - INTEGER.
  78. *           On entry, N specifies the number of columns of B.  N must be
  79. *           at least zero.
  80. *           Unchanged on exit.
  81. *
  82. *  ALPHA  - DOUBLE PRECISION.
  83. *           On entry,  ALPHA specifies the scalar  alpha. When  alpha is
  84. *           zero then  A is not referenced and  B need not be set before
  85. *           entry.
  86. *           Unchanged on exit.
  87. *
  88. *  A      - DOUBLE PRECISION array of DIMENSION ( LDA, k ), where k is m
  89. *           when  SIDE = 'L' or 'l'  and is  n  when  SIDE = 'R' or 'r'.
  90. *           Before entry  with  UPLO = 'U' or 'u',  the  leading  k by k
  91. *           upper triangular part of the array  A must contain the upper
  92. *           triangular matrix  and the strictly lower triangular part of
  93. *           A is not referenced.
  94. *           Before entry  with  UPLO = 'L' or 'l',  the  leading  k by k
  95. *           lower triangular part of the array  A must contain the lower
  96. *           triangular matrix  and the strictly upper triangular part of
  97. *           A is not referenced.
  98. *           Note that when  DIAG = 'U' or 'u',  the diagonal elements of
  99. *           A  are not referenced either,  but are assumed to be  unity.
  100. *           Unchanged on exit.
  101. *
  102. *  LDA    - INTEGER.
  103. *           On entry, LDA specifies the first dimension of A as declared
  104. *           in the calling (sub) program.  When  SIDE = 'L' or 'l'  then
  105. *           LDA  must be at least  max( 1, m ),  when  SIDE = 'R' or 'r'
  106. *           then LDA must be at least max( 1, n ).
  107. *           Unchanged on exit.
  108. *
  109. *  B      - DOUBLE PRECISION array of DIMENSION ( LDB, n ).
  110. *           Before entry,  the leading  m by n part of the array  B must
  111. *           contain the matrix  B,  and  on exit  is overwritten  by the
  112. *           transformed matrix.
  113. *
  114. *  LDB    - INTEGER.
  115. *           On entry, LDB specifies the first dimension of B as declared
  116. *           in  the  calling  (sub)  program.   LDB  must  be  at  least
  117. *           max( 1, m ).
  118. *           Unchanged on exit.
  119. *
  120. *
  121. *  Level 3 Blas routine.
  122. *
  123. *  -- Written on 8-February-1989.
  124. *     Jack Dongarra, Argonne National Laboratory.
  125. *     Iain Duff, AERE Harwell.
  126. *     Jeremy Du Croz, Numerical Algorithms Group Ltd.
  127. *     Sven Hammarling, Numerical Algorithms Group Ltd.
  128. *
  129. *
  130. *     .. External Functions ..
  131.       LOGICAL            LSAME
  132.       EXTERNAL           LSAME
  133. *     .. External Subroutines ..
  134.       EXTERNAL           XERBLA
  135. *     .. Intrinsic Functions ..
  136.       INTRINSIC          MAX
  137. *     .. Local Scalars ..
  138.       LOGICAL            LSIDE, NOUNIT, UPPER
  139.       INTEGER            I, INFO, J, K, NROWA
  140.       DOUBLE PRECISION   TEMP
  141. *     .. Parameters ..
  142.       DOUBLE PRECISION   ONE         , ZERO
  143.       PARAMETER        ( ONE = 1.0D+0, ZERO = 0.0D+0 )
  144. *     ..
  145. *     .. Executable Statements ..
  146. *
  147. *     Test the input parameters.
  148. *
  149.       LSIDE  = LSAME( SIDE  , 'L' )
  150.       IF( LSIDE )THEN
  151.          NROWA = M
  152.       ELSE
  153.          NROWA = N
  154.       END IF
  155.       NOUNIT = LSAME( DIAG  , 'N' )
  156.       UPPER  = LSAME( UPLO  , 'U' )
  157. *
  158.       INFO   = 0
  159.       IF(      ( .NOT.LSIDE                ).AND.
  160.      $         ( .NOT.LSAME( SIDE  , 'R' ) )      )THEN
  161.          INFO = 1
  162.       ELSE IF( ( .NOT.UPPER                ).AND.
  163.      $         ( .NOT.LSAME( UPLO  , 'L' ) )      )THEN
  164.          INFO = 2
  165.       ELSE IF( ( .NOT.LSAME( TRANSA, 'N' ) ).AND.
  166.      $         ( .NOT.LSAME( TRANSA, 'T' ) ).AND.
  167.      $         ( .NOT.LSAME( TRANSA, 'C' ) )      )THEN
  168.          INFO = 3
  169.       ELSE IF( ( .NOT.LSAME( DIAG  , 'U' ) ).AND.
  170.      $         ( .NOT.LSAME( DIAG  , 'N' ) )      )THEN
  171.          INFO = 4
  172.       ELSE IF( M  .LT.0               )THEN
  173.          INFO = 5
  174.       ELSE IF( N  .LT.0               )THEN
  175.          INFO = 6
  176.       ELSE IF( LDA.LT.MAX( 1, NROWA ) )THEN
  177.          INFO = 9
  178.       ELSE IF( LDB.LT.MAX( 1, M     ) )THEN
  179.          INFO = 11
  180.       END IF
  181.       IF( INFO.NE.0 )THEN
  182.          CALL XERBLA( 'DTRMM ', INFO )
  183.          RETURN
  184.       END IF
  185. *
  186. *     Quick return if possible.
  187. *
  188.       IF( N.EQ.0 )
  189.      $   RETURN
  190. *
  191. *     And when  alpha.eq.zero.
  192. *
  193.       IF( ALPHA.EQ.ZERO )THEN
  194.          DO 20, J = 1, N
  195.             DO 10, I = 1, M
  196.                B( I, J ) = ZERO
  197.    10       CONTINUE
  198.    20    CONTINUE
  199.          RETURN
  200.       END IF
  201. *
  202. *     Start the operations.
  203. *
  204.       IF( LSIDE )THEN
  205.          IF( LSAME( TRANSA, 'N' ) )THEN
  206. *
  207. *           Form  B := alpha*A*B.
  208. *
  209.             IF( UPPER )THEN
  210.                DO 50, J = 1, N
  211.                   DO 40, K = 1, M
  212.                      IF( B( K, J ).NE.ZERO )THEN
  213.                         TEMP = ALPHA*B( K, J )
  214.                         DO 30, I = 1, K - 1
  215.                            B( I, J ) = B( I, J ) + TEMP*A( I, K )
  216.    30                   CONTINUE
  217.                         IF( NOUNIT )
  218.      $                     TEMP = TEMP*A( K, K )
  219.                         B( K, J ) = TEMP
  220.                      END IF
  221.    40             CONTINUE
  222.    50          CONTINUE
  223.             ELSE
  224.                DO 80, J = 1, N
  225.                   DO 70 K = M, 1, -1
  226.                      IF( B( K, J ).NE.ZERO )THEN
  227.                         TEMP      = ALPHA*B( K, J )
  228.                         B( K, J ) = TEMP
  229.                         IF( NOUNIT )
  230.      $                     B( K, J ) = B( K, J )*A( K, K )
  231.                         DO 60, I = K + 1, M
  232.                            B( I, J ) = B( I, J ) + TEMP*A( I, K )
  233.    60                   CONTINUE
  234.                      END IF
  235.    70             CONTINUE
  236.    80          CONTINUE
  237.             END IF
  238.          ELSE
  239. *
  240. *           Form  B := alpha*B*A'.
  241. *
  242.             IF( UPPER )THEN
  243.                DO 110, J = 1, N
  244.                   DO 100, I = M, 1, -1
  245.                      TEMP = B( I, J )
  246.                      IF( NOUNIT )
  247.      $                  TEMP = TEMP*A( I, I )
  248.                      DO 90, K = 1, I - 1
  249.                         TEMP = TEMP + A( K, I )*B( K, J )
  250.    90                CONTINUE
  251.                      B( I, J ) = ALPHA*TEMP
  252.   100             CONTINUE
  253.   110          CONTINUE
  254.             ELSE
  255.                DO 140, J = 1, N
  256.                   DO 130, I = 1, M
  257.                      TEMP = B( I, J )
  258.                      IF( NOUNIT )
  259.      $                  TEMP = TEMP*A( I, I )
  260.                      DO 120, K = I + 1, M
  261.                         TEMP = TEMP + A( K, I )*B( K, J )
  262.   120                CONTINUE
  263.                      B( I, J ) = ALPHA*TEMP
  264.   130             CONTINUE
  265.   140          CONTINUE
  266.             END IF
  267.          END IF
  268.       ELSE
  269.          IF( LSAME( TRANSA, 'N' ) )THEN
  270. *
  271. *           Form  B := alpha*B*A.
  272. *
  273.             IF( UPPER )THEN
  274.                DO 180, J = N, 1, -1
  275.                   TEMP = ALPHA
  276.                   IF( NOUNIT )
  277.      $               TEMP = TEMP*A( J, J )
  278.                   DO 150, I = 1, M
  279.                      B( I, J ) = TEMP*B( I, J )
  280.   150             CONTINUE
  281.                   DO 170, K = 1, J - 1
  282.                      IF( A( K, J ).NE.ZERO )THEN
  283.                         TEMP = ALPHA*A( K, J )
  284.                         DO 160, I = 1, M
  285.                            B( I, J ) = B( I, J ) + TEMP*B( I, K )
  286.   160                   CONTINUE
  287.                      END IF
  288.   170             CONTINUE
  289.   180          CONTINUE
  290.             ELSE
  291.                DO 220, J = 1, N
  292.                   TEMP = ALPHA
  293.                   IF( NOUNIT )
  294.      $               TEMP = TEMP*A( J, J )
  295.                   DO 190, I = 1, M
  296.                      B( I, J ) = TEMP*B( I, J )
  297.   190             CONTINUE
  298.                   DO 210, K = J + 1, N
  299.                      IF( A( K, J ).NE.ZERO )THEN
  300.                         TEMP = ALPHA*A( K, J )
  301.                         DO 200, I = 1, M
  302.                            B( I, J ) = B( I, J ) + TEMP*B( I, K )
  303.   200                   CONTINUE
  304.                      END IF
  305.   210             CONTINUE
  306.   220          CONTINUE
  307.             END IF
  308.          ELSE
  309. *
  310. *           Form  B := alpha*B*A'.
  311. *
  312.             IF( UPPER )THEN
  313.                DO 260, K = 1, N
  314.                   DO 240, J = 1, K - 1
  315.                      IF( A( J, K ).NE.ZERO )THEN
  316.                         TEMP = ALPHA*A( J, K )
  317.                         DO 230, I = 1, M
  318.                            B( I, J ) = B( I, J ) + TEMP*B( I, K )
  319.   230                   CONTINUE
  320.                      END IF
  321.   240             CONTINUE
  322.                   TEMP = ALPHA
  323.                   IF( NOUNIT )
  324.      $               TEMP = TEMP*A( K, K )
  325.                   IF( TEMP.NE.ONE )THEN
  326.                      DO 250, I = 1, M
  327.                         B( I, K ) = TEMP*B( I, K )
  328.   250                CONTINUE
  329.                   END IF
  330.   260          CONTINUE
  331.             ELSE
  332.                DO 300, K = N, 1, -1
  333.                   DO 280, J = K + 1, N
  334.                      IF( A( J, K ).NE.ZERO )THEN
  335.                         TEMP = ALPHA*A( J, K )
  336.                         DO 270, I = 1, M
  337.                            B( I, J ) = B( I, J ) + TEMP*B( I, K )
  338.   270                   CONTINUE
  339.                      END IF
  340.   280             CONTINUE
  341.                   TEMP = ALPHA
  342.                   IF( NOUNIT )
  343.      $               TEMP = TEMP*A( K, K )
  344.                   IF( TEMP.NE.ONE )THEN
  345.                      DO 290, I = 1, M
  346.                         B( I, K ) = TEMP*B( I, K )
  347.   290                CONTINUE
  348.                   END IF
  349.   300          CONTINUE
  350.             END IF
  351.          END IF
  352.       END IF
  353. *
  354.       RETURN
  355. *
  356. *     End of DTRMM .
  357. *
  358.       END
  359.