home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 5 / FreshFish_July-August1994.bin / bbs / dev / rkrm.lha / RKRM / Printer / epsonx / transfer.asm < prev    next >
Encoding:
Assembly Source File  |  1992-09-03  |  9.3 KB  |  301 lines
  1. *
  2. * Copyright (c) 1992 Commodore-Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Commodore-Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Commodore Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. **********************************************************************
  27. *
  28. * Transfer routine for EpsonX
  29. *
  30. **********************************************************************
  31.  
  32.         INCLUDE "exec/types.i"
  33.  
  34.         INCLUDE "intuition/intuition.i"
  35.         INCLUDE "devices/printer.i"
  36.         INCLUDE "devices/prtbase.i"
  37.         INCLUDE "devices/prtgfx.i"
  38.  
  39.         XREF    _PD
  40.         XREF    _PED
  41.         XREF    _LVODebug
  42.         XREF    _AbsExecBase
  43.  
  44.         XDEF    _Transfer
  45.  
  46.         SECTION         printer,CODE
  47. _Transfer:
  48. ; Transfer(PInfo, y, ptr, colors, BufOffset)
  49. ; struct PrtInfo *PInfo         4-7
  50. ; UWORD y;                      8-11
  51. ; UBYTE *ptr;                   12-15
  52. ; UWORD *colors;                16-19
  53. ; ULONG BufOffset               20-23
  54.  
  55.         movem.l d2-d6/a2-a4,-(sp)       ;save regs used
  56.  
  57.         movea.l 36(sp),a0               ;a0 = PInfo
  58.         move.l  40(sp),d0               ;d0 = y
  59.         movea.l 44(sp),a1               ;a1 = ptr
  60.         movea.l 48(sp),a2               ;a2 = colors
  61.         move.l  52(sp),d1               ;d1 = BufOffset
  62.  
  63.         move.l  d0,d3                   ;save y
  64.         moveq.l #3,d2
  65.         and.w   d0,d2                   ;d2 = y & 3
  66.         lsl.w   #2,d2                   ;d2 = (y & 3) << 2
  67.         movea.l pi_dmatrix(a0),a3       ;a3 = dmatrix
  68.         adda.l  d2,a3                   ;a3 = dmatrix + ((y & 3) << 2)
  69.  
  70.         movea.l _PED,a4                 ;a4 = ptr to PED
  71.         cmpi.w  #216,ped_YDotsInch(a4)  ;triple interleaving?
  72.         bne.s   10$                     ;no
  73.         divu.w  #3,d0                   ;y /= 3
  74.         swap.w  d0                      ;d0 = y % 3
  75.         mulu.w  d0,d1                   ;BufOffset *= y % 3
  76.         swap.w  d0                      ;d0 = y / 3
  77.         bra.s   30$
  78.  
  79. 10$:    cmpi.w  #144,ped_YDotsInch(a4)  ;double interleaving?
  80.         bne.s   20$                     ;no, clear BufOffset
  81.         asr.w   #1,d0                   ;y /= 2
  82.         btst    #0,d3                   ;odd pass?
  83.         bne.s   30$                     ;no, dont clear BufOffset
  84.  
  85. 20$:    moveq.l #0,d1                   ;BufOffset = 0
  86.  
  87. 30$:    move.w  d0,d6
  88.         not.b   d6                      ;d6 = bit to set
  89.         adda.l  d1,a1                   ;ptr += BufOffset
  90.  
  91.         movea.l _PD,a4                  ;a4 = ptr to PD
  92.         cmpi.w  #SHADE_COLOR,pd_Preferences+pf_PrintShade(a4)   ;color dump?
  93.         bne     not_color               ;no
  94.  
  95. color:
  96. ; a0 - PInfo
  97. ; a1 - ptr (ptr + BufOffset)
  98. ; a2 - colors
  99. ; a3 - dmatrix ptr
  100. ; d0 - y
  101. ; d1 - BufOffset
  102. ; d6 - bit to set
  103.  
  104.         movem.l d7/a5-a6,-(sp)          ;save regs used
  105.  
  106.         movea.l a1,a4
  107.         movea.l a1,a5
  108.         movea.l a1,a6
  109.         adda.w  (a2)+,a1                ;a1 = ptr + colors[0] (bptr)
  110.         adda.w  (a2)+,a4                ;a4 = ptr + colors[1] (yptr)
  111.         adda.w  (a2)+,a5                ;a5 = ptr + colors[2] (mptr)
  112.         adda.w  (a2)+,a6                ;a6 = ptr + colors[3] (cptr)
  113.  
  114. ;       move.l  a6,-(sp)
  115. ;       move.l  _AbsExecBase,a6
  116. ;       jsr     _LVODebug(a6)
  117. ;       move.l  (sp)+,a6
  118.  
  119.         movea.l pi_ColorInt(a0),a2      ;a2 = ColorInt ptr
  120.         move.w  pi_width(a0),width      ;# of pixels to do
  121.         move.w  pi_xpos(a0),d2          ;d2 = x
  122.         movea.l pi_ScaleX(a0),a0        ;a0 = ScaleX (sxptr)
  123.         move.b  d6,d7                   ;d7 = bit to set
  124.  
  125. ; a0 - sxptr
  126. ; a1 - bptr
  127. ; a2 - ColorInt ptr
  128. ; a3 - dmatrix ptr
  129. ; a4 - yptr
  130. ; a5 - mptr
  131. ; a6 - cptr
  132. ; d1 - Black
  133. ; d2 - x
  134. ; d3 - dvalue (dmatrix[x & 3])
  135. ; d4 - Yellow
  136. ; d5 - Magenta
  137. ; d6 - Cyan
  138. ; d7 - bit to set
  139.  
  140. cwidth_loop:
  141.         move.b  PCMBLACK(a2),d1         ;d1 = Black
  142.         move.b  PCMYELLOW(a2),d4        ;d4 = Yellow
  143.         move.b  PCMMAGENTA(a2),d5       ;d5 = Magenta
  144.         move.b  PCMCYAN(a2),d6          ;d6 = Cyan
  145.         addq.l  #ce_SIZEOF,a2           ;advance to next entry
  146.  
  147.         move.w  (a0)+,sx                ;# of times to use this pixel
  148.  
  149. csx_loop:
  150.         moveq.l #3,d3
  151.         and.w   d2,d3                   ;d3 = x & 3
  152.         move.b  0(a3,d3.w),d3           ;d3 = dmatrix[x & 3]
  153.  
  154. black:
  155.         cmp.b   d3,d1                   ;render black?
  156.         ble.s   yellow                  ;no, try ymc
  157.         bset.b  d7,0(a1,d2.w)           ;set black pixel
  158.         bra.s   csx_end
  159.  
  160. yellow:
  161.         cmp.b   d3,d4                   ;render yellow pixel?
  162.         ble.s   magenta                 ;no.
  163.         bset.b  d7,0(a4,d2.w)           ;set yellow pixel
  164.  
  165. magenta:
  166.         cmp.b   d3,d5                   ;render magenta pixel?
  167.         ble.s   cyan                    ;no.
  168.         bset.b  d7,0(a5,d2.w)           ;set magenta pixel
  169.  
  170. cyan:
  171.         cmp.b   d3,d6                   ;render cyan pixel?
  172.         ble.s   csx_end                 ;no, skip to next pixel.
  173.         bset.b  d7,0(a6,d2.w)           ;clear cyan pixel
  174.  
  175. csx_end
  176.         addq.w  #1,d2                   ;x++
  177.         subq.w  #1,sx                   ;sx--
  178.         bne.s   csx_loop
  179.         subq.w  #1,width                ;width--
  180.         bne.s   cwidth_loop
  181.  
  182.         movem.l (sp)+,d7/a5-a6          ;restore regs used
  183.         bra     exit
  184.  
  185. not_color:
  186. ; a0 - PInfo
  187. ; a1 - ptr
  188. ; a2 - colors
  189. ; a3 - dmatrix ptr
  190. ; d0 - y
  191. ; d6 - bit to set
  192.  
  193.         adda.w  (a2),a1                 ;a1 = ptr + colors[0]
  194.         move.w  pi_width(a0),d1         ;d1 = width
  195.         subq.w  #1,d1                   ;adjust for dbra
  196.  
  197.         move.w  pi_threshold(a0),d3     ;d3 = threshold, thresholding?
  198.         beq.s   grey_scale              ;no, grey-scaling
  199.  
  200. threshold:
  201. ; a0 - PInfo
  202. ; a1 - ptr
  203. ; a3 - dmatrix ptr
  204. ; d1 - width-1
  205. ; d3 - threshold
  206. ; d6 - bit to set
  207.  
  208.         eori.b  #15,d3                  ;d3 = dvalue
  209.         movea.l pi_ColorInt(a0),a2      ;a2 = ColorInt ptr
  210.         move.w  pi_xpos(a0),d2          ;d2 = x
  211.         movea.l pi_ScaleX(a0),a0        ;a0 = ScaleX (sxptr)
  212.         adda.w  d2,a1                   ;ptr += x
  213.  
  214. ; a0 - sxptr
  215. ; a1 - ptr
  216. ; a2 - ColorInt ptr
  217. ; a3 - dmatrix ptr (NOT USED)
  218. ; d1 - width
  219. ; d3 - dvalue
  220. ; d4 - Black
  221. ; d5 - sx
  222. ; d6 - bit to set
  223.  
  224. twidth_loop:
  225.         move.b  PCMBLACK(a2),d4         ;d4 = Black
  226.         addq.l  #ce_SIZEOF,a2           ;advance to next entry
  227.  
  228.         move.w  (a0)+,d5                ;d5 = # of times to use this pixel
  229.  
  230.         cmp.b   d3,d4                   ;render this pixel?
  231.         ble.s   tsx_end                 ;no, skip to next pixel.
  232.         subq.w  #1,d5                   ;adjust for dbra
  233.  
  234. tsx_render:                             ;yes, render this pixel sx times
  235.         bset.b  d6,(a1)                 ;*(ptr) |= bit;
  236.  
  237.         adda.w  #1,a1                   ;ptr++
  238.         dbra    d5,tsx_render           ;sx--
  239.         dbra    d1,twidth_loop          ;width--
  240.         bra.s   exit                    ;all done
  241.  
  242. tsx_end:
  243.         adda.w  d5,a1                   ;ptr += sx
  244.         dbra    d1,twidth_loop          ;width--
  245.         bra.s   exit
  246.  
  247. grey_scale:
  248. ; a0 - PInfo
  249. ; a1 - ptr
  250. ; a3 - dmatrix ptr
  251. ; d0 - y
  252. ; d1 - width-1
  253. ; d6 - bit to set
  254.  
  255.         movea.l pi_ColorInt(a0),a2      ;a2 = ColorInt ptr
  256.         move.w  pi_xpos(a0),d2          ;d2 = x
  257.         movea.l pi_ScaleX(a0),a0        ;a0 = ScaleX (sxptr)
  258.  
  259. ; a0 - sxptr
  260. ; a1 - ptr
  261. ; a2 - ColorInt ptr
  262. ; a3 - dmatrix ptr
  263. ; d1 - width
  264. ; d2 - x
  265. ; d3 - dvalue (dmatrix[x & 3])
  266. ; d4 - Black
  267. ; d5 - sx
  268. ; d6 - bit to set
  269.  
  270. gwidth_loop:
  271.         move.b  PCMBLACK(a2),d4         ;d4 = Black
  272.         addq.l  #ce_SIZEOF,a2           ;advance to next entry
  273.  
  274.         move.w  (a0)+,d5                ;d5 = # of times to use this pixel
  275.         subq.w  #1,d5                   ;adjust for dbra
  276.  
  277. gsx_loop:
  278.         moveq.l #3,d3
  279.         and.w   d2,d3                   ;d3 = x & 3
  280.         move.b  0(a3,d3.w),d3           ;d3 = dmatrix[x & 3]
  281.  
  282.         cmp.b   d3,d4                   ;render this pixel?
  283.         ble.s   gsx_end                 ;no, skip to next pixel.
  284.  
  285.         bset.b  d6,0(a1,d2.w)           ;*(ptr + x) |= bit
  286.  
  287. gsx_end
  288.         addq.w  #1,d2                   ;x++
  289.         dbra    d5,gsx_loop             ;sx--
  290.         dbra    d1,gwidth_loop          ;width--
  291.  
  292. exit:
  293.         movem.l (sp)+,d2-d6/a2-a4       ;restore regs used
  294.         moveq.l #0,d0                   ;flag all ok
  295.         rts                             ;goodbye
  296.  
  297. sx      dc.w    0
  298. width   dc.w    0
  299.  
  300.         END
  301.