home *** CD-ROM | disk | FTP | other *** search
/ Fresh Fish 6 / FreshFish_September1994.bin / bbs / gnu / emacs-18.59-src.lha / GNU / src / amiga / emacs-18.59 / lisp / simple.el < prev    next >
Encoding:
Text File  |  1992-11-21  |  49.6 KB  |  1,465 lines
  1. ;; Basic editing commands for Emacs
  2. ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
  3.  
  4. ;; This file is part of GNU Emacs.
  5.  
  6. ;; GNU Emacs is free software; you can redistribute it and/or modify
  7. ;; it under the terms of the GNU General Public License as published by
  8. ;; the Free Software Foundation; either version 1, or (at your option)
  9. ;; any later version.
  10.  
  11. ;; GNU Emacs is distributed in the hope that it will be useful,
  12. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14. ;; GNU General Public License for more details.
  15.  
  16. ;; You should have received a copy of the GNU General Public License
  17. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  18. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  19.  
  20.  
  21. (defun open-line (arg)
  22.   "Insert a newline and leave point before it.
  23. With arg, inserts that many newlines."
  24.   (interactive "*p")
  25.   (let ((flag (and (bolp) (not (bobp)))))
  26.     (if flag (forward-char -1))
  27.     (while (> arg 0)
  28.       (insert ?\n)
  29.       (goto-char (1- (point)))
  30.       (setq arg (1- arg)))
  31.     (if flag (forward-char 1))))
  32.  
  33. (defun split-line ()
  34.   "Split current line, moving portion beyond point vertically down."
  35.   (interactive "*")
  36.   (skip-chars-forward " \t")
  37.   (let ((col (current-column))
  38.     (pos (point)))
  39.     (insert ?\n)
  40.     (indent-to col 0)
  41.     (goto-char pos)))
  42.  
  43. (defun quoted-insert (arg)
  44.   "Read next input character and insert it.
  45. Useful for inserting control characters.
  46. You may also type up to 3 octal digits, to insert a character with that code"
  47.   (interactive "*p")
  48.   (let ((char (read-quoted-char)))
  49.     (while (> arg 0)
  50.       (insert char)
  51.       (setq arg (1- arg)))))
  52.  
  53. (defun delete-indentation (&optional arg)
  54.   "Join this line to previous and fix up whitespace at join.
  55. With argument, join this line to following line."
  56.   (interactive "*P")
  57.   (beginning-of-line)
  58.   (if arg (forward-line 1))
  59.   (if (eq (preceding-char) ?\n)
  60.       (progn
  61.     (delete-region (point) (1- (point)))
  62.     (fixup-whitespace))))
  63.  
  64. (defun fixup-whitespace ()
  65.   "Fixup white space between objects around point.
  66. Leave one space or none, according to the context."
  67.   (interactive "*")
  68.   (save-excursion
  69.     (delete-horizontal-space)
  70.     (if (or (looking-at "^\\|\\s)\\|$")
  71.         (save-excursion (forward-char -1)
  72.                 (looking-at "\\s(\\|\\s'")))
  73.     nil
  74.       (insert ?\ ))))
  75.  
  76. (defun delete-horizontal-space ()
  77.   "Delete all spaces and tabs around point."
  78.   (interactive "*")
  79.   (skip-chars-backward " \t")
  80.   (delete-region (point) (progn (skip-chars-forward " \t") (point))))
  81.  
  82. (defun just-one-space ()
  83.   "Delete all spaces and tabs around point, leaving one space."
  84.   (interactive "*")
  85.   (skip-chars-backward " \t")
  86.   (if (= (following-char) ? )
  87.       (forward-char 1)
  88.     (insert ? ))
  89.   (delete-region (point) (progn (skip-chars-forward " \t") (point))))
  90.  
  91. (defun delete-blank-lines ()
  92.   "On blank line, delete all surrounding blank lines, leaving just one.
  93. On isolated blank line, delete that one.
  94. On nonblank line, delete all blank lines that follow it."
  95.   (interactive "*")
  96.   (let (thisblank singleblank)
  97.     (save-excursion
  98.       (beginning-of-line)
  99.       (setq thisblank (looking-at "[ \t]*$"))
  100.       (setq singleblank
  101.         (and thisblank
  102.          (not (looking-at "[ \t]*\n[ \t]*$"))
  103.          (or (bobp)
  104.              (progn (forward-line -1)
  105.                 (not (looking-at "[ \t]*$")))))))
  106.     (if thisblank
  107.     (progn
  108.       (beginning-of-line)
  109.       (if singleblank (forward-line 1))
  110.       (delete-region (point)
  111.              (if (re-search-backward "[^ \t\n]" nil t)
  112.                  (progn (forward-line 1) (point))
  113.                (point-min)))))
  114.     (if (not (and thisblank singleblank))
  115.     (save-excursion
  116.       (end-of-line)
  117.       (forward-line 1)
  118.       (delete-region (point)
  119.              (if (re-search-forward "[^ \t\n]" nil t)
  120.                  (progn (beginning-of-line) (point))
  121.                (point-max)))))))
  122.  
  123. (defun back-to-indentation ()
  124.   "Move point to the first non-whitespace character on this line."
  125.   (interactive)
  126.   (beginning-of-line 1)
  127.   (skip-chars-forward " \t"))
  128.  
  129. (defun newline-and-indent ()
  130.   "Insert a newline, then indent according to major mode.
  131. Indentation is done using the current indent-line-function.
  132. In programming language modes, this is the same as TAB.
  133. In some text modes, where TAB inserts a tab, this indents to the
  134. specified left-margin column."
  135.   (interactive "*")
  136.   (delete-region (point) (progn (skip-chars-backward " \t") (point)))
  137.   (newline)
  138.   (indent-according-to-mode))
  139.  
  140. (defun reindent-then-newline-and-indent ()
  141.   "Reindent current line, insert newline, then indent the new line.
  142. Indentation of both lines is done according to the current major mode,
  143. which means that the current value of indent-line-function is called.
  144. In programming language modes, this is the same as TAB.
  145. In some text modes, where TAB inserts a tab, this indents to the
  146. specified left-margin column."
  147.   (interactive "*")
  148.   (save-excursion
  149.     (delete-region (point) (progn (skip-chars-backward " \t") (point)))
  150.     (indent-according-to-mode))
  151.   (newline)
  152.   (indent-according-to-mode))
  153.  
  154. (defun kill-forward-chars (arg)
  155.   (if (listp arg) (setq arg (car arg)))
  156.   (if (eq arg '-) (setq arg -1))
  157.   (kill-region (point) (+ (point) arg)))
  158.  
  159. (defun kill-backward-chars (arg)
  160.   (if (listp arg) (setq arg (car arg)))
  161.   (if (eq arg '-) (setq arg -1))
  162.   (kill-region (point) (- (point) arg)))
  163.  
  164. (defun backward-delete-char-untabify (arg &optional killp)
  165.   "Delete characters backward, changing tabs into spaces.
  166. Delete ARG chars, and kill (save in kill ring) if KILLP is non-nil.
  167. Interactively, ARG is the prefix arg (default 1)
  168. and KILLP is t if prefix arg is was specified."
  169.   (interactive "*p\nP")
  170.   (let ((count arg))
  171.     (save-excursion
  172.       (while (and (> count 0) (not (bobp)))
  173.     (if (= (preceding-char) ?\t)
  174.         (let ((col (current-column)))
  175.           (forward-char -1)
  176.           (setq col (- col (current-column)))
  177.           (insert-char ?\ col)
  178.           (delete-char 1)))
  179.     (forward-char -1)
  180.     (setq count (1- count)))))
  181.   (delete-backward-char arg killp))
  182.  
  183. (defun zap-to-char (arg char)
  184.   "Kill up to (but not including) ARG'th occurrence of CHAR.
  185. Goes backward if ARG is negative; goes to end of buffer if CHAR not found."
  186.   (interactive "*p\ncZap to char: ")
  187.   (kill-region (point) (if (search-forward (char-to-string char) nil t arg)
  188.              (progn (goto-char (if (> arg 0) (1- (point)) (1+ (point))))
  189.                 (point))
  190.                (if (> arg 0) (point-max) (point-min)))))
  191.  
  192. (defun beginning-of-buffer (&optional arg)
  193.   "Move point to the beginning of the buffer; leave mark at previous position.
  194. With arg N, put point N/10 of the way from the true beginning.
  195. Don't use this in Lisp programs!
  196. \(goto-char (point-min)) is faster and does not set the mark."
  197.   (interactive "P")
  198.   (push-mark)
  199.   (goto-char (if arg
  200.          (if (> (buffer-size) 10000)
  201.              ;; Avoid overflow for large buffer sizes!
  202.              (* (prefix-numeric-value arg)
  203.             (/ (buffer-size) 10))
  204.            (/ (+ 10 (* (buffer-size) (prefix-numeric-value arg))) 10))
  205.            (point-min)))
  206.   (if arg (forward-line 1)))
  207.  
  208. (defun end-of-buffer (&optional arg)
  209.   "Move point to the end of the buffer; leave mark at previous position.
  210. With arg N, put point N/10 of the way from the true end.
  211. Don't use this in Lisp programs!
  212. \(goto-char (point-max)) is faster and does not set the mark."
  213.   (interactive "P")
  214.   (push-mark)
  215.   (goto-char (if arg
  216.          (- (1+ (buffer-size))
  217.             (if (> (buffer-size) 10000)
  218.             ;; Avoid overflow for large buffer sizes!
  219.             (* (prefix-numeric-value arg)
  220.                (/ (buffer-size) 10))
  221.               (/ (* (buffer-size) (prefix-numeric-value arg)) 10)))
  222.            (point-max)))
  223.   (if arg (forward-line 1)))
  224.  
  225. (defun mark-whole-buffer ()
  226.   "Put point at beginning and mark at end of buffer."
  227.   (interactive)
  228.   (push-mark (point))
  229.   (push-mark (point-max))
  230.   (goto-char (point-min)))
  231.  
  232. (defun count-lines-region (start end)
  233.   "Print number of lines in the region."
  234.   (interactive "r")
  235.   (message "Region has %d lines" (count-lines start end)))
  236.  
  237. (defun what-line ()
  238.   "Print the current line number (in the buffer) of point."
  239.   (interactive)
  240.   (save-restriction
  241.     (widen)
  242.     (save-excursion
  243.       (beginning-of-line)
  244.       (message "Line %d"
  245.            (1+ (count-lines 1 (point)))))))
  246.  
  247. (defun count-lines (start end)
  248.   "Return number of newlines between START and END."
  249.   (save-excursion
  250.     (save-restriction
  251.       (narrow-to-region start end)
  252.       (goto-char (point-min))
  253.       (- (buffer-size) (forward-line (buffer-size))))))
  254.  
  255. (defun what-cursor-position ()
  256.   "Print info on cursor position (on screen and within buffer)."
  257.   (interactive)
  258.   (let* ((char (following-char))
  259.      (beg (point-min))
  260.      (end (point-max))
  261.          (pos (point))
  262.      (total (buffer-size))
  263.      (percent (if (> total 50000)
  264.               ;; Avoid overflow from multiplying by 100!
  265.               (/ (+ (/ total 200) (1- pos)) (max (/ total 100) 1))
  266.             (/ (+ (/ total 2) (* 100 (1- pos))) (max total 1))))
  267.      (hscroll (if (= (window-hscroll) 0)
  268.               ""
  269.             (format " Hscroll=%d" (window-hscroll))))
  270.      (col (current-column)))
  271.     (if (= pos end)
  272.     (if (or (/= beg 1) (/= end (1+ total)))
  273.         (message "point=%d of %d(%d%%) <%d - %d>  column %d %s"
  274.              pos total percent beg end col hscroll)
  275.       (message "point=%d of %d(%d%%)  column %d %s"
  276.            pos total percent col hscroll))
  277.       (if (or (/= beg 1) (/= end (1+ total)))
  278.       (message "Char: %s (0%o)  point=%d of %d(%d%%) <%d - %d>  column %d %s"
  279.            (single-key-description char) char pos total percent beg end col hscroll)
  280.     (message "Char: %s (0%o)  point=%d of %d(%d%%)  column %d %s"
  281.          (single-key-description char) char pos total percent col hscroll)))))
  282.  
  283. (defun fundamental-mode ()
  284.   "Major mode not specialized for anything in particular.
  285. Other major modes are defined by comparison with this one."
  286.   (interactive)
  287.   (kill-all-local-variables))
  288.  
  289. (put 'eval-expression 'disabled t)
  290.  
  291. ;; We define this, rather than making  eval  interactive,
  292. ;; for the sake of completion of names like eval-region, eval-current-buffer.
  293. (defun eval-expression (expression)
  294.   "Evaluate EXPRESSION and print value in minibuffer.
  295. Value is also consed on to front of variable  values  's value."
  296.   (interactive "xEval: ")
  297.   (setq values (cons (eval expression) values))
  298.   (prin1 (car values) t))
  299.  
  300. (defun edit-and-eval-command (prompt command)
  301.   "Prompting with PROMPT, let user edit COMMAND and eval result.
  302. COMMAND is a Lisp expression.  Let user edit that expression in
  303. the minibuffer, then read and evaluate the result."
  304.   (eval (read-minibuffer prompt
  305.              (prin1-to-string command))))
  306.  
  307. (defvar repeat-complex-command-map (copy-alist minibuffer-local-map))
  308. (define-key repeat-complex-command-map "\ep" 'previous-complex-command)
  309. (define-key repeat-complex-command-map "\en" 'next-complex-command)
  310. (defun repeat-complex-command (repeat-complex-command-arg)
  311.   "Edit and re-evaluate last complex command, or ARGth from last.
  312. A complex command is one which used the minibuffer.
  313. The command is placed in the minibuffer as a Lisp form for editing.
  314. The result is executed, repeating the command as changed.
  315. If the command has been changed or is not the most recent previous command
  316. it is added to the front of the command history.
  317. Whilst editing the command, the following commands are available:
  318. \\{repeat-complex-command-map}"
  319.   (interactive "p")
  320.   (let ((elt (nth (1- repeat-complex-command-arg) command-history))
  321.     newcmd)
  322.     (if elt
  323.     (progn
  324.       (setq newcmd (read-from-minibuffer "Redo: "
  325.                          (prin1-to-string elt)
  326.                          repeat-complex-command-map
  327.                          t))
  328.       ;; If command to be redone does not match front of history,
  329.       ;; add it to the history.
  330.       (or (equal newcmd (car command-history))
  331.           (setq command-history (cons newcmd command-history)))
  332.       (eval newcmd))
  333.       (ding))))
  334.  
  335. (defun next-complex-command (n)
  336.   "Inserts the next element of `command-history' into the minibuffer."
  337.   (interactive "p")
  338.   (let ((narg (min (max 1 (- repeat-complex-command-arg n))
  339.            (length command-history))))
  340.     (if (= repeat-complex-command-arg narg)
  341.     (error (if (= repeat-complex-command-arg 1)
  342.            "No following item in command history"
  343.          "No preceeding item command history"))
  344.       (erase-buffer)
  345.       (setq repeat-complex-command-arg narg)
  346.       (insert (prin1-to-string (nth (1- repeat-complex-command-arg)
  347.                     command-history)))
  348.       (goto-char (point-min)))))
  349.  
  350. (defun previous-complex-command (n)
  351.   "Inserts the previous element of `command-history' into the minibuffer."
  352.   (interactive "p")
  353.   (next-complex-command (- n)))
  354.  
  355. (defun goto-line (arg)
  356.   "Goto line ARG, counting from line 1 at beginning of buffer."
  357.   (interactive "NGoto line: ")
  358.   (save-restriction
  359.     (widen)
  360.     (goto-char 1)
  361.     (if (eq selective-display t)
  362.     (re-search-forward "[\n\C-m]" nil 'end (1- arg))
  363.       (forward-line (1- arg)))))
  364.  
  365. ;Put this on C-x u, so we can force that rather than C-_ into startup msg
  366. (fset 'advertised-undo 'undo)
  367.  
  368. (defun undo (&optional arg)
  369.   "Undo some previous changes.
  370. Repeat this command to undo more changes.
  371. A numeric argument serves as a repeat count."
  372.   (interactive "*p")
  373.   (let ((modified (buffer-modified-p)))
  374.     (or (eq (selected-window) (minibuffer-window))
  375.     (message "Undo!"))
  376.     (or (eq last-command 'undo)
  377.     (progn (undo-start)
  378.            (undo-more 1)))
  379.     (setq this-command 'undo)
  380.     (undo-more (or arg 1))
  381.     (and modified (not (buffer-modified-p))
  382.      (delete-auto-save-file-if-necessary))))
  383.  
  384. (defun shell-command (command &optional flag)
  385.   "Execute string COMMAND in inferior shell; display output, if any.
  386. Optional second arg non-nil (prefix arg, if interactive)
  387. means insert output in current buffer after point (leave mark after it)."
  388.   (interactive "sShell command: \nP")
  389.   (if flag
  390.       (progn (barf-if-buffer-read-only)
  391.          (push-mark)
  392.          (call-process shell-file-name nil t nil
  393.                "-c" command)
  394.          (exchange-point-and-mark))
  395.     (shell-command-on-region (point) (point) command nil)))
  396.  
  397. (defun shell-command-on-region (start end command &optional flag interactive)
  398.   "Execute string COMMAND in inferior shell with region as input.
  399. Normally display output (if any) in temp buffer;
  400. Prefix arg means replace the region with it.
  401. Noninteractive args are START, END, COMMAND, FLAG.
  402. Noninteractively FLAG means insert output in place of text from START to END,
  403. and put point at the end, but don't alter the mark."
  404.   (interactive "r\nsShell command on region: \nP\np")
  405.   (if flag
  406.       ;; Replace specified region with output from command.
  407.       (let ((swap (and interactive (< (point) (mark)))))
  408.     ;; Don't muck with mark
  409.     ;; unless called interactively.
  410.     (and interactive (push-mark))
  411.     (call-process-region start end shell-file-name t t nil
  412.                  "-c" command)
  413.     (and interactive swap (exchange-point-and-mark)))
  414.     (let ((buffer (get-buffer-create "*Shell Command Output*")))
  415.       (if (eq buffer (current-buffer))
  416.       ;; If the input is the same buffer as the output,
  417.       ;; delete everything but the specified region,
  418.       ;; then replace that region with the output.
  419.       (progn (delete-region end (point-max))
  420.          (delete-region (point-min) start)
  421.          (call-process-region (point-min) (point-max)
  422.                       shell-file-name t t nil
  423.                       "-c" command))
  424.     ;; Clear the output buffer, then run the command with output there.
  425.     (save-excursion
  426.       (set-buffer buffer)
  427.       (erase-buffer))
  428.     (call-process-region start end shell-file-name
  429.                  nil buffer nil
  430.                  "-c" command))
  431.       (if (save-excursion
  432.         (set-buffer buffer)
  433.         (> (buffer-size) 0))
  434.       (set-window-start (display-buffer buffer) 1)
  435.     (message "(Shell command completed with no output)")))))
  436.  
  437. (defun universal-argument ()
  438.   "Begin a numeric argument for the following command.
  439. Digits or minus sign following \\[universal-argument] make up the numeric argument.
  440. \\[universal-argument] following the digits or minus sign ends the argument.
  441. \\[universal-argument] without digits or minus sign provides 4 as argument.
  442. Repeating \\[universal-argument] without digits or minus sign
  443.  multiplies the argument by 4 each time."
  444.   (interactive nil)
  445.   (let ((c-u 4) (argstartchar last-command-char)
  446.     char)
  447. ;   (describe-arg (list c-u) 1)
  448.     (setq char (read-char))
  449.     (while (= char argstartchar)
  450.       (setq c-u (* 4 c-u))
  451. ;     (describe-arg (list c-u) 1)
  452.       (setq char (read-char)))
  453.     (prefix-arg-internal char c-u nil)))
  454.  
  455. (defun prefix-arg-internal (char c-u value)
  456.   (let ((sign 1))
  457.     (if (and (numberp value) (< value 0))
  458.     (setq sign -1 value (- value)))
  459.     (if (eq value '-)
  460.     (setq sign -1 value nil))
  461. ;   (describe-arg value sign)
  462.     (while (= ?- char)
  463.       (setq sign (- sign) c-u nil)
  464. ;     (describe-arg value sign)
  465.       (setq char (read-char)))
  466.     (while (and (>= char ?0) (<= char ?9))
  467.       (setq value (+ (* (if (numberp value) value 0) 10) (- char ?0)) c-u nil)
  468. ;     (describe-arg value sign)
  469.       (setq char (read-char)))
  470.     ;; Repeating the arg-start char after digits
  471.     ;; terminates the argument but is ignored.
  472.     (if (eq (lookup-key global-map (make-string 1 char)) 'universal-argument)
  473.     (setq char (read-char)))
  474.     (setq prefix-arg
  475.       (cond (c-u (list c-u))
  476.         ((numberp value) (* value sign))
  477.         ((= sign -1) '-)))
  478.     (setq unread-command-char char)))
  479.  
  480. ;(defun describe-arg (value sign)
  481. ; (cond ((numberp value)
  482. ;     (message "Arg: %d" (* value sign)))
  483. ;    ((consp value)
  484. ;     (message "Arg: C-u factor %d" (car value)))
  485. ;    ((< sign 0)
  486. ;     (message "Arg: -"))))
  487.  
  488. (defun digit-argument (arg)
  489.   "Part of the numeric argument for the next command.
  490. \\[universal-argument] following digits or minus sign ends the argument."
  491.   (interactive "P")
  492.   (prefix-arg-internal last-command-char nil arg))
  493.  
  494. (defun negative-argument (arg)
  495.   "Begin a negative numeric argument for the next command.
  496. \\[universal-argument] following digits or minus sign ends the argument."
  497.   (interactive "P")
  498.   (prefix-arg-internal ?- nil arg))
  499.  
  500. (defun forward-to-indentation (arg)
  501.   "Move forward ARG lines and position at first nonblank character."
  502.   (interactive "p")
  503.   (forward-line arg)
  504.   (skip-chars-forward " \t"))
  505.  
  506. (defun backward-to-indentation (arg)
  507.   "Move backward ARG lines and position at first nonblank character."
  508.   (interactive "p")
  509.   (forward-line (- arg))
  510.   (skip-chars-forward " \t"))
  511.  
  512. (defun kill-line (&optional arg)
  513.   "Kill the rest of the current line; if no nonblanks there, kill thru newline.
  514. With prefix argument, kill that many lines from point.
  515. Negative arguments kill lines backward.
  516.  
  517. When calling from a program, nil means \"no arg\",
  518. a number counts as a prefix arg."
  519.   (interactive "*P")
  520.   (kill-region (point)
  521.            (progn
  522.          (if arg
  523.              (forward-line (prefix-numeric-value arg))
  524.            (if (eobp)
  525.                (signal 'end-of-buffer nil))
  526.            (if (looking-at "[ \t]*$")
  527.                (forward-line 1)
  528.              (end-of-line)))
  529.          (point))))
  530.  
  531. ;;;; The kill ring
  532.  
  533. (defvar kill-ring nil
  534.   "List of killed text sequences.")
  535.  
  536. (defconst kill-ring-max 30
  537.   "*Maximum length of kill ring before oldest elements are thrown away.")
  538.  
  539. (defvar kill-ring-yank-pointer nil
  540.   "The tail of the kill ring whose car is the last thing yanked.")
  541.  
  542. (if (eq system-type 'amigados)
  543.     (progn
  544.       (defun safe-amiga-paste ()
  545.     "Paste from the amiga clipboard, trapping any errors."
  546.     (condition-case nil
  547.         (amiga-paste)
  548.       (error nil)))
  549.  
  550.       (defun check-clipboard ()
  551.     "If there is anything new in the clipboard, add it to the emacs kill ring.
  552. Returns t if there was something added, nil otherwise."
  553.     (let (added)
  554.       (if amiga-new-clip
  555.           (let ((str (safe-amiga-paste)))
  556.         (setq amiga-new-clip nil)
  557.         (if str
  558.             (progn
  559.               (kill-add str)
  560.               (setq added t)
  561.               (setq kill-ring-yank-pointer kill-ring)))))
  562.       added))
  563.       (defun update-clipboard (str)
  564.     (amiga-cut str)
  565.     (setq amiga-new-clip nil)))
  566.     (progn ; These could be defined for X-Windows.
  567.       (defun check-clipboard () nil)
  568.       (defun update-clipboard () nil)))
  569.  
  570. (defun kill-append (string before-p)
  571.   (setcar kill-ring
  572.       (if before-p
  573.           (concat string (car kill-ring))
  574.           (concat (car kill-ring) string)))
  575.   (update-clipboard (car kill-ring)))
  576.  
  577. (defun kill-add (string)
  578.   (check-clipboard)
  579.   (setq kill-ring (cons string kill-ring))
  580.   (update-clipboard string)
  581.   (if (> (length kill-ring) kill-ring-max)
  582.       (setcdr (nthcdr (1- kill-ring-max) kill-ring) nil)))
  583.  
  584. (defun kill-region (beg end)
  585.   "Kill between point and mark.
  586. The text is deleted but saved in the kill ring.
  587. The command \\[yank] can retrieve it from there.
  588. \(If you want to kill and then yank immediately, use \\[copy-region-as-kill].)
  589.  
  590. This is the primitive for programs to kill text (as opposed to deleting it).
  591. Supply two arguments, character numbers indicating the stretch of text
  592.  to be killed.
  593. Any command that calls this function is a \"kill command\".
  594. If the previous command was also a kill command,
  595. the text killed this time appends to the text killed last time
  596. to make one entry in the kill ring."
  597.   (interactive "*r")
  598.   (if (and (not (eq buffer-undo-list t))
  599.        (not (eq last-command 'kill-region))
  600.        (not (eq beg end))
  601.        ;; This test is here in case someone wants to remove the `*'
  602.        ;; above, so that the text gets stored in the kill ring
  603.        ;; even though it doesn't get deleted.
  604.        (not buffer-read-only))
  605.       ;; Don't let the undo list be truncated before we can even access it.
  606.       (let ((undo-high-threshold (+ (- (max beg end) (min beg end)) 100)))
  607.     (delete-region beg end)
  608.     ;; Take the same string recorded for undo
  609.     ;; and put it in the kill-ring.
  610.     (kill-add (car (car buffer-undo-list)))
  611.     (setq this-command 'kill-region)
  612.     (setq kill-ring-yank-pointer kill-ring))
  613.     (copy-region-as-kill beg end)
  614.     (delete-region beg end)))
  615.  
  616. (fset 'kill-ring-save 'copy-region-as-kill)
  617.  
  618. (defun copy-region-as-kill (beg end)
  619.   "Save the region as if killed, but don't kill it."
  620.   (interactive "r")
  621.   (if (and (eq last-command 'kill-region) (not (check-clipboard)))
  622.       (kill-append (buffer-substring beg end) (< end beg))
  623.     (kill-add (buffer-substring beg end)))
  624.   (setq this-command 'kill-region)
  625.   (setq kill-ring-yank-pointer kill-ring))
  626.  
  627. (defun append-next-kill ()
  628.   "Cause following command, if kill, to append to previous kill."
  629.   (interactive)
  630.   (if (interactive-p)
  631.       (setq this-command 'kill-region)
  632.       (setq last-command 'kill-region)))
  633.  
  634. (defun rotate-yank-pointer (arg)
  635.   "Rotate the yanking point in the kill ring."
  636.   (interactive "p")
  637.   (let ((length (length kill-ring)))
  638.     (if (zerop length)
  639.     (error "Kill ring is empty")
  640.       (setq kill-ring-yank-pointer
  641.         (nthcdr (% (+ arg (- length (length kill-ring-yank-pointer)))
  642.                length)
  643.             kill-ring)))))
  644.  
  645. (defun yank-pop (arg)
  646.   "Replace just-yanked stretch of killed-text with a different stretch.
  647. This command is allowed only immediately after a  yank  or a  yank-pop.
  648. At such a time, the region contains a stretch of reinserted
  649. previously-killed text.  yank-pop  deletes that text and inserts in its
  650. place a different stretch of killed text.
  651.  
  652. With no argument, the previous kill is inserted.
  653. With argument n, the n'th previous kill is inserted.
  654. If n is negative, this is a more recent kill.
  655.  
  656. The sequence of kills wraps around, so that after the oldest one
  657. comes the newest one."
  658.   (interactive "*p")
  659.   (if (not (eq last-command 'yank))
  660.       (error "Previous command was not a yank"))
  661.   (setq this-command 'yank)
  662.   (let ((before (< (point) (mark))))
  663.     (delete-region (point) (mark))
  664.     (rotate-yank-pointer arg)
  665.     (set-mark (point))
  666.     (insert (car kill-ring-yank-pointer))
  667.     (if before (exchange-point-and-mark))))
  668.  
  669. (defun yank (&optional arg)
  670.   "Reinsert the last stretch of killed text.
  671. More precisely, reinsert the stretch of killed text most recently
  672. killed OR yanked.
  673. With just C-U as argument, same but put point in front (and mark at end).
  674. With argument n, reinsert the nth most recently killed stretch of killed
  675. text.
  676. See also the command \\[yank-pop]."
  677.   (interactive "*P")
  678.   (check-clipboard)
  679.   (rotate-yank-pointer (if (listp arg) 0
  680.              (if (eq arg '-) -1
  681.                (1- arg))))
  682.   (push-mark (point))
  683.   (insert (car kill-ring-yank-pointer))
  684.   (if (consp arg)
  685.       (exchange-point-and-mark)))
  686.  
  687. (defun insert-buffer (buffer)
  688.   "Insert after point the contents of BUFFER.
  689. Puts mark after the inserted text.
  690. BUFFER may be a buffer or a buffer name."
  691.   (interactive "*bInsert buffer: ")
  692.   (or (bufferp buffer)
  693.       (setq buffer (get-buffer buffer)))
  694.   (let (start end newmark)
  695.     (save-excursion
  696.       (save-excursion
  697.     (set-buffer buffer)
  698.     (setq start (point-min) end (point-max)))
  699.       (insert-buffer-substring buffer start end)
  700.       (setq newmark (point)))
  701.     (push-mark newmark)))
  702.  
  703. (defun append-to-buffer (buffer start end)
  704.   "Append to specified buffer the text of the region.
  705. It is inserted into that buffer before its point.
  706.  
  707. When calling from a program, give three arguments:
  708. a buffer or the name of one, and two character numbers
  709. specifying the portion of the current buffer to be copied."
  710.   (interactive "BAppend to buffer: \nr")
  711.   (let ((oldbuf (current-buffer)))
  712.     (save-excursion
  713.       (set-buffer (get-buffer-create buffer))
  714.       (insert-buffer-substring oldbuf start end))))
  715.  
  716. (defun prepend-to-buffer (buffer start end)
  717.   "Prepend to specified buffer the text of the region.
  718. It is inserted into that buffer after its point.
  719.  
  720. When calling from a program, give three arguments:
  721. a buffer or the name of one, and two character numbers
  722. specifying the portion of the current buffer to be copied."
  723.   (interactive "BPrepend to buffer: \nr")
  724.   (let ((oldbuf (current-buffer)))
  725.     (save-excursion
  726.       (set-buffer (get-buffer-create buffer))
  727.       (save-excursion
  728.     (insert-buffer-substring oldbuf start end)))))
  729.  
  730. (defun copy-to-buffer (buffer start end)
  731.   "Copy to specified buffer the text of the region.
  732. It is inserted into that buffer, replacing existing text there.
  733.  
  734. When calling from a program, give three arguments:
  735. a buffer or the name of one, and two character numbers
  736. specifying the portion of the current buffer to be copied."
  737.   (interactive "BCopy to buffer: \nr")
  738.   (let ((oldbuf (current-buffer)))
  739.     (save-excursion
  740.       (set-buffer (get-buffer-create buffer))
  741.       (erase-buffer)
  742.       (save-excursion
  743.     (insert-buffer-substring oldbuf start end)))))
  744.  
  745. (defun mark ()
  746.   "Return this buffer's mark value as integer, or nil if no mark.
  747. If you are using this in an editing command, you are most likely making
  748. a mistake; see the documentation of `set-mark'."
  749.   (marker-position (mark-marker)))
  750.  
  751. (defun set-mark (pos)
  752.   "Set this buffer's mark to POS.  Don't use this function!
  753. That is to say, don't use this function unless you want
  754. the user to see that the mark has moved, and you want the previous
  755. mark position to be lost.
  756.  
  757. Normally, when a new mark is set, the old one should go on the stack.
  758. This is why most applications should use push-mark, not set-mark.
  759.  
  760. Novice emacs-lisp programmers often try to use the mark for the wrong
  761. purposes.  The mark saves a location for the user's convenience.
  762. Most editing commands should not alter the mark.
  763. To remember a location for internal use in the Lisp program,
  764. store it in a Lisp variable.  Example:
  765.  
  766.    (let ((beg (point))) (forward-line 1) (delete-region beg (point)))."
  767.  
  768.   (set-marker (mark-marker) pos (current-buffer)))
  769.  
  770. (defvar mark-ring nil
  771.   "The list of saved former marks of the current buffer,
  772. most recent first.")
  773. (make-variable-buffer-local 'mark-ring)
  774.  
  775. (defconst mark-ring-max 16
  776.   "*Maximum size of mark ring.  Start discarding off end if gets this big.")
  777.  
  778. (defun set-mark-command (arg)
  779.   "Set mark at where point is, or jump to mark.
  780. With no prefix argument, set mark, and push previous mark on mark ring.
  781. With argument, jump to mark, and pop into mark off the mark ring.
  782.  
  783. Novice emacs-lisp programmers often try to use the mark for the wrong
  784. purposes.  See the documentation of `set-mark' for more information."
  785.   (interactive "P")
  786.   (if (null arg)
  787.       (push-mark)
  788.     (if (null (mark))
  789.     (error "No mark set in this buffer")
  790.       (goto-char (mark))
  791.       (pop-mark))))
  792.  
  793. (defun push-mark (&optional location nomsg)
  794.   "Set mark at LOCATION (point, by default) and push old mark on mark ring.
  795. Displays \"Mark set\" unless the optional second arg NOMSG is non-nil.
  796.  
  797. Novice emacs-lisp programmers often try to use the mark for the wrong
  798. purposes.  See the documentation of `set-mark' for more information."
  799.   (if (null (mark))
  800.       nil
  801.     (setq mark-ring (cons (copy-marker (mark-marker)) mark-ring))
  802.     (if (> (length mark-ring) mark-ring-max)
  803.     (progn
  804.       (move-marker (car (nthcdr mark-ring-max mark-ring)) nil)
  805.       (setcdr (nthcdr (1- mark-ring-max) mark-ring) nil))))
  806.   (set-mark (or location (point)))
  807.   (or nomsg executing-macro (> (minibuffer-depth) 0)
  808.       (message "Mark set")))
  809.  
  810. (defun pop-mark ()
  811.   "Pop off mark ring into the buffer's actual mark.
  812. Does not set point.  Does nothing if mark ring is empty."
  813.   (if mark-ring
  814.       (progn
  815.     (setq mark-ring (nconc mark-ring (list (copy-marker (mark-marker)))))
  816.     (set-mark (+ 0 (car mark-ring)))
  817.     (move-marker (car mark-ring) nil)
  818.     (if (null (mark)) (ding))
  819.     (setq mark-ring (cdr mark-ring)))))
  820.  
  821. (fset 'exchange-dot-and-mark 'exchange-point-and-mark)
  822. (defun exchange-point-and-mark ()
  823.   "Put the mark where point is now, and point where the mark is now."
  824.   (interactive nil)
  825.   (let ((omark (mark)))
  826.     (if (null omark)
  827.     (error "No mark set in this buffer"))
  828.     (set-mark (point))
  829.     (goto-char omark)
  830.     nil))
  831.  
  832. (defun next-line (arg)
  833.   "Move cursor vertically down ARG lines.
  834. If there is no character in the target line exactly under the current column,
  835. the cursor is positioned after the character in that line which spans this
  836. column, or at the end of the line if it is not long enough.
  837. If there is no line in the buffer after this one,
  838. a newline character is inserted to create a line
  839. and the cursor moves to that line.
  840.  
  841. The command \\[set-goal-column] can be used to create
  842. a semipermanent goal column to which this command always moves.
  843. Then it does not try to move vertically.
  844.  
  845. If you are thinking of using this in a Lisp program, consider
  846. using `forward-line' instead.  It is usually easier to use
  847. and more reliable (no dependence on goal column, etc.)."
  848.   (interactive "p")
  849.   (if (= arg 1)
  850.       (let ((opoint (point)))
  851.     (forward-line 1)
  852.     (if (or (= opoint (point))
  853.         (not (eq (preceding-char) ?\n)))
  854.         (insert ?\n)
  855.       (goto-char opoint)
  856.       (next-line-internal arg)))
  857.     (next-line-internal arg))
  858.   nil)
  859.  
  860. (defun previous-line (arg)
  861.   "Move cursor vertically up ARG lines.
  862. If there is no character in the target line exactly over the current column,
  863. the cursor is positioned after the character in that line which spans this
  864. column, or at the end of the line if it is not long enough.
  865.  
  866. The command \\[set-goal-column] can be used to create
  867. a semipermanent goal column to which this command always moves.
  868. Then it does not try to move vertically.
  869.  
  870. If you are thinking of using this in a Lisp program, consider using
  871. `forward-line' with negative argument instead..  It is usually easier
  872. to use and more reliable (no dependence on goal column, etc.)."
  873.   (interactive "p")
  874.   (next-line-internal (- arg))
  875.   nil)
  876.  
  877. (defconst track-eol nil
  878.   "*Non-nil means vertical motion starting at the end of a line should keep to ends of lines.
  879. This means moving to the end of each line moved onto.")
  880.  
  881. (defvar goal-column nil
  882.   "*Semipermanent goal column for vertical motion, as set by \\[set-goal-column], or nil.")
  883.  
  884. (defvar temporary-goal-column 0
  885.   "Current goal column for vertical motion.
  886. It is the column where point was at the start of current run of vertical motion commands.")
  887.  
  888. (defun next-line-internal (arg)
  889.   (if (not (or (eq last-command 'next-line)
  890.            (eq last-command 'previous-line)))
  891.       (setq temporary-goal-column
  892.         (if (and track-eol (eolp))
  893.         t
  894.           (current-column))))
  895.   (if (not (integerp selective-display))
  896.       (forward-line arg)
  897.     ;; Move by arg lines, but ignore invisible ones.
  898.     (while (> arg 0)
  899.       (vertical-motion 1)
  900.       (forward-char -1)
  901.       (forward-line 1)
  902.       (setq arg (1- arg)))
  903.     (while (< arg 0)
  904.       (vertical-motion -1)
  905.       (beginning-of-line)
  906.       (setq arg (1+ arg))))
  907.   (if (eq (or goal-column temporary-goal-column) t)
  908.       (end-of-line)
  909.     (move-to-column (or goal-column temporary-goal-column)))
  910.   nil)
  911.  
  912.  
  913. (defun set-goal-column (arg)
  914.   "Set the current horizontal position as a goal for \\[next-line] and \\[previous-line].
  915. Those commands will move to this position in the line moved to
  916. rather than trying to keep the same horizontal position.
  917. With a non-nil argument, clears out the goal column
  918. so that \\[next-line] and \\[previous-line] resume vertical motion."
  919.   (interactive "P")
  920.   (if arg
  921.       (progn
  922.         (setq goal-column nil)
  923.         (message "No goal column"))
  924.     (setq goal-column (current-column))
  925.     (message (substitute-command-keys
  926.           "Goal column %d (use \\[set-goal-column] with an arg to unset it)")
  927.          goal-column))
  928.   nil)
  929.  
  930. (defun transpose-chars (arg)
  931.   "Interchange characters around point, moving forward one character.
  932. With prefix arg ARG, effect is to take character before point
  933. and drag it forward past ARG other characters (backward if ARG negative).
  934. If no argument and at end of line, the previous two chars are exchanged."
  935.   (interactive "*P")
  936.   (and (null arg) (eolp) (forward-char -1))
  937.   (transpose-subr 'forward-char (prefix-numeric-value arg)))
  938.  
  939. (defun transpose-words (arg)
  940.   "Interchange words around point, leaving point at end of them.
  941. With prefix arg ARG, effect is to take word before or around point
  942. and drag it forward past ARG other words (backward if ARG negative).
  943. If ARG is zero, the words around or after point and around or after mark
  944. are interchanged."
  945.   (interactive "*p")
  946.   (transpose-subr 'forward-word arg))
  947.  
  948. (defun transpose-sexps (arg)
  949.   "Like \\[transpose-words] but applies to sexps.
  950. Does not work on a sexp that point is in the middle of
  951. if it is a list or string."
  952.   (interactive "*p")
  953.   (transpose-subr 'forward-sexp arg))
  954.  
  955. (defun transpose-lines (arg)
  956.   "Exchange current line and previous line, leaving point after both.
  957. With argument ARG, takes previous line and moves it past ARG lines.
  958. With argument 0, interchanges line point is in with line mark is in."
  959.   (interactive "*p")
  960.   (transpose-subr (function
  961.            (lambda (arg)
  962.              (if (= arg 1)
  963.              (progn
  964.                ;; Move forward over a line,
  965.                ;; but create a newline if none exists yet.
  966.                (end-of-line)
  967.                (if (eobp)
  968.                    (newline)
  969.                  (forward-char 1)))
  970.                (forward-line arg))))
  971.           arg))
  972.  
  973. (defun transpose-subr (mover arg)
  974.   (let (start1 end1 start2 end2)
  975.     (if (= arg 0)
  976.     (progn
  977.       (save-excursion
  978.         (funcall mover 1)
  979.         (setq end2 (point))
  980.         (funcall mover -1)
  981.         (setq start2 (point))
  982.         (goto-char (mark))
  983.         (funcall mover 1)
  984.         (setq end1 (point))
  985.         (funcall mover -1)
  986.         (setq start1 (point))
  987.         (transpose-subr-1))
  988.       (exchange-point-and-mark)))
  989.     (while (> arg 0)
  990.       (funcall mover -1)
  991.       (setq start1 (point))
  992.       (funcall mover 1)
  993.       (setq end1 (point))
  994.       (funcall mover 1)
  995.       (setq end2 (point))
  996.       (funcall mover -1)
  997.       (setq start2 (point))
  998.       (transpose-subr-1)
  999.       (goto-char end2)
  1000.       (setq arg (1- arg)))
  1001.     (while (< arg 0)
  1002.       (funcall mover -1)
  1003.       (setq start2 (point))
  1004.       (funcall mover -1)
  1005.       (setq start1 (point))
  1006.       (funcall mover 1)
  1007.       (setq end1 (point))
  1008.       (funcall mover 1)
  1009.       (setq end2 (point))
  1010.       (transpose-subr-1)
  1011.       (setq arg (1+ arg)))))
  1012.  
  1013. (defun transpose-subr-1 ()
  1014.   (if (> (min end1 end2) (max start1 start2))
  1015.       (error "Don't have two things to transpose"))
  1016.   (let ((word1 (buffer-substring start1 end1))
  1017.     (word2 (buffer-substring start2 end2)))
  1018.     (delete-region start2 end2)
  1019.     (goto-char start2)
  1020.     (insert word1)
  1021.     (goto-char (if (< start1 start2) start1
  1022.          (+ start1 (- (length word1) (length word2)))))
  1023.     (delete-char (length word1))
  1024.     (insert word2)))
  1025.  
  1026. (defconst comment-column 32
  1027.   "*Column to indent right-margin comments to.
  1028. Setting this variable automatically makes it local to the current buffer.")
  1029. (make-variable-buffer-local 'comment-column)
  1030.  
  1031. (defconst comment-start nil
  1032.   "*String to insert to start a new comment, or nil if no comment syntax defined.")
  1033.  
  1034. (defconst comment-start-skip nil
  1035.   "*Regexp to match the start of a comment plus everything up to its body.
  1036. If there are any \\(...\\) pairs, the comment delimiter text is held to begin
  1037. at the place matched by the close of the first pair.")
  1038.  
  1039. (defconst comment-end ""
  1040.   "*String to insert to end a new comment.
  1041. Should be an empty string if comments are terminated by end-of-line.")
  1042.  
  1043. (defconst comment-indent-hook
  1044.   '(lambda () comment-column)
  1045.   "Function to compute desired indentation for a comment
  1046. given the character number it starts at.")
  1047.  
  1048. (defun indent-for-comment ()
  1049.   "Indent this line's comment to comment column, or insert an empty comment."
  1050.   (interactive "*")
  1051.   (beginning-of-line 1)
  1052.   (if (null comment-start)
  1053.       (error "No comment syntax defined")
  1054.     (let* ((eolpos (save-excursion (end-of-line) (point)))
  1055.        cpos indent begpos)
  1056.       (if (re-search-forward comment-start-skip eolpos 'move)
  1057.       (progn (setq cpos (point-marker))
  1058.          ;; Find the start of the comment delimiter.
  1059.          ;; If there were paren-pairs in comment-start-skip,
  1060.          ;; position at the end of the first pair.
  1061.          (if (match-end 1)
  1062.              (goto-char (match-end 1))
  1063.            ;; If comment-start-skip matched a string with internal
  1064.            ;; whitespace (not final whitespace) then the delimiter
  1065.            ;; start at the end of that whitespace.
  1066.            ;; Otherwise, it starts at the beginning of what was matched.
  1067.            (skip-chars-backward " \t" (match-beginning 0))
  1068.            (skip-chars-backward "^ \t" (match-beginning 0)))))
  1069.       (setq begpos (point))
  1070.       ;; Compute desired indent.
  1071.       (if (= (current-column)
  1072.          (setq indent (funcall comment-indent-hook)))
  1073.       (goto-char begpos)
  1074.     ;; If that's different from current, change it.
  1075.     (skip-chars-backward " \t")
  1076.     (delete-region (point) begpos)
  1077.     (indent-to indent))
  1078.       ;; An existing comment?
  1079.       (if cpos 
  1080.       (progn (goto-char cpos)
  1081.          (set-marker cpos nil))
  1082.     ;; No, insert one.
  1083.     (insert comment-start)
  1084.     (save-excursion
  1085.       (insert comment-end))))))
  1086.  
  1087. (defun set-comment-column (arg)
  1088.   "Set the comment column based on point.
  1089. With no arg, set the comment column to the current column.
  1090. With just minus as arg, kill any comment on this line.
  1091. With any other arg, set comment column to indentation of the previous comment
  1092.  and then align or create a comment on this line at that column."
  1093.   (interactive "P")
  1094.   (if (eq arg '-)
  1095.       (kill-comment nil)
  1096.     (if arg
  1097.     (progn
  1098.       (save-excursion
  1099.         (beginning-of-line)
  1100.         (re-search-backward comment-start-skip)
  1101.         (beginning-of-line)
  1102.         (re-search-forward comment-start-skip)
  1103.         (goto-char (match-beginning 0))
  1104.         (setq comment-column (current-column))
  1105.         (message "Comment column set to %d" comment-column))
  1106.       (indent-for-comment))
  1107.       (setq comment-column (current-column))
  1108.       (message "Comment column set to %d" comment-column))))
  1109.  
  1110. (defun kill-comment (arg)
  1111.   "Kill the comment on this line, if any.
  1112. With argument, kill comments on that many lines starting with this one."
  1113.   (interactive "P")
  1114.   (barf-if-buffer-read-only)
  1115.   (let ((count (prefix-numeric-value arg)))
  1116.     (beginning-of-line)
  1117.     (while (> count 0)
  1118.       (let ((eolpos (save-excursion (end-of-line) (point))))
  1119.     (if (re-search-forward comment-start-skip eolpos t)
  1120.         (progn
  1121.           (goto-char (match-beginning 0))
  1122.           (skip-chars-backward " \t")
  1123.           (kill-region (point) eolpos))))
  1124.       (if arg
  1125.       (forward-line 1))
  1126.       (setq count (1- count)))))
  1127.  
  1128. (defun backward-word (arg)
  1129.   "Move backward until encountering the end of a word.
  1130. With argument, do this that many times.
  1131. In programs, it is faster to call forward-word with negative arg."
  1132.   (interactive "p")
  1133.   (forward-word (- arg)))
  1134.  
  1135. (defun mark-word (arg)
  1136.   "Set mark arg words away from point."
  1137.   (interactive "p")
  1138.   (push-mark
  1139.     (save-excursion
  1140.       (forward-word arg)
  1141.       (point))))
  1142.  
  1143. (defun kill-word (arg)
  1144.   "Kill characters forward until encountering the end of a word.
  1145. With argument, do this that many times."
  1146.   (interactive "*p")
  1147.   (kill-region (point) (progn (forward-word arg) (point))))
  1148.  
  1149. (defun backward-kill-word (arg)
  1150.   "Kill characters backward until encountering the end of a word.
  1151. With argument, do this that many times."
  1152.   (interactive "*p")
  1153.   (kill-word (- arg)))
  1154.  
  1155. (defconst fill-prefix nil
  1156.   "*String for filling to insert at front of new line, or nil for none.
  1157. Setting this variable automatically makes it local to the current buffer.")
  1158. (make-variable-buffer-local 'fill-prefix)
  1159.  
  1160. (defun do-auto-fill ()
  1161.   (let ((fill-point
  1162.      (let ((opoint (point)))
  1163.        (save-excursion
  1164.          (move-to-column (1+ fill-column))
  1165.          (skip-chars-backward "^ \t\n")
  1166.          (if (bolp)
  1167.          (re-search-forward "[ \t]" opoint t))
  1168.          (skip-chars-backward " \t")
  1169.          (point)))))
  1170.     ;; If there is a space on the line before fill-point,
  1171.     ;; and nonspaces precede it, break the line there.
  1172.     (if (save-excursion
  1173.       (goto-char fill-point)
  1174.       (not (bolp)))
  1175.     ;; If point is at the fill-point, do not `save-excursion'.
  1176.     ;; Otherwise, if a comment prefix or fill-prefix is inserted,
  1177.     ;; point will end up before it rather than after it.
  1178.     (if (save-excursion
  1179.           (skip-chars-backward " \t")
  1180.           (= (point) fill-point))
  1181.         (indent-new-comment-line)
  1182.         (save-excursion
  1183.           (goto-char fill-point)
  1184.           (indent-new-comment-line))))))
  1185.  
  1186. (defconst comment-multi-line nil
  1187.   "*Non-nil means \\[indent-new-comment-line] should continue same comment
  1188. on new line, with no new terminator or starter.")
  1189.  
  1190. (defun indent-new-comment-line ()
  1191.   "Break line at point and indent, continuing comment if presently within one.
  1192. The body of the continued comment is indented under the previous comment line."
  1193.   (interactive "*")
  1194.   (let (comcol comstart)
  1195.     (skip-chars-backward " \t")
  1196.     (delete-region (point)
  1197.            (progn (skip-chars-forward " \t")
  1198.               (point)))
  1199.     (insert ?\n)
  1200.     (save-excursion
  1201.       (if (and comment-start-skip
  1202.            (let ((opoint (point)))
  1203.          (forward-line -1)
  1204.          (re-search-forward comment-start-skip opoint t)))
  1205.       ;; The old line is a comment.
  1206.       ;; Set WIN to the pos of the comment-start.
  1207.       ;; But if the comment is empty, look at preceding lines
  1208.       ;; to find one that has a nonempty comment.
  1209.       (let ((win (match-beginning 0)))
  1210.         (while (and (eolp) (not (bobp))
  1211.             (let (opoint)
  1212.               (beginning-of-line)
  1213.               (setq opoint (point))
  1214.               (forward-line -1)
  1215.               (re-search-forward comment-start-skip opoint t)))
  1216.           (setq win (match-beginning 0)))
  1217.         ;; Indent this line like what we found.
  1218.         (goto-char win)
  1219.         (setq comcol (current-column))
  1220.         (setq comstart (buffer-substring (point) (match-end 0))))))
  1221.     (if comcol
  1222.     (let ((comment-column comcol)
  1223.           (comment-start comstart)
  1224.           (comment-end comment-end))
  1225.       (and comment-end (not (equal comment-end ""))
  1226.            (if (not comment-multi-line)
  1227.            (progn
  1228.              (forward-char -1)
  1229.              (insert comment-end)
  1230.              (forward-char 1))
  1231.          (setq comment-column (+ comment-column (length comment-start))
  1232.                comment-start "")))
  1233.       (if (not (eolp))
  1234.           (setq comment-end ""))
  1235.       (insert ?\n)
  1236.       (forward-char -1)
  1237.       (indent-for-comment)
  1238.       (delete-char 1))
  1239.       (if fill-prefix
  1240.       (insert fill-prefix)
  1241.     (indent-according-to-mode)))))
  1242.  
  1243. (defun auto-fill-mode (arg)
  1244.   "Toggle auto-fill mode.
  1245. With arg, turn auto-fill mode on iff arg is positive.
  1246. In auto-fill mode, inserting a space at a column beyond  fill-column
  1247. automatically breaks the line at a previous space."
  1248.   (interactive "P")
  1249.   (prog1 (setq auto-fill-hook
  1250.            (if (if (null arg)
  1251.                (not auto-fill-hook)
  1252.                (> (prefix-numeric-value arg) 0))
  1253.            'do-auto-fill
  1254.            nil))
  1255.     ;; update mode-line
  1256.     (set-buffer-modified-p (buffer-modified-p))))
  1257.  
  1258. (defun turn-on-auto-fill ()
  1259.   "Unconditionally turn on Auto Fill mode."
  1260.   (auto-fill-mode 1))
  1261.  
  1262. (defun set-fill-column (arg)
  1263.   "Set fill-column to current column, or to argument if given.
  1264. fill-column's value is separate for each buffer."
  1265.   (interactive "P")
  1266.   (setq fill-column (if (integerp arg) arg (current-column)))
  1267.   (message "fill-column set to %d" fill-column))
  1268.  
  1269. (defun set-selective-display (arg)
  1270.   "Set selective-display to ARG; clear it if no arg.
  1271. When selective-display is a number > 0,
  1272. lines whose indentation is >= selective-display are not displayed.
  1273. selective-display's value is separate for each buffer."
  1274.   (interactive "P")
  1275.   (if (eq selective-display t)
  1276.       (error "selective-display already in use for marked lines"))
  1277.   (setq selective-display
  1278.     (and arg (prefix-numeric-value arg)))
  1279.   (set-window-start (selected-window) (window-start (selected-window)))
  1280.   (princ "selective-display set to " t)
  1281.   (prin1 selective-display t)
  1282.   (princ "." t))
  1283.  
  1284. (defun overwrite-mode (arg)
  1285.   "Toggle overwrite mode.
  1286. With arg, turn overwrite mode on iff arg is positive.
  1287. In overwrite mode, printing characters typed in replace existing text
  1288. on a one-for-one basis, rather than pushing it to the right."
  1289.   (interactive "P")
  1290.   (setq overwrite-mode
  1291.     (if (null arg) (not overwrite-mode)
  1292.       (> (prefix-numeric-value arg) 0)))
  1293.   (set-buffer-modified-p (buffer-modified-p))) ;No-op, but updates mode line.
  1294.  
  1295. (defconst blink-matching-paren t
  1296.   "*Non-nil means show matching open-paren when close-paren is inserted.")
  1297.  
  1298. (defconst blink-matching-paren-distance 4000
  1299.   "*If non-nil, is maximum distance to search for matching open-paren
  1300. when close-paren is inserted.")
  1301.  
  1302. (defun blink-matching-open ()
  1303.   "Move cursor momentarily to the beginning of the sexp before point."
  1304.   (and (> (point) (1+ (point-min)))
  1305.        (/= (char-syntax (char-after (- (point) 2))) ?\\ )
  1306.        blink-matching-paren
  1307.        (let* ((oldpos (point))
  1308.           (blinkpos)
  1309.           (mismatch))
  1310.      (save-excursion
  1311.        (save-restriction
  1312.          (if blink-matching-paren-distance
  1313.          (narrow-to-region (max (point-min)
  1314.                     (- (point) blink-matching-paren-distance))
  1315.                    oldpos))
  1316.          (condition-case ()
  1317.          (setq blinkpos (scan-sexps oldpos -1))
  1318.            (error nil)))
  1319.        (and blinkpos (/= (char-syntax (char-after blinkpos))
  1320.                  ?\$)
  1321.         (setq mismatch
  1322.               (/= (char-after (1- oldpos))
  1323.               (logand (lsh (aref (syntax-table)
  1324.                          (char-after blinkpos))
  1325.                        -8)
  1326.                   255))))
  1327.        (if mismatch (setq blinkpos nil))
  1328.        (if blinkpos
  1329.            (progn
  1330.         (goto-char blinkpos)
  1331.         (if (pos-visible-in-window-p)
  1332.             (sit-for 1)
  1333.           (goto-char blinkpos)
  1334.           (message
  1335.            "Matches %s"
  1336.            (if (save-excursion
  1337.              (skip-chars-backward " \t")
  1338.              (not (bolp)))
  1339.                (buffer-substring (progn (beginning-of-line) (point))
  1340.                      (1+ blinkpos))
  1341.              (buffer-substring blinkpos
  1342.                        (progn
  1343.                     (forward-char 1)
  1344.                     (skip-chars-forward "\n \t")
  1345.                     (end-of-line)
  1346.                     (point)))))))
  1347.          (cond (mismatch
  1348.             (message "Mismatched parentheses"))
  1349.            ((not blink-matching-paren-distance)
  1350.             (message "Unmatched parenthesis"))))))))
  1351.  
  1352. ;Turned off because it makes dbx bomb out.
  1353. (setq blink-paren-hook 'blink-matching-open)
  1354.  
  1355. ; this is just something for the luser to see in a keymap -- this is not
  1356. ;  how quitting works normally!
  1357. (defun keyboard-quit ()
  1358.   "Signal a  quit  condition."
  1359.   (interactive)
  1360.   (signal 'quit nil))
  1361.  
  1362. (define-key global-map "\C-g" 'keyboard-quit)
  1363.  
  1364. (defun set-variable (var val)
  1365.   "Set VARIABLE to VALUE.  VALUE is a Lisp object.
  1366. When using this interactively, supply a Lisp expression for VALUE.
  1367. If you want VALUE to be a string, you must surround it with doublequotes."
  1368.   (interactive
  1369.    (let* ((var (read-variable "Set variable: "))
  1370.       (minibuffer-help-form
  1371.        '(funcall myhelp))
  1372.       (myhelp
  1373.        (function
  1374.         (lambda ()
  1375.           (with-output-to-temp-buffer "*Help*"
  1376.         (prin1 var)
  1377.         (princ "\nDocumentation:\n")
  1378.         (princ (substring (documentation-property var 'variable-documentation)
  1379.                   1))
  1380.         (if (boundp var)
  1381.             (let ((print-length 20))
  1382.               (princ "\n\nCurrent value: ")
  1383.               (prin1 (symbol-value var))))
  1384.         nil)))))
  1385.      (list var
  1386.        (eval-minibuffer (format "Set %s to value: " var)))))
  1387.   (set var val))
  1388.  
  1389. ;These commands are defined in editfns.c
  1390. ;but they are not assigned to keys there.
  1391. (put 'narrow-to-region 'disabled t)
  1392. (define-key ctl-x-map "n" 'narrow-to-region)
  1393. (define-key ctl-x-map "w" 'widen)
  1394.  
  1395. (define-key global-map "\C-j" 'newline-and-indent)
  1396. (define-key global-map "\C-m" 'newline)
  1397. (define-key global-map "\C-o" 'open-line)
  1398. (define-key esc-map "\C-o" 'split-line)
  1399. (define-key global-map "\C-q" 'quoted-insert)
  1400. (define-key esc-map "^" 'delete-indentation)
  1401. (define-key esc-map "\\" 'delete-horizontal-space)
  1402. (define-key esc-map "m" 'back-to-indentation)
  1403. (define-key ctl-x-map "\C-o" 'delete-blank-lines)
  1404. (define-key esc-map " " 'just-one-space)
  1405. (define-key esc-map "z" 'zap-to-char)
  1406. (define-key esc-map "=" 'count-lines-region)
  1407. (define-key ctl-x-map "=" 'what-cursor-position)
  1408. (define-key esc-map "\e" 'eval-expression)
  1409. (define-key ctl-x-map "\e" 'repeat-complex-command)
  1410. (define-key ctl-x-map "u" 'advertised-undo)
  1411. (define-key global-map "\C-_" 'undo)
  1412. (define-key esc-map "!" 'shell-command)
  1413. (define-key esc-map "|" 'shell-command-on-region)
  1414.  
  1415. (define-key global-map "\C-u" 'universal-argument)
  1416. (let ((i ?0))
  1417.   (while (<= i ?9)
  1418.     (define-key esc-map (char-to-string i) 'digit-argument)
  1419.     (setq i (1+ i))))
  1420. (define-key esc-map "-" 'negative-argument)
  1421.  
  1422. (define-key global-map "\C-k" 'kill-line)
  1423. (define-key global-map "\C-w" 'kill-region)
  1424. (define-key esc-map "w" 'copy-region-as-kill)
  1425. (define-key esc-map "\C-w" 'append-next-kill)
  1426. (define-key global-map "\C-y" 'yank)
  1427. (define-key esc-map "y" 'yank-pop)
  1428.  
  1429. (define-key ctl-x-map "a" 'append-to-buffer)
  1430.  
  1431. (define-key global-map "\C-@" 'set-mark-command)
  1432. (define-key ctl-x-map "\C-x" 'exchange-point-and-mark)
  1433.  
  1434. (define-key global-map "\C-n" 'next-line)
  1435. (define-key global-map "\C-p" 'previous-line)
  1436. (define-key ctl-x-map "\C-n" 'set-goal-column)
  1437.  
  1438. (define-key global-map "\C-t" 'transpose-chars)
  1439. (define-key esc-map "t" 'transpose-words)
  1440. (define-key esc-map "\C-t" 'transpose-sexps)
  1441. (define-key ctl-x-map "\C-t" 'transpose-lines)
  1442.  
  1443. (define-key esc-map ";" 'indent-for-comment)
  1444. (define-key esc-map "j" 'indent-new-comment-line)
  1445. (define-key esc-map "\C-j" 'indent-new-comment-line)
  1446. (define-key ctl-x-map ";" 'set-comment-column)
  1447. (define-key ctl-x-map "f" 'set-fill-column)
  1448. (define-key ctl-x-map "$" 'set-selective-display)
  1449.  
  1450. (define-key esc-map "@" 'mark-word)
  1451. (define-key esc-map "f" 'forward-word)
  1452. (define-key esc-map "b" 'backward-word)
  1453. (define-key esc-map "d" 'kill-word)
  1454. (define-key esc-map "\177" 'backward-kill-word)
  1455.  
  1456. (define-key esc-map "<" 'beginning-of-buffer)
  1457. (define-key esc-map ">" 'end-of-buffer)
  1458. (define-key ctl-x-map "h" 'mark-whole-buffer)
  1459. (define-key esc-map "\\" 'delete-horizontal-space)
  1460.  
  1461. (fset 'mode-specific-command-prefix (make-sparse-keymap))
  1462. (defconst mode-specific-map (symbol-function 'mode-specific-command-prefix)
  1463.   "Keymap for characters following C-c.")
  1464. (define-key global-map "\C-c" 'mode-specific-command-prefix)
  1465.