home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-dist / octave-1.1.1p1-src.tgz / tar.out / fsf / octave / libcruft / blas / dtrmv.f < prev    next >
Text File  |  1996-09-28  |  9KB  |  290 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE DTRMV ( UPLO, TRANS, DIAG, N, A, LDA, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, LDA, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       DOUBLE PRECISION   A( LDA, * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  DTRMV  performs one of the matrix-vector operations
  16. *
  17. *     x := A*x,   or   x := A'*x,
  18. *
  19. *  where x is an n element vector and  A is an n by n unit, or non-unit,
  20. *  upper or lower triangular matrix.
  21. *
  22. *  Parameters
  23. *  ==========
  24. *
  25. *  UPLO   - CHARACTER*1.
  26. *           On entry, UPLO specifies whether the matrix is an upper or
  27. *           lower triangular matrix as follows:
  28. *
  29. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  30. *
  31. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  32. *
  33. *           Unchanged on exit.
  34. *
  35. *  TRANS  - CHARACTER*1.
  36. *           On entry, TRANS specifies the operation to be performed as
  37. *           follows:
  38. *
  39. *              TRANS = 'N' or 'n'   x := A*x.
  40. *
  41. *              TRANS = 'T' or 't'   x := A'*x.
  42. *
  43. *              TRANS = 'C' or 'c'   x := A'*x.
  44. *
  45. *           Unchanged on exit.
  46. *
  47. *  DIAG   - CHARACTER*1.
  48. *           On entry, DIAG specifies whether or not A is unit
  49. *           triangular as follows:
  50. *
  51. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  52. *
  53. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  54. *                                  triangular.
  55. *
  56. *           Unchanged on exit.
  57. *
  58. *  N      - INTEGER.
  59. *           On entry, N specifies the order of the matrix A.
  60. *           N must be at least zero.
  61. *           Unchanged on exit.
  62. *
  63. *  A      - DOUBLE PRECISION array of DIMENSION ( LDA, n ).
  64. *           Before entry with  UPLO = 'U' or 'u', the leading n by n
  65. *           upper triangular part of the array A must contain the upper
  66. *           triangular matrix and the strictly lower triangular part of
  67. *           A is not referenced.
  68. *           Before entry with UPLO = 'L' or 'l', the leading n by n
  69. *           lower triangular part of the array A must contain the lower
  70. *           triangular matrix and the strictly upper triangular part of
  71. *           A is not referenced.
  72. *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
  73. *           A are not referenced either, but are assumed to be unity.
  74. *           Unchanged on exit.
  75. *
  76. *  LDA    - INTEGER.
  77. *           On entry, LDA specifies the first dimension of A as declared
  78. *           in the calling (sub) program. LDA must be at least
  79. *           max( 1, n ).
  80. *           Unchanged on exit.
  81. *
  82. *  X      - DOUBLE PRECISION array of dimension at least
  83. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  84. *           Before entry, the incremented array X must contain the n
  85. *           element vector x. On exit, X is overwritten with the
  86. *           tranformed vector x.
  87. *
  88. *  INCX   - INTEGER.
  89. *           On entry, INCX specifies the increment for the elements of
  90. *           X. INCX must not be zero.
  91. *           Unchanged on exit.
  92. *
  93. *
  94. *  Level 2 Blas routine.
  95. *
  96. *  -- Written on 22-October-1986.
  97. *     Jack Dongarra, Argonne National Lab.
  98. *     Jeremy Du Croz, Nag Central Office.
  99. *     Sven Hammarling, Nag Central Office.
  100. *     Richard Hanson, Sandia National Labs.
  101. *
  102. *
  103. *     .. Parameters ..
  104.       DOUBLE PRECISION   ZERO
  105.       PARAMETER        ( ZERO = 0.0D+0 )
  106. *     .. Local Scalars ..
  107.       DOUBLE PRECISION   TEMP
  108.       INTEGER            I, INFO, IX, J, JX, KX
  109.       LOGICAL            NOUNIT
  110. *     .. External Functions ..
  111.       LOGICAL            LSAME
  112.       EXTERNAL           LSAME
  113. *     .. External Subroutines ..
  114.       EXTERNAL           XERBLA
  115. *     .. Intrinsic Functions ..
  116.       INTRINSIC          MAX
  117. *     ..
  118. *     .. Executable Statements ..
  119. *
  120. *     Test the input parameters.
  121. *
  122.       INFO = 0
  123.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  124.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  125.          INFO = 1
  126.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  127.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  128.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  129.          INFO = 2
  130.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  131.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  132.          INFO = 3
  133.       ELSE IF( N.LT.0 )THEN
  134.          INFO = 4
  135.       ELSE IF( LDA.LT.MAX( 1, N ) )THEN
  136.          INFO = 6
  137.       ELSE IF( INCX.EQ.0 )THEN
  138.          INFO = 8
  139.       END IF
  140.       IF( INFO.NE.0 )THEN
  141.          CALL XERBLA( 'DTRMV ', INFO )
  142.          RETURN
  143.       END IF
  144. *
  145. *     Quick return if possible.
  146. *
  147.       IF( N.EQ.0 )
  148.      $   RETURN
  149. *
  150.       NOUNIT = LSAME( DIAG, 'N' )
  151. *
  152. *     Set up the start point in X if the increment is not unity. This
  153. *     will be  ( N - 1 )*INCX  too small for descending loops.
  154. *
  155.       IF( INCX.LE.0 )THEN
  156.          KX = 1 - ( N - 1 )*INCX
  157.       ELSE IF( INCX.NE.1 )THEN
  158.          KX = 1
  159.       END IF
  160. *
  161. *     Start the operations. In this version the elements of A are
  162. *     accessed sequentially with one pass through A.
  163. *
  164.       IF( LSAME( TRANS, 'N' ) )THEN
  165. *
  166. *        Form  x := A*x.
  167. *
  168.          IF( LSAME( UPLO, 'U' ) )THEN
  169.             IF( INCX.EQ.1 )THEN
  170.                DO 20, J = 1, N
  171.                   IF( X( J ).NE.ZERO )THEN
  172.                      TEMP = X( J )
  173.                      DO 10, I = 1, J - 1
  174.                         X( I ) = X( I ) + TEMP*A( I, J )
  175.    10                CONTINUE
  176.                      IF( NOUNIT )
  177.      $                  X( J ) = X( J )*A( J, J )
  178.                   END IF
  179.    20          CONTINUE
  180.             ELSE
  181.                JX = KX
  182.                DO 40, J = 1, N
  183.                   IF( X( JX ).NE.ZERO )THEN
  184.                      TEMP = X( JX )
  185.                      IX   = KX
  186.                      DO 30, I = 1, J - 1
  187.                         X( IX ) = X( IX ) + TEMP*A( I, J )
  188.                         IX      = IX      + INCX
  189.    30                CONTINUE
  190.                      IF( NOUNIT )
  191.      $                  X( JX ) = X( JX )*A( J, J )
  192.                   END IF
  193.                   JX = JX + INCX
  194.    40          CONTINUE
  195.             END IF
  196.          ELSE
  197.             IF( INCX.EQ.1 )THEN
  198.                DO 60, J = N, 1, -1
  199.                   IF( X( J ).NE.ZERO )THEN
  200.                      TEMP = X( J )
  201.                      DO 50, I = N, J + 1, -1
  202.                         X( I ) = X( I ) + TEMP*A( I, J )
  203.    50                CONTINUE
  204.                      IF( NOUNIT )
  205.      $                  X( J ) = X( J )*A( J, J )
  206.                   END IF
  207.    60          CONTINUE
  208.             ELSE
  209.                KX = KX + ( N - 1 )*INCX
  210.                JX = KX
  211.                DO 80, J = N, 1, -1
  212.                   IF( X( JX ).NE.ZERO )THEN
  213.                      TEMP = X( JX )
  214.                      IX   = KX
  215.                      DO 70, I = N, J + 1, -1
  216.                         X( IX ) = X( IX ) + TEMP*A( I, J )
  217.                         IX      = IX      - INCX
  218.    70                CONTINUE
  219.                      IF( NOUNIT )
  220.      $                  X( JX ) = X( JX )*A( J, J )
  221.                   END IF
  222.                   JX = JX - INCX
  223.    80          CONTINUE
  224.             END IF
  225.          END IF
  226.       ELSE
  227. *
  228. *        Form  x := A'*x.
  229. *
  230.          IF( LSAME( UPLO, 'U' ) )THEN
  231.             IF( INCX.EQ.1 )THEN
  232.                DO 100, J = N, 1, -1
  233.                   TEMP = X( J )
  234.                   IF( NOUNIT )
  235.      $               TEMP = TEMP*A( J, J )
  236.                   DO 90, I = J - 1, 1, -1
  237.                      TEMP = TEMP + A( I, J )*X( I )
  238.    90             CONTINUE
  239.                   X( J ) = TEMP
  240.   100          CONTINUE
  241.             ELSE
  242.                JX = KX + ( N - 1 )*INCX
  243.                DO 120, J = N, 1, -1
  244.                   TEMP = X( JX )
  245.                   IX   = JX
  246.                   IF( NOUNIT )
  247.      $               TEMP = TEMP*A( J, J )
  248.                   DO 110, I = J - 1, 1, -1
  249.                      IX   = IX   - INCX
  250.                      TEMP = TEMP + A( I, J )*X( IX )
  251.   110             CONTINUE
  252.                   X( JX ) = TEMP
  253.                   JX      = JX   - INCX
  254.   120          CONTINUE
  255.             END IF
  256.          ELSE
  257.             IF( INCX.EQ.1 )THEN
  258.                DO 140, J = 1, N
  259.                   TEMP = X( J )
  260.                   IF( NOUNIT )
  261.      $               TEMP = TEMP*A( J, J )
  262.                   DO 130, I = J + 1, N
  263.                      TEMP = TEMP + A( I, J )*X( I )
  264.   130             CONTINUE
  265.                   X( J ) = TEMP
  266.   140          CONTINUE
  267.             ELSE
  268.                JX = KX
  269.                DO 160, J = 1, N
  270.                   TEMP = X( JX )
  271.                   IX   = JX
  272.                   IF( NOUNIT )
  273.      $               TEMP = TEMP*A( J, J )
  274.                   DO 150, I = J + 1, N
  275.                      IX   = IX   + INCX
  276.                      TEMP = TEMP + A( I, J )*X( IX )
  277.   150             CONTINUE
  278.                   X( JX ) = TEMP
  279.                   JX      = JX   + INCX
  280.   160          CONTINUE
  281.             END IF
  282.          END IF
  283.       END IF
  284. *
  285.       RETURN
  286. *
  287. *     End of DTRMV .
  288. *
  289.       END
  290.